I_VMSVEHICLEINVOICE

CDS View

Text View for vehicle Invoice

I_VMSVEHICLEINVOICE is a CDS View in S/4HANA. Text View for vehicle Invoice. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_VMSVehicleInvoice view from COMPOSITE Vehicle Outgoing Invoice 
@AbapCatalog.sqlViewName: 'IVMSINVOICE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Text View for vehicle Invoice'
@ObjectModel.usageType.serviceQuality : #C
@ObjectModel.usageType.sizeCategory : #XL
@ObjectModel.usageType.dataClass : #TRANSACTIONAL
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
define view I_VMSVehicleInvoice
  as select from I_VMSVehicleInvoiceBasic as _VMSVehicleInvoiceBasic
  association [1..*] to I_BillingDocumentItemBasic as _BILLINGDOCUMENTITEMBASIC on  _BILLINGDOCUMENTITEMBASIC.BillingDocument = _VMSVehicleInvoiceBasic.BillingDocument
                                                                                and _BILLINGDOCUMENTITEMBASIC.Batch           = _VMSVehicleInvoiceBasic.VMSVehicleBatch
  association [1..*] to I_SalesOrganizationText    as _SalesOrganizationText    on  _SalesOrganizationText.SalesOrganization = $projection.SalesOrganization
  association [1..1] to E_VMSVehicleInvoice        as _Extension                on  $projection.VMSVehicleUUID           = _Extension.VMSVehicleUUID
                                                                                and $projection.VMSVehicleActionDateTime = _Extension.VMSVehicleActionDateTime
{
  key VMSVehicleUUID,
  key VMSVehicleActionDateTime,
      VMSVehicleActionDocType,
      BillingDocument,
      VMSVehicleActnDocTypeIsRvsd,
      CreatedByUser,
      _VMSVehicleInvoiceBasic.VMSVehicleBatch,
      @ObjectModel.text.association: '_SalesOrganizationText'
      _VMSVehicleInvoiceBasic.SalesOrganization,
      _VMSVehicleInvoiceBasic.CompanyCode,
      _VMSVehicleInvoiceBasic.BillingDocumentDate,
      _VMSVehicleInvoiceBasic.CreationDate,
      _VMSVehicleInvoiceBasic.SoldToParty,
      _VMSVehicleInvoiceBasic.SDDocumentCategory,
      case _VMSVehicleInvoiceBasic.SDDocumentCategory
      when 'N' then 'X'
      when 'M' then ''
      end                                                                    as BillingDocumentIsCancelled,
      cast(case  when _VMSVehicleInvoiceBasic.SDDocumentCategory  = 'N'
      then _VMSVehicleInvoiceBasic.DocumentReferenceID end as abap.char(16)) as DocumentReferenceID,
      _VMSVehicleInvoiceBasic.BillingDocumentIsCancelled                     as VMSBillingDocumentIsCancelled,
      _VMSVehicleInvoiceBasic.CancelledBillingDocument,
      //      _VMSVehicleInvoiceBasic.DocumentReferenceID,

      _BILLINGDOCUMENTITEMBASIC.BillingDocumentItem,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      _BILLINGDOCUMENTITEMBASIC.NetAmount,
      @Semantics.currencyCode: true
      _BILLINGDOCUMENTITEMBASIC.TransactionCurrency,
      _BILLINGDOCUMENTITEMBASIC.Plant,
      _SalesOrganization,
      _VMSVehicleInvoiceBasic.BillingDocumentType,
      _BILLINGDOCUMENTITEMBASIC._Plant,
      _CompanyCode,
      @Consumption.hidden: true
      _SalesOrganizationText,
      _SoldToParty
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLINGDOCUMENTITEMBASIC",
"I_VMSVEHICLEINVOICEBASIC"
],
"ASSOCIATED":
[
"E_VMSVEHICLEINVOICE",
"I_BILLINGDOCUMENTITEMBASIC",
"I_COMPANYCODE",
"I_CUSTOMER",
"I_PLANT",
"I_SALESORGANIZATION",
"I_SALESORGANIZATIONTEXT"
],
"BASE":
[
"I_BILLINGDOCUMENTITEMBASIC",
"I_VMSVEHICLEINVOICEBASIC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More