I_TASKLISTTOFUNCNLLOCALLOC

CDS View

Allocation of Task Lists to Functional Location

I_TASKLISTTOFUNCNLLOCALLOC is a CDS View in S/4HANA. Allocation of Task Lists to Functional Location. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
P_TaskListToFuncnlLocAlloc view from COMPOSITE 
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.sqlViewName: 'ITSKLSTTOFLALLOC'
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Allocation of Task Lists to Functional Location'
@ObjectModel.representativeKey: [ 'ItemCounter' ]
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #M
@VDM.viewType: #BASIC


define view I_TaskListToFuncnlLocAlloc
  as select from tapl

  association [1..1] to I_FunctionalLocation      as _FunctionalLocation      on  _FunctionalLocation.FunctionalLocation = $projection.FunctionalLocation

  association [1..1] to I_MaintenanceTaskList     as _MaintenanceTaskList     on  _MaintenanceTaskList.TaskListType         = $projection.TaskListType
                                                                              and _MaintenanceTaskList.TaskListGroup        = $projection.TaskListGroup
                                                                              and _MaintenanceTaskList.TaskListGroupCounter = $projection.TaskListGroupCounter

  association [1..1] to I_MaintenanceTaskListType as _MaintenanceTaskListType on  _MaintenanceTaskListType.TaskListType = $projection.TaskListType

{
  key tapl.tplnr                                                  as   FunctionalLocation,
      
      @ObjectModel.foreignKey.association: '_MaintenanceTaskListType'
  key tapl.plnty                                                  as   TaskListType,
  
  key tapl.plnnr                                                  as   TaskListGroup,
  
  key tapl.plnal                                                  as   TaskListGroupCounter,
  
  key tapl.zkriz                                                  as   AdditionalCriteriaCounter,
  
  key tapl.zaehl                                                  as   ItemCounter,
      
      tapl.datuv                                                  as   ValidityStartDate,
      
      tapl.loekz                                                  as   IsDeleted,
      
      tapl.aennr                                                  as   ChangeNumber,
      
      tapl.iwerk                                                  as   MaintenancePlanningPlant,
      
      @Semantics.systemDate.createdAt: true
      tapl.andat                                                  as   CreationDate,
      
      @Semantics.user.createdBy: true
      cast(tapl.annam as vdm_createdbyuserid preserving type)     as   CreatedByUser,
      
      @Semantics.systemDate.lastChangedAt: true
      tapl.aedat                                                  as   LastChangeDate,
      
      @Semantics.user.lastChangedBy: true
      cast(tapl.aenam as vdm_lastchangedbyuserid preserving type) as   LastChangedByUser,


      /* Associations */
      _FunctionalLocation,
      _MaintenanceTaskList,
      _MaintenanceTaskListType
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"TAPL"
],
"ASSOCIATED":
[
"I_FUNCTIONALLOCATION",
"I_MAINTENANCETASKLIST",
"I_MAINTENANCETASKLISTTYPE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More