I_UTILITIESINVOICINGORDER

CDS View

Invoicing Order

I_UTILITIESINVOICINGORDER is a CDS View in S/4HANA. Invoicing Order. It contains 12 fields. 4 CDS views read from this table.

Used by 4 CDS view(s) 12 fields

CDS Views using this table (4)

ViewTypeJoinVDMDescription
I_SchedldUtilsContrNotInvcd view left_outer COMPOSITE Scheduled Contract Has not Been Invoiced
I_UtilsContrAcctInvcgOrderCntr view from COMPOSITE Number of Invoicing Orders for Contract Account
I_UtilsContrToBeBlldInvcdAnlys view left_outer COMPOSITE Analysis of Contract to Be Billed and Invoiced
I_UtilsInvcgOrdSchedldBillgDte view from COMPOSITE Invoicing Order For Scheduled Billing Date

Fields (12)

KeyField CDS FieldsUsed in Views
KEY ContractAccount ContractAccount 2
KEY UtilitiesBillingDocument UtilitiesBillingDocument 1
KEY UtilitiesBillingReason UtilitiesBillingReason 2
KEY UtilitiesPortion UtilitiesPortion 2
_UtilitiesBillingReason _UtilitiesBillingReason 1
_UtilitiesPortion _UtilitiesPortion 1
BusinessPartner BusinessPartner 1
CompanyCode CompanyCode 1
Division Division 1
UtilitiesContract UtilitiesContract 1
UtilsBillgDocIsNotReleased UtilsBillgDocIsNotReleased 1
UtilsBillgSimulationReason UtilsBillgSimulationReason 1 
@EndUserText.label: 'Invoicing Order'
@Analytics.dataCategory: #DIMENSION
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IEINVOICINGORDER'
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'UtilitiesBillingDocument'
@Metadata.allowExtensions:true
@AbapCatalog.compiler.compareFilter:true
//@AbapCatalog.preserveKey:true

@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE, #ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE ]
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION

define view I_UtilitiesInvoicingOrder
  as select from eitr

  association [1..1] to I_UtilsInvcgOrdSourceType    as _UtilsInvcgOrdSourceType    on $projection.UtilsInvoicingOrdSrceType = _UtilsInvcgOrdSourceType.UtilsInvoicingOrdSrceType
  association [0..1] to I_CompanyCode                as _CompanyCode                on $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1..1] to I_UtilitiesBillingReason     as _UtilitiesBillingReason     on $projection.UtilitiesBillingReason = _UtilitiesBillingReason.UtilitiesBillingReason
  association [1..1] to I_UtilsBillgDocSimulationRsn as _UtilsBillgDocSimulationRsn on $projection.UtilsBillgSimulationReason = _UtilsBillgDocSimulationRsn.UtilsBillgSimulationReason
  association [0..1] to I_Division                   as _Division                   on $projection.Division = _Division.Division
  association [0..1] to I_UtilitiesPortion           as _UtilitiesPortion           on $projection.UtilitiesPortion = _UtilitiesPortion.UtilitiesPortion
  association [0..1] to I_BusinessPartner            as _BusinessPartner            on $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  //association[0..1] to I_ContractAccount as _ContractAccount on $projection.ContractAccount = _ContractAccount.ContractAccount

  association [0..1] to I_UtilitiesContract          as _UtilitiesContract          on $projection.UtilitiesContract = _UtilitiesContract.UtilitiesContract
  association [0..1] to I_UtilitiesBillingDocument   as _UtilitiesBillingDocument   on $projection.UtilitiesBillingDocument = _UtilitiesBillingDocument.UtilitiesBillingDocument
{
  key eitr.belnr                                 as UtilitiesBillingDocument,

      @ObjectModel.foreignKey.association: '_UtilsInvcgOrdSourceType'
  key eitr.bel_art                               as UtilsInvoicingOrdSrceType,

      @ObjectModel.foreignKey.association: '_CompanyCode'
      eitr.bukrs                                 as CompanyCode,

      @ObjectModel.foreignKey.association: '_UtilitiesPortion'
      eitr.portion                               as UtilitiesPortion,

      eitr.gpartner                              as BusinessPartner,

      //@ObjectModel.foreignKey.association: '_ContractAccount'

      eitr.vkont                                 as ContractAccount,

      @ObjectModel.foreignKey.association: '_UtilitiesContract'
      eitr.vertrag                               as UtilitiesContract,

      @ObjectModel.foreignKey.association: '_Division'
      eitr.sparte                                as Division,

      @ObjectModel.foreignKey.association: '_UtilitiesBillingReason'
      eitr.abrvorg                               as UtilitiesBillingReason,

      @ObjectModel.foreignKey.association: '_UtilsBillgDocSimulationRsn'
      cast (eitr.simulation as e_simulation_vdm) as UtilsBillgSimulationReason,
      @Semantics.booleanIndicator:true
      eitr.tobreleasd                            as UtilsBillgDocIsNotReleased,

      @Semantics.businessDate.at
      eitr.faedn                                 as NetDueDate,

      eitr.invcg_err                             as UtilsInvoicingOrderIndicator,

      _UtilsInvcgOrdSourceType,
      _CompanyCode,
      _UtilitiesBillingReason,
      _UtilsBillgDocSimulationRsn,
      _Division,
      _UtilitiesPortion,
      _BusinessPartner,
      //_ContractAccount,

      _UtilitiesContract,
      _UtilitiesBillingDocument
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"EITR"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_COMPANYCODE",
"I_DIVISION",
"I_UTILITIESBILLINGDOCUMENT",
"I_UTILITIESBILLINGREASON",
"I_UTILITIESCONTRACT",
"I_UTILITIESPORTION",
"I_UTILSBILLGDOCSIMULATIONRSN",
"I_UTILSINVCGORDSOURCETYPE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More