I_UTILITIESMOVEOUTDOCUMENT

@EndUserText.label: 'Utilities Move Out Document'
@Analytics.dataCategory: #DIMENSION
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IEUTILMOVEOUTDOC'
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'UtilitiesMoveOutDocument'
//Privileged associations specified

@AccessControl.privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser' ]
@Metadata.allowExtensions:true
@AbapCatalog.compiler.compareFilter:true
//@AbapCatalog.preserveKey:true

@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE, #ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE ]
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION

define view I_UtilitiesMoveOutDocument
  as select from eausv
  association [1..1] to I_UtilitiesContract            as _UtilitiesContract            on $projection.UtilitiesContract = _UtilitiesContract.UtilitiesContract
  association [1..1] to I_User                         as _CreatedByUser                on $projection.UtilsMoveOutDocCreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                         as _LastChangedByUser            on $projection.UtilsMoveOutDocLastChgdByUser = _LastChangedByUser.UserID
  association [0..1] to I_UtilitiesInstallation        as _UtilitiesInstallation        on $projection.UtilitiesInstallation = _UtilitiesInstallation.UtilitiesInstallation
  association [0..1] to I_CADunningProcedure           as _CADunningProcedure           on $projection.CADunningProcedure = _CADunningProcedure.CADunningProcedure
  association [0..1] to I_UtilsMoveOutRsnWithoutMoveIn as _UtilsMoveOutRsnWithoutMoveIn on $projection.UtilsMoveOutWithoutMoveIn = _UtilsMoveOutRsnWithoutMoveIn.UtilsMoveOutWithoutMoveIn
  association [0..1] to I_InvcUtilsContractsJointly    as _InvcUtilsContractsJointly    on $projection.UtilsContrJointInvcType = _InvcUtilsContractsJointly.UtilsContrJointInvcType
  association [0..1] to I_UtilsSpclMoveOutCaseExists   as _UtilsSpclMoveOutCaseExists   on $projection.UtilsSpclMoveOutCaseIsExisting = _UtilsSpclMoveOutCaseExists.UtilsSpclMoveOutCaseIsExisting
  association [0..1] to I_CADunningProcedure           as _UtilsMoveInOutDunningProced  on $projection.UtilsMoveInOutDunningProcedure = _UtilsMoveInOutDunningProced.CADunningProcedure
  association [0..1] to I_UtilsBillgOutsortingGroup    as _UtilsBillgOutsortingGroup    on $projection.UtilsBillgOutsortingReason = _UtilsBillgOutsortingGroup.UtilsBillgOutsortingReason
  association [0..1] to I_UtilitiesPremise             as _UtilitiesPremise             on $projection.UtilitiesPremise = _UtilitiesPremise.UtilitiesPremise
{
  key eausv.auszbeleg  as UtilitiesMoveOutDocument,
      @ObjectModel.foreignKey.association: '_UtilitiesContract'
  key eausv.vertrag    as UtilitiesContract,
      @ObjectModel.foreignKey.association: '_UtilitiesInstallation'
      eausv.anlage     as UtilitiesInstallation,
      @Semantics.businessDate.at: true
      eausv.auszdat    as UtilitiesMoveOutDate,
      @ObjectModel.foreignKey.association: '_UtilsMoveOutRsnWithoutMoveIn'
      eausv.ohneeinz   as UtilsMoveOutWithoutMoveIn,
      @Semantics.booleanIndicator:true
      eausv.storausz   as UtilsMoveOutDocumentIsReversed,
      @Semantics.booleanIndicator:true
      eausv.absstopkz  as UtilsBdgtBillingPlanIsStopped,
      @Semantics.booleanIndicator:true
      @ObjectModel.foreignKey.association: '_UtilsSpclMoveOutCaseExists'
      eausv.kzsondausz as UtilsSpclMoveOutCaseIsExisting,
      @Semantics.booleanIndicator:true
      eausv.auteigeinz as UtilsMoveInHasAutomOwnerAlloc,
      @Semantics.businessDate.at: true
      eausv.absstopdat as UtilsFinalDateForBudgetBilling,
      @ObjectModel.foreignKey.association: '_InvcUtilsContractsJointly'
      eausv.schlfakt   as UtilsContrJointInvcType,
      @ObjectModel.foreignKey.association: '_CADunningProcedure'
      eausv.mahnv      as CADunningProcedure,
      eausv.mansp      as CADunningLockReason,
      @ObjectModel.foreignKey.association: '_UtilsMoveInOutDunningProced'
      eausv.mahnvumz   as UtilsMoveInOutDunningProcedure,
      @ObjectModel.foreignKey.association: '_UtilsBillgOutsortingGroup'
      eausv.manoutsort as UtilsBillgOutsortingReason,
      eausv.keinablbel as UtilsDoNotCrteCustSelfRdngCard,
      @Semantics.businessDate.at: true
      eausv.abrdats    as ScheduledUtilitiesBillingDate,
      @Semantics.businessDate.at: true
      eausv.erdat      as UtilsMoveOutDocCreationDate,
      @Semantics.user.createdBy: true
      eausv.ernam      as UtilsMoveOutDocCreatedByUser,
      @Semantics.businessDate.at: true
      eausv.aedat      as UtilsMoveOutDocLastChangeDate,
      @Semantics.user.lastChangedBy: true
      eausv.aenam      as UtilsMoveOutDocLastChgdByUser,
      eausv.begru      as AuthorizationGroup,
      eausv.loevm      as DeletionIndicator,
      @ObjectModel.foreignKey.association: '_UtilitiesPremise'
      eausv.vstelle    as UtilitiesPremise,

      //Associations

      _UtilitiesContract,
      _CreatedByUser,
      _LastChangedByUser,
      _UtilitiesInstallation,
      _CADunningProcedure,
      _UtilsMoveOutRsnWithoutMoveIn,
      _InvcUtilsContractsJointly,
      _UtilsSpclMoveOutCaseExists,
      _UtilsMoveInOutDunningProced,
      _UtilsBillgOutsortingGroup,
      _UtilitiesPremise
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"EAUSV"
],
"ASSOCIATED":
[
"I_CADUNNINGPROCEDURE",
"I_INVCUTILSCONTRACTSJOINTLY",
"I_USER",
"I_UTILITIESCONTRACT",
"I_UTILITIESINSTALLATION",
"I_UTILITIESPREMISE",
"I_UTILSBILLGOUTSORTINGGROUP",
"I_UTILSMOVEOUTRSNWITHOUTMOVEIN",
"I_UTILSSPCLMOVEOUTCASEEXISTS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/