I_UTILITIESINSTALLATIONHIST

@EndUserText.label: 'Installation History'
@Analytics.dataCategory: #DIMENSION
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #MANDATORY
@ObjectModel.representativeKey: 'UtilitiesInstallation'
@AbapCatalog.sqlViewName: 'IEINSTHISTORY'
//@AbapCatalog.preserveKey: true

@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MASTER
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE, #ANALYTICAL_DIMENSION, #ANALYTICAL_PROVIDER, #CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE ]
@AbapCatalog.compiler.compareFilter:true
@Metadata.allowExtensions:true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION

define view I_UtilitiesInstallationHist
  as select from eanlh
  association [1..1] to I_UtilitiesInstallation        as _UtilitiesInstallation        on $projection.UtilitiesInstallation = _UtilitiesInstallation.UtilitiesInstallation

  association [0..1] to I_UtilsDepdntValdtnGroup       as _UtilsDepdntValdtnGroup       on $projection.UtilsRegDepdntValdtnGroup = _UtilsDepdntValdtnGroup.UtilsRegDepdntValdtnGroup
  association [0..1] to I_UtilsUnbilldRevnXtrapltnType as _UtilsUnbilldRevnXtrapltnType on $projection.UnbilldRevnXtrapltnType = _UtilsUnbilldRevnXtrapltnType.UnbilldRevnXtrapltnType
  association [0..1] to I_UtilsInstGroupType           as _UtilsInstGroupType           on $projection.UtilsInstallationGroupType = _UtilsInstGroupType.UtilsInstallationGroupType
  association [0..1] to I_UtilsInstGroupRole           as _UtilsInstGroupRole           on $projection.UtilsInstallationGroupRole = _UtilsInstGroupRole.UtilsInstallationGroupRole
  association [0..1] to I_UtilsTemperatureArea         as _UtilsTemperatureArea         on $projection.UtilitiesTemperatureArea = _UtilsTemperatureArea.UtilitiesTemperatureArea
  association [0..1] to I_UtilsBillingClass            as _UtilsBillingClass            on $projection.UtilitiesBillingClass = _UtilsBillingClass.UtilitiesBillingClass
  //association [0..1] to I_Industries  as _Industries on $projection.IndustrySector = _Industries.IndustrySector

  association [1..1] to I_UtilitiesRateCategory        as _UtilitiesRateCategory        on $projection.UtilitiesRateCategory = _UtilitiesRateCategory.UtilitiesRateCategory
  association [1..1] to I_MeterReadingUnit             as _MeterReadingUnit             on $projection.MeterReadingUnit = _MeterReadingUnit.MeterReadingUnit
{
  key eanlh.anlage                                            as UtilitiesInstallation,
      @Semantics.businessDate.to: true
  key cast(eanlh.bis as e_inst_end_vdm preserving type)       as UtilsInstHistValidityEndDate,
      @Semantics.businessDate.from: true
      cast(eanlh.ab  as e_inst_start_vdm preserving type)     as UtilsInstHistValidityStartDate,
      //    key eanlh.anlage as UtilitiesInstallation,

      //    @Semantics.businessDate.to: true

      //    key eanlh.bis                                      as UtilsInstHistValidityEndDate,

      //        @Semantics.businessDate.from: true

      //        eanlh.ab                                       as UtilsInstHistValidityStartDate,

      @ObjectModel.foreignKey.association: '_UtilitiesRateCategory'
      eanlh.tariftyp                                          as UtilitiesRateCategory,
      eanlh.schemanr                                          as UtilitiesBillingSchema,
      @ObjectModel.foreignKey.association: '_UtilsBillingClass'
      eanlh.aklasse                                           as UtilitiesBillingClass,
      @ObjectModel.foreignKey.association: '_MeterReadingUnit'
      eanlh.ableinh                                           as MeterReadingUnit,
      @ObjectModel.foreignKey.association: '_UtilsTemperatureArea'
      eanlh.temp_area                                         as UtilitiesTemperatureArea,
      @Semantics.booleanIndicator: true
      eanlh.konzbefr                                          as UtilsInstIsExmptFrmFrnchsFee,
      @Semantics.booleanIndicator: true
      eanlh.pauschal                                          as UtilsInstDvceAllctnIsNotAllwd,
      eanlh.konzver                                           as UtilitiesFranchiseContract,
      eanlh.billing_party                                     as UtilitiesBillingParty,
      eanlh.invoicing_party                                   as UtilitiesInvoicingParty,
      eanlh.prov_last_res                                     as ObligatorySupUtilsSrvcProvider,
      eanlh.maininst                                          as PrimaryUtilitiesInstallation,
      @ObjectModel.foreignKey.association: '_UtilsInstGroupRole'
      eanlh.instrole                                          as UtilsInstallationGroupRole,
      @ObjectModel.foreignKey.association: '_UtilsInstGroupType'
      eanlh.instgrtype                                        as UtilsInstallationGroupType,
      eanlh.highlevinst                                       as HigherLevelUtilsInstallation,
      @ObjectModel.foreignKey.association: '_UtilsUnbilldRevnXtrapltnType'
      eanlh.hochart                                           as UnbilldRevnXtrapltnType,
      @ObjectModel.foreignKey.association: '_UtilsDepdntValdtnGroup'
      eanlh.pruefgr                                           as UtilsRegDepdntValdtnGroup,
      cast ( eanlh.branche as bu_ind_sector preserving type ) as IndustrySector,

      _UtilsDepdntValdtnGroup,
      _UtilsUnbilldRevnXtrapltnType,
      _UtilsInstGroupType,
      _UtilsInstGroupRole,
      _UtilsTemperatureArea,
      _UtilsBillingClass,
      _UtilitiesInstallation,
      //    _Industries

      _UtilitiesRateCategory,
      _MeterReadingUnit

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"EANLH"
],
"ASSOCIATED":
[
"I_METERREADINGUNIT",
"I_UTILITIESINSTALLATION",
"I_UTILITIESRATECATEGORY",
"I_UTILSBILLINGCLASS",
"I_UTILSDEPDNTVALDTNGROUP",
"I_UTILSINSTGROUPROLE",
"I_UTILSINSTGROUPTYPE",
"I_UTILSTEMPERATUREAREA",
"I_UTILSUNBILLDREVNXTRAPLTNTYPE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/