I_SPECPRIMIDFRFORSPECCATMIN

CDS View

Specification primary identifier for a category

I_SPECPRIMIDFRFORSPECCATMIN is a CDS View in S/4HANA. Specification primary identifier for a category. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_SpecDefIdfrForSpecCat view inner COMPOSITE Default description of a specification 
@AbapCatalog.sqlViewName: 'ISPECIDFRPRIM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true

@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MASTER

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #COMPOSITE

@EndUserText.label: 'Specification primary identifier for a category'

define view I_SpecPrimIdfrForSpecCatMin
  with parameters
    @Environment.systemField: #SYSTEM_DATE
    P_KeyDate               : sydate,
    P_SpecificationCategory : eseobjtype
  as select from I_SpecIdentifierForKeyDate( P_KeyDate: $parameters.P_KeyDate ) as idn

    inner join   I_SpecificationForKeyDate( P_KeyDate: $parameters.P_KeyDate )  as specification    on specification.SpecificationInternalID = idn.SpecificationInternalID

    inner join   I_SpecTypeAssignedCategory                                     as spectypecategory on  spectypecategory.SpecificationCategory = $parameters.P_SpecificationCategory
                                                                                                    and spectypecategory.SpecificationType     = specification.SpecificationType

    inner join   I_SpecIdnListingDefinition                                     as listingCust      on  listingCust.SpecificationIdnListing     = 'D_DEFAULT'
                                                                                                    and listingCust.SpecificationIdnListingPrio = '0001'
                                                                                                    and listingCust.SpecificationIdnListingPos  = '0002'
                                                                                                    and listingCust.SpecificationCategory       = $parameters.P_SpecificationCategory
                                                                                                    and listingCust.SpecIdfgDescCategory        = idn.SpecIdfgDescCategory
                                                                                                    and listingCust.SpecIdfgDescType            = idn.SpecIdfgDescType
{
  key      min(idn.SpecIdfgDescInternalID) as SpecIdfgDescInternalID,

           idn.SpecificationInternalID,
           idn.SpecIdfgDescLanguage,
           
           //Associations

           idn._SpecificationForKeyDate   as _SpecificationForKeyDate        

}
group by
  idn.SpecificationInternalID,
  idn.SpecIdfgDescLanguage
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SPECIDENTIFIERFORKEYDATE",
"I_SPECIDNLISTINGDEFINITION",
"I_SPECIFICATIONFORKEYDATE",
"I_SPECTYPEASSIGNEDCATEGORY"
],
"ASSOCIATED":
[
"I_SPECIFICATIONFORKEYDATE"
],
"BASE":
[
"I_SPECIDENTIFIERFORKEYDATE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More