I_TRANSPCHARGEITEM
Transportation Charge Item
I_TRANSPCHARGEITEM is a CDS View in S/4HANA. Transportation Charge Item. 6 CDS views read from this table.
CDS Views using this table (6)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_CollabnMngFrtOrdChargeItemVH | view | from | CONSUMPTION | Trasnportation Order Charge Items |
| I_FrtCarrInvcInvcAmt | view_entity | inner | COMPOSITE | Invoice Amount for Freight Carrier Invc |
| I_FrtCarrInvcVarcAmt | view_entity | inner | COMPOSITE | Variance Amount for Freight Carrier Invoice |
| I_TranspChargeItemEnrcd | view | from | COMPOSITE | Transportation Charge Item enriched |
| P_FrtOrdAccrChrgItem | view | from | COMPOSITE | |
| R_TranspOrderChargeItemTP | view_entity | from | TRANSACTIONAL | Transportation Charge Item |
@EndUserText: {label: 'Transportation Charge Item'}
//@ClientHandling.algorithm: #SESSION_VARIABLE
//@AbapCatalog: {sqlViewName: 'ITCHRGITEM',
// compiler: {compareFilter: true}}
@ObjectModel: {representativeKey: 'TranspChargeItemUUID',
usageType: {serviceQuality: #C,
sizeCategory: #XXL,
dataClass: #TRANSACTIONAL}}
@VDM: {viewType: #BASIC,
lifecycle.contract.type: #NONE}
@AccessControl: {authorizationCheck: #PRIVILEGED_ONLY,
privilegedAssociations: ['_TranspChargeItemElement'],
personalData.blocking: #('TRANSACTIONAL_DATA')}
define view entity I_TranspChargeItem
as select from /scmtms/d_tchrgi
/* Business Object related Node Associations*/
association [0..*] to I_TranspChargeItemElement as _TranspChargeItemElement on $projection.TranspChargeItemUUID = _TranspChargeItemElement.TranspChargeItemUUID
/* Foreign Key and Text Associations */
association [0..1] to I_InvoicingStatus as _TranspChargeItmInvcgStatus on $projection.TranspChargeItmInvcgStatus = _TranspChargeItmInvcgStatus.InvoicingStatus
association [0..1] to I_TranspChargeCalcLevel as _TranspChargeCalcLevel on $projection.TranspChargeCalcLevel = _TranspChargeCalcLevel.TranspChargeCalcLevel
// S4CE 1902
association [0..1] to I_TranspChargeCalcStatus as _TranspChargeCalcStatus on $projection.TranspChargeCalcStatus = _TranspChargeCalcStatus.TranspChargeCalcStatus
association [0..1] to I_BusinessPartner as _BusinessPartner on $projection.BusinessPartnerUUID = _BusinessPartner.BusinessPartnerUUID
association [0..1] to I_Currency as _TranspChargeDocumentCurrency on $projection.TranspChrgItemDocCurrency = _TranspChargeDocumentCurrency.Currency
association [0..1] to I_Currency as _TranspChrgItemLoclCurrency on $projection.TranspChrgItemLoclCurrency = _TranspChrgItemLoclCurrency.Currency
association [0..1] to I_TransportationAgreement as _TransportationAgreement on $projection.TransportationAgreementUUID = _TransportationAgreement.TransportationAgreementUUID
association [0..1] to I_TranspChargeExchRate as _TranspChargeExchRate on $projection.TranspChargeItemUUID = _TranspChargeExchRate.TranspChargeItemUUID
and _TranspChargeExchRate.TranspChrgIsLoclExchRate is not initial
association [0..1] to I_TranspDimnWeightProfile as _TranspDimnWeightProfile on $projection.TranspDimnWeightProfile = _TranspDimnWeightProfile.TranspDimnWeightProfile
association [0..1] to I_TranspChargeCalcSheet as _TranspChargeCalcSheet on $projection.TranspChrgCalcSheetUUID = _TranspChargeCalcSheet.TranspChrgCalcSheetUUID
association [0..*] to I_PaymentTermsText as _Text on $projection.PaymentTerms = _Text.PaymentTerms
//END
{
key cast(db_key as /scmtms/vdm_chrg_itm_db_key preserving type) as TranspChargeItemUUID,
parent_key as TransportationChargesObjUUID,
cast(ref_key as /scmtms/vdm_tor_db_key preserving type) as RefTransportationOrderNodeUUID,
cast(ref_root_key as /scmtms/vdm_tor_db_key preserving type) as RefTransportationOrderUUID,
@ObjectModel.foreignKey.association: '_TranspChargeCalcLevel'
root_level as TranspChargeCalcLevel,
@ObjectModel.foreignKey.association: '_TranspChargeItmInvcgStatus'
cast(invoicing as /scmtms/vdm_itm_invoice_status preserving type) as TranspChargeItmInvcgStatus,
// S4CE 1902
host_root_key as TranspChargeHostDocumentUUID,
@ObjectModel.foreignKey.association: '_TransportationAgreement'
uuid057 as TransportationAgreementUUID,
@ObjectModel.foreignKey.association: '_TranspChargeCalcSheet'
uuid020 as TranspChrgCalcSheetUUID,
@ObjectModel.foreignKey.association: '_TranspChargeCalcStatus'
calc_status as TranspChargeCalcStatus,
@ObjectModel.foreignKey.association: '_BusinessPartner'
cast(party_uuid as bu_partner_guid preserving type) as BusinessPartnerUUID,
//fagrmntid044 as TransportationAgreement, // name and association should be maintained
//fagrmntvsid045 as TransportationAgreementVersion, // This field is required in near future
dim_wt_profile as TranspDimnWeightProfile,
exchdate_doc as ExchangeRateDate,
@ObjectModel.foreignKey.association: '_TranspChargeDocumentCurrency'
// @Semantics.currencyCode: true
currcode016 as TranspChrgItemDocCurrency,
@Semantics.amount.currencyCode: 'TranspChrgItemDocCurrency'
//cast(amount as /scmtms/amount preserving type) * 10000 as TranspChrgItmTotAmtInDocCrcy,
cast( cast( amount as abap.dec(31,6) ) * 10000 as abap.curr(31,2) ) as TranspChrgItmTotAmtInDocCrcy,
@ObjectModel.foreignKey.association: '_TranspChrgItemLoclCurrency'
// @Semantics.currencyCode: true
currcode016lcl as TranspChrgItemLoclCurrency,
@Semantics.amount.currencyCode: 'TranspChrgItemLoclCurrency'
//cast(amountlcl as /scmtms/amount preserving type) * 10000 as TranspChrgItmTotAmtInLoclCrcy,
cast( cast( amountlcl as abap.dec(31,6) ) * 10000 as abap.curr(31,2) ) as TranspChrgItmTotAmtInLoclCrcy,
is_header_charge as TranspChargeItemIsHeaderCharge,
calcdate_tstmp as TranspChargeCalculationDateTme,
@ObjectModel.text.association: '_Text'
zterm as PaymentTerms,
posting_date as TranspChargePostingDate,
type_code as TranspChargeItemTypeCode,
// END
host_key as TranspChargeCalcLevelRefUUID,
fix_calcdate as TranspChrgCalcDteTmeIsChanged,
_TranspChargeItemElement,
_TranspChargeItmInvcgStatus,
_TranspChargeCalcLevel,
// S4CE 1902
_TranspChargeCalcStatus,
_BusinessPartner,
_TranspChargeDocumentCurrency,
_TranspChrgItemLoclCurrency,
_TransportationAgreement,
_TranspChargeExchRate,
_TranspDimnWeightProfile,
_TranspChargeCalcSheet,
_Text
// END
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"/SCMTMS/D_TCHRGI"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CURRENCY",
"I_INVOICINGSTATUS",
"I_PAYMENTTERMSTEXT",
"I_TRANSPCHARGECALCLEVEL",
"I_TRANSPCHARGECALCSHEET",
"I_TRANSPCHARGECALCSTATUS",
"I_TRANSPCHARGEEXCHRATE",
"I_TRANSPCHARGEITEMELEMENT",
"I_TRANSPDIMNWEIGHTPROFILE",
"I_TRANSPORTATIONAGREEMENT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/