I_STOCKTRANSPORTORDER

CDS View

Stock Transport Order

I_STOCKTRANSPORTORDER is a CDS View in S/4HANA. Stock Transport Order. 5 CDS views read from this table.

Used by 5 CDS view(s)

CDS Views using this table (5)

ViewTypeJoinVDMDescription
C_RFDYStockTransportOrder view from CONSUMPTION Release for Delivery Stock Transport Order
I_StockTransportOrderItem view inner BASIC Stock Transport Order Item
I_StockTransportOrderShipping view inner BASIC STO Shipping Data
I_StockTransportOrderStdVH view from COMPOSITE CDS View for Stock Transport Order
I_StockTransptOrdScheduleLine view inner BASIC CDS View for STO Schedule Line 
@AbapCatalog.sqlViewName: 'ISTOCKHEADER'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true 
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Stock Transport Order'
@VDM.viewType : #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.compositionRoot:true
@ObjectModel.representativeKey: 'PurchaseOrder'
@ObjectModel.supportedCapabilities: [ #SEARCHABLE_ENTITY, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@Metadata.ignorePropagatedAnnotations:true

define view I_StockTransportOrder as select from I_PurchaseOrder

association [0..*] to I_StockTransportOrderItem as _StockTransportOrderItem on  $projection.PurchaseOrder = _StockTransportOrderItem.PurchaseOrder

association [1..1] to E_PurchasingDocument           as _PurchaseOrderExtension  on  $projection.PurchaseOrder = _PurchaseOrderExtension.PurchasingDocument

{
  key cast (PurchaseOrder as vdm_stocktransportorder preserving type) as PurchaseOrder,
  @ObjectModel.foreignKey.association: '_PurchaseOrderType'
  PurchaseOrderType,
  PurchaseOrderSubtype,
  CreatedByUser,
  CreationDate,
  PurchaseOrderDate,
  @ObjectModel.foreignKey.association: '_Language'
  Language,
  PurchasingDocumentDeletionCode,
  ReleaseIsNotCompleted,
  @ObjectModel.foreignKey.association: '_CompanyCode'
  CompanyCode,
  @ObjectModel.foreignKey.association: '_PurchasingOrganization'
  PurchasingOrganization,
  @ObjectModel.foreignKey.association: '_PurchasingGroup'
  PurchasingGroup,
  @ObjectModel.foreignKey.association: '_Supplier'
  Supplier,
  ManualSupplierAddressID,
  SupplierAddressID,
  SupplierRespSalesPersonName,
  SupplierPhoneNumber,
  @ObjectModel.foreignKey.association: '_SupplyingSupplier'
  SupplyingSupplier,
  @ObjectModel.foreignKey.association: '_SupplyingPlant'
  SupplyingPlant,
  @ObjectModel.foreignKey.association: '_InvoicingParty'
  InvoicingParty,
  PaymentTerms,
  PurchasingDocumentCondition,
  PricingProcedure,
  DocumentCurrency,
  ValidityStartDate,
  ValidityEndDate,
  ExchangeRate,
  ExchangeRateIsFixed,
  LastChangeDateTime,
  
  @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
  _StockTransportOrderItem,
  
  _PurchaseOrderType,
  _CompanyCode,
  _CreatedByUser,
  _Supplier,
  _SupplyingSupplier,
  _InvoicingParty,
  _PurchasingOrganization,
  _PurchasingGroup,
  _DocumentCurrency,
  _SupplyingPlant,
  _Language
}

where SupplyingPlant <> ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PURCHASEORDER"
],
"ASSOCIATED":
[
"E_PURCHASINGDOCUMENT",
"I_COMPANYCODE",
"I_CURRENCY",
"I_LANGUAGE",
"I_PLANT",
"I_PURCHASINGDOCUMENTTYPE",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_STOCKTRANSPORTORDERITEM",
"I_SUPPLIER",
"I_USER"
],
"BASE":
[
"I_PURCHASEORDER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More