I_UTILITIESBILLINGORDER

@EndUserText.label: 'Billing Order' //same as DDL description

@Analytics.dataCategory: #DIMENSION //or #CUBE or #FACT

@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IEBILLGORDER' //must start with "I"

@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'ScheduledUtilitiesBillingDate'
@Metadata.allowExtensions:true

//Privileged associations specified

@AccessControl.privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser' ]
@AbapCatalog.compiler.compareFilter:true
//@AbapCatalog.preserveKey:true

@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE, #ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE ]
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION

define view I_UtilitiesBillingOrder
  as select from etrg
  association [1..1] to I_UtilitiesInstallation      as _UtilitiesInstallation      on $projection.UtilitiesInstallation = _UtilitiesInstallation.UtilitiesInstallation
  association [1..1] to I_UtilitiesBillingReason     as _UtilitiesBillingReason     on $projection.UtilitiesBillingReason = _UtilitiesBillingReason.UtilitiesBillingReason
  association [1..1] to I_Division                   as _Division                   on $projection.Division = _Division.Division
  association [1..1] to I_CompanyCode                as _CompanyCode                on $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1..1] to I_MeterReadingUnit           as _MeterReadingUnit           on $projection.MeterReadingUnit = _MeterReadingUnit.MeterReadingUnit
  association [1..1] to I_UtilitiesPortion           as _UtilitiesPortion           on $projection.UtilitiesPortion = _UtilitiesPortion.UtilitiesPortion
  association [1..1] to I_UtilsBillingOrderStatus    as _UtilsBillingOrderStatus    on $projection.UtilsBillingOrderStatus = _UtilsBillingOrderStatus.UtilsBillingOrderStatus
  association [1..1] to I_User                       as _CreatedByUser              on $projection.UtilsBillgOrderCreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                       as _LastChangedByUser          on $projection.UtilsBillgOrdLastChangedByUser = _LastChangedByUser.UserID
  association [1..1] to I_UtilitiesBillingReason     as _SuppressedUtilsBillgReason on $projection.SuppressedUtilsBillgReason = _SuppressedUtilsBillgReason.UtilitiesBillingReason
  association [1..1] to I_UtilsBillingOrderIndicator as _UtilsBillingOrderIndicator on $projection.UtilsBillingOrderIndicator = _UtilsBillingOrderIndicator.UtilsBillingOrderIndicator
{
      @ObjectModel.foreignKey.association:'_UtilitiesInstallation'
  key etrg.anlage                                                      as UtilitiesInstallation,

      @Semantics.businessDate.at: true
  key cast(etrg.abrdats as e_schedld_billg_dte_vdm preserving type)    as ScheduledUtilitiesBillingDate,

      @ObjectModel.foreignKey.association:'_UtilitiesBillingReason'
  key cast( etrg.abrvorg as e_abrvorg_vdm preserving type)             as UtilitiesBillingReason,

      @ObjectModel.foreignKey.association:'_CompanyCode'
      etrg.bukrs                                                       as CompanyCode,

      @ObjectModel.foreignKey.association:'_Division'
      etrg.sparte                                                      as Division,

      @ObjectModel.foreignKey.association:'_UtilsBillingOrderStatus'
      etrg.trigstat                                                    as UtilsBillingOrderStatus,

      @ObjectModel.foreignKey.association:'_UtilitiesPortion'
      etrg.portion                                                     as UtilitiesPortion,

      @ObjectModel.foreignKey.association:'_MeterReadingUnit'
      cast(etrg.ableinh as ableinheit preserving type)                 as MeterReadingUnit,

      cast(etrg.adatsoll as e_schedld_mtrrdng_dte_vdm preserving type) as ScheduledMeterReadingDate,

      etrg.zuorddat                                                    as UtilsBillgPeriodAllocationDate,

      @Semantics.systemDate.createdAt: true
      etrg.erdat                                                       as UtilsBillgOrderCreationDate,

      @Semantics.user.createdBy: true
      etrg.ernam                                                       as UtilsBillgOrderCreatedByUser,

      @Semantics.systemDate.lastChangedAt: true
      etrg.aedat                                                       as UtilsBillgOrderLastChangeDate,

      @Semantics.user.lastChangedBy: true
      etrg.aenam                                                       as UtilsBillgOrdLastChangedByUser,

      cast( etrg.abrdatsu as e_abrdatsu_vdm preserving type)           as SuppressedUtilsSchedldBillgDte,

      cast( etrg.adatsollu as e_adatsollu_vdm preserving type)         as SuppressedSchedldMtrRdngDte,

      @ObjectModel.foreignKey.association: '_SuppressedUtilsBillgReason'
      cast( etrg.abrvorgu as e_abrvorgu_vdm preserving type)           as SuppressedUtilsBillgReason,

      @ObjectModel.foreignKey.association: '_UtilsBillingOrderIndicator'
      @Semantics.booleanIndicator:true
      cast( etrg.billg_err as e_billgordind_vdm preserving type)       as UtilsBillingOrderIndicator,

      /* Associations */
      _UtilitiesInstallation,
      _UtilitiesBillingReason,
      _Division,
      _CompanyCode,
      _MeterReadingUnit,
      _UtilitiesPortion,
      _UtilsBillingOrderStatus,
      _CreatedByUser,
      _LastChangedByUser,
      _SuppressedUtilsBillgReason,
      _UtilsBillingOrderIndicator
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"ETRG"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_DIVISION",
"I_METERREADINGUNIT",
"I_USER",
"I_UTILITIESBILLINGREASON",
"I_UTILITIESINSTALLATION",
"I_UTILITIESPORTION",
"I_UTILSBILLINGORDERINDICATOR",
"I_UTILSBILLINGORDERSTATUS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/