I_SRVCDOCDOCUMENTFLOW

CDS View

Trans Hist of Preced and Follow-Up Trans

I_SRVCDOCDOCUMENTFLOW is a CDS View in S/4HANA. Trans Hist of Preced and Follow-Up Trans. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
C_SrvcDocDocumentFlow view from CONSUMPTION Transac Hist of Orders and Confirmations
R_SrvcDocDocumentFlow view from COMPOSITE Transaction flow for Service Transaction 
@AbapCatalog.sqlViewName: 'ISRVCDOCFLW'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Trans Hist of Preced and Follow-Up Trans'
@VDM: {
  viewType: #COMPOSITE
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}
define view I_SrvcDocDocumentFlow
  as select from I_ServiceDocumentEnhcd inner join I_ServiceDocumentSuccessor as _ServiceDocSuccssr  on _ServiceDocSuccssr.ServiceDocumentUUID  = I_ServiceDocumentEnhcd.ServiceDocumentUUID
                                                                                                      and _ServiceDocSuccssr.ServiceObjectType    = I_ServiceDocumentEnhcd.ServiceObjectType
                                                                                                      and not (
                                                                                                      _ServiceDocSuccssr.ServiceDocSuccessorBusObjType = _ServiceDocSuccssr.ServiceObjectType 
                                                                                                      and I_ServiceDocumentEnhcd.ServiceDocumentUUID = _ServiceDocSuccssr.ServiceDocumentSuccessorUUID)
{
  key     I_ServiceDocumentEnhcd.ServiceDocument,
  key     _ServiceDocSuccssr.ServiceDocumentRelationUUID,
          _ServiceDocSuccssr.ServiceDocSuccessor           as CustMgmtPrdcssrTransactionKey,
          _ServiceDocSuccssr.ServiceDocSuccessorBusObjType as PrdcssrSuccssrDocObjectType,
          _ServiceDocSuccssr.ServiceDocSuccessorBusObjType as ServiceDocSuccessorBusObjType,
          _ServiceDocSuccssr.ServiceObjectType as ServiceDocPrdcssrBusObjType,
          _ServiceDocSuccssr.ServiceDocumentSuccessorUUID  as SrvcMgmtObjectUUID,
          I_ServiceDocumentEnhcd.ServiceObjectType,
          cast( ' ' as abap.char( 1 ))                       as ReltdSrvcDocIsPredecessor,
          case I_ServiceDocumentEnhcd.ServiceObjectType
          when 'BUS2000117'
          then  I_ServiceDocumentEnhcd._ServiceDocPredecessor[ServiceDocumentRelationType = 'VONA' and ServiceDocumentRelationKind = 'A']._ServiceDoc.ServiceDocument
          when 'BUS2000116' then  I_ServiceDocumentEnhcd.ServiceDocument
          end                                                as ServiceOrder,

          I_ServiceDocumentEnhcd.ServiceDocumentUUID,

          //          case ServiceObjectType

          //          when 'BUS2000117'

          //          then _ServiceDocPredecessor[ServiceDocumentRelationType = 'VONA' and ServiceDocumentRelationKind = 'A']._ServiceDoc.ServiceDocumentUUID

          //          when 'BUS2000116' then ServiceDocumentUUID

          //          end                                                as ServiceDocUUID

           I_ServiceDocumentEnhcd.ServiceDocumentType,
           I_ServiceDocumentEnhcd.ResponsibleEmployee                                as RespEmployeeBusinessPartnerId,
           I_ServiceDocumentEnhcd.SalesOrganization,
           I_ServiceDocumentEnhcd.SalesOffice,
           I_ServiceDocumentEnhcd.SalesGroup,
           I_ServiceDocumentEnhcd.Division,
           I_ServiceDocumentEnhcd.DistributionChannel,
           I_ServiceDocumentEnhcd.SalesOrganizationOrgUnitID,
           I_ServiceDocumentEnhcd.SalesOfficeOrgUnitID,
           I_ServiceDocumentEnhcd.SalesGroupOrgUnitID,
           I_ServiceDocumentEnhcd.ServiceOrganization,
           _ServiceDocSuccssr.ServiceDocumentRelationType as ServiceDocumentRelationType

}
union 
select from I_ServiceDocumentEnhcd inner join I_ServiceDocumentPredecessor as _ServiceDocPrdcssr on _ServiceDocPrdcssr.ServiceDocumentUUID  = I_ServiceDocumentEnhcd.ServiceDocumentUUID
                                                                                                          and _ServiceDocPrdcssr.ServiceObjectType    = I_ServiceDocumentEnhcd.ServiceObjectType
                                                                                                          and not (
                                                                                                      _ServiceDocPrdcssr.ServiceDocPrdcssrBusObjType = _ServiceDocPrdcssr.ServiceObjectType 
                                                                                                      and I_ServiceDocumentEnhcd.ServiceDocumentUUID = _ServiceDocPrdcssr.ServiceDocumentPredecessorUUID )                                                                                                          
{
  key    I_ServiceDocumentEnhcd.ServiceDocument,
  key   _ServiceDocPrdcssr.ServiceDocumentRelationUUID,
        _ServiceDocPrdcssr.CustMgmtPrdcssrTransactionKey  as CustMgmtPrdcssrTransactionKey,
        _ServiceDocPrdcssr.ServiceDocPrdcssrBusObjType    as PrdcssrSuccssrDocObjectType,
        _ServiceDocPrdcssr.ServiceObjectType as ServiceDocSuccessorBusObjType,
        _ServiceDocPrdcssr.ServiceDocPrdcssrBusObjType as ServiceDocPrdcssrBusObjType,

        _ServiceDocPrdcssr.ServiceDocumentPredecessorUUID as SrvcMgmtObjectUUID,

        I_ServiceDocumentEnhcd.ServiceObjectType,
        cast( 'X' as abap.char( 1 ))                          as ReltdSrvcDocIsPredecessor,

        case  I_ServiceDocumentEnhcd.ServiceObjectType
        when 'BUS2000117'
        then  I_ServiceDocumentEnhcd._ServiceDocPredecessor[ServiceDocumentRelationType = 'VONA' and ServiceDocumentRelationKind = 'A']._ServiceDoc.ServiceDocument
        when 'BUS2000116' then  I_ServiceDocumentEnhcd.ServiceDocument
        end                                                   as ServiceOrder,

         I_ServiceDocumentEnhcd.ServiceDocumentUUID,

        //        case ServiceObjectType

        //        when 'BUS2000117'

        //        then _ServiceDocPredecessor[ServiceDocumentRelationType = 'VONA' and ServiceDocumentRelationKind = 'A']._ServiceDoc.ServiceDocumentUUID

        //        when 'BUS2000116' then ServiceDocumentUUID

        //        end                                                   as ServiceDocUUID

         I_ServiceDocumentEnhcd.ServiceDocumentType,
         I_ServiceDocumentEnhcd.ResponsibleEmployee                                   as RespEmployeeBusinessPartnerId,
         I_ServiceDocumentEnhcd.SalesOrganization,
         I_ServiceDocumentEnhcd.SalesOffice,
         I_ServiceDocumentEnhcd.SalesGroup,
         I_ServiceDocumentEnhcd.Division,
         I_ServiceDocumentEnhcd.DistributionChannel,
         I_ServiceDocumentEnhcd.SalesOrganizationOrgUnitID,
         I_ServiceDocumentEnhcd.SalesOfficeOrgUnitID,
         I_ServiceDocumentEnhcd.SalesGroupOrgUnitID,
         I_ServiceDocumentEnhcd.ServiceOrganization,
         _ServiceDocPrdcssr.ServiceDocumentRelationType as ServiceDocumentRelationType
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SERVICEDOCUMENTENHCD",
"I_SERVICEDOCUMENTPREDECESSOR",
"I_SERVICEDOCUMENTSUCCESSOR"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More