I_VMSVEHICLEPURCHASEORDER

CDS View

View for Vehicle purchase Order

I_VMSVEHICLEPURCHASEORDER is a CDS View in S/4HANA. View for Vehicle purchase Order. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_VMSVehiclePurchaseOrder view from COMPOSITE Vehicle Purchase Order 
@AbapCatalog.sqlViewName: 'IVMSPURORD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.serviceQuality : #C
@ObjectModel.usageType.sizeCategory : #L
@ObjectModel.usageType.dataClass : #TRANSACTIONAL
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'View for Vehicle purchase Order'
define view I_VMSVehiclePurchaseOrder
  as select from vlcporder
  association [1..1] to I_VMSVehicleStdPurchaseOrder as _VMSVehicleStdPurchaseOrder on  vlcporder.ebeln = _VMSVehicleStdPurchaseOrder.PurchaseOrder
                                                                                    and vlcporder.ebelp = _VMSVehicleStdPurchaseOrder.PurchaseOrderItem
  association [0..*] to I_CostCenterText             as _CostCenterText             on  _CostCenterText.CostCenter = $projection.costcenter
  association [1..1] to E_VMSVehiclePurchaseOrder    as _Extension                  on  $projection.VMSVehicleUUID           = _Extension.VMSVehicleUUID
                                                                                    and $projection.VMSVehicleActionDateTime = _Extension.VMSVehicleActionDateTime

{
  key vlcporder.vguid      as VMSVehicleUUID,
  key vlcporder.tstmp      as VMSVehicleActionDateTime,
      vlcporder.actdoctype as VMSVehicleActionDocType,
      vlcporder.ebeln      as PurchaseOrder,
      vlcporder.ebelp      as PurchaseOrderItem,
      vlcporder.cuobj      as ConfigurationNumber,
      vlcporder.ernam      as CreatedByUserName,
      vlcporder.xgore      as VMSVehicleGdsReceiptIsComplete,
      vlcporder.xiniv      as VMSVehicleInvcRcptIsComplete,
      _VMSVehicleStdPurchaseOrder.CompanyCode,
      _VMSVehicleStdPurchaseOrder.CompanyCodeName,
      _VMSVehicleStdPurchaseOrder.Supplier,
      _VMSVehicleStdPurchaseOrder.PurchasingOrganization,
      _VMSVehicleStdPurchaseOrder.PurchasingOrganizationName,
      _VMSVehicleStdPurchaseOrder.PurchasingGroup,
      _VMSVehicleStdPurchaseOrder.PurchasingGroupName,
      _VMSVehicleStdPurchaseOrder.PurchaseOrderDate,
      _VMSVehicleStdPurchaseOrder.Plant,
      _VMSVehicleStdPurchaseOrder.PlantName,
      @ObjectModel.text.association: '_CostCenterText'
      _VMSVehicleStdPurchaseOrder.CostCenter,
      @Semantics.amount.currencyCode : 'DocumentCurrency'
      _VMSVehicleStdPurchaseOrder.NetPriceAmount,
      @Semantics.currencyCode: true
      _VMSVehicleStdPurchaseOrder.DocumentCurrency,
      _VMSVehicleStdPurchaseOrder.PurchasingProcessingStatus,
      _VMSVehicleStdPurchaseOrder.PurchasingProcessingStatusName,
      _VMSVehicleStdPurchaseOrder._Supplier,
      _VMSVehicleStdPurchaseOrder._CompanyCode,
      _VMSVehicleStdPurchaseOrder._PurchasingOrganization,
      _VMSVehicleStdPurchaseOrder._PurchasingGroup,
      _VMSVehicleStdPurchaseOrder._DocumentCurrency,
      _VMSVehicleStdPurchaseOrder.PurchaseOrderType,
      @Consumption.hidden: true
      _CostCenterText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_VMSVEHICLESTDPURCHASEORDER",
"VLCPORDER"
],
"ASSOCIATED":
[
"E_VMSVEHICLEPURCHASEORDER",
"I_COMPANYCODE",
"I_COSTCENTERTEXT",
"I_CURRENCY",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_SUPPLIER",
"I_VMSVEHICLESTDPURCHASEORDER"
],
"BASE":
[
"I_VMSVEHICLESTDPURCHASEORDER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More