I_SERVICEQUOTATIONSTATUSTEXT

CDS View

Service Quotation Status Text

I_SERVICEQUOTATIONSTATUSTEXT is a CDS View in S/4HANA. Service Quotation Status Text. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_SrvcQtanLifeCycleStatusText view union COMPOSITE Srvc Quotation Life Cycle Status - Txt 
@EndUserText.label: 'Service Quotation Status Text'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog: {
  sqlViewName: 'ISERVQTANSTATTXT',
  compiler.compareFilter: true,
  preserveKey: true
}
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl.authorizationCheck: #NOT_REQUIRED

@ObjectModel: {
   dataCategory: #TEXT,
   representativeKey: 'ServiceQuotationStatus',
   usageType: {
     dataClass:      #META,
     serviceQuality: #B,
     sizeCategory:   #S
   }
}

@Metadata.ignorePropagatedAnnotations: true

@Search.searchable: true

define view I_ServiceQuotationStatusText
  as select from dd07t 
  association [1..1] to I_ServiceQuotationStatus as _ServiceQuotationStatus on $projection.ServiceQuotationStatus = _ServiceQuotationStatus.ServiceQuotationStatus                                
  association [1..1] to I_Language               as _Language               on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_ServiceQuotationStatus'
      @ObjectModel.text.element: ['ServiceQuotationStatusName']
  key cast(domvalue_l as crms4_qtan_stat_lc)                  as ServiceQuotationStatus,
      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language'
  key ddlanguage                                              as Language,
      @Consumption.hidden: true
      dd07t.domvalue_l                                        as DomainValue,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @Semantics.text: true
      cast(ddtext as crms4_qtan_stat_lc_name preserving type) as ServiceQuotationStatusName,

      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT,
                                      #TO_COMPOSITION_ROOT]
      _ServiceQuotationStatus,
      _Language
}
where
      domname  = 'CRMS4_QTAN_STAT_LC'      
  and as4local = 'A'
  and as4vers  = '0000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_SERVICEQUOTATIONSTATUS"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More