I_SERVICEENTRYSHEETBASIC

@AbapCatalog.sqlViewName: 'ISRVCENTRSHTBSC'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: [ '_SESWorkflowStatus' ]
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Service Entry Sheet Basic'
@VDM.viewType : #BASIC

@ObjectModel: {
   compositionRoot: true,
   representativeKey: 'ServiceEntrySheet',
   usageType.serviceQuality: #A,
   usageType.sizeCategory: #L,
   usageType.dataClass: #TRANSACTIONAL
}

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

define view I_ServiceEntrySheetBasic
  as select from mmpur_ses_header as Document

  association [1..*] to I_ServiceEntrySheetItemBasic  as _ServiceEntrySheetItem      on  $projection.ServiceEntrySheet = _ServiceEntrySheetItem.ServiceEntrySheet
  association [0..1] to I_Supplier                    as _Supplier                   on  $projection.Supplier = _Supplier.Supplier
  association [0..1] to I_SrvcEntrShtApprovalStatus   as _ApprovalStatusValueHelp    on  $projection.ApprovalStatus = _ApprovalStatusValueHelp.ApprovalStatus
  association [1..1] to I_SESWorkflowStatus           as _SESWorkflowStatus          on  $projection.ServiceEntrySheet = _SESWorkflowStatus.ServiceEntrySheet
  association [0..1] to I_SrvcEntrShtRespUsrValueHelp as _ResponsiblePersonValueHelp on  $projection.ResponsiblePerson = _ResponsiblePersonValueHelp.EmploymentInternalID
  association [0..1] to I_User                        as _CreatedByUser              on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                        as _LastChangeUser             on  $projection.LastChangeUser = _LastChangeUser.UserID
{
  key Document.serviceentrysheet                                           as ServiceEntrySheet,
      Document.serviceentrysheetuuid                                       as ServiceEntrySheetUUID,
      @Semantics.text: true
      Document.name                                                        as ServiceEntrySheetName,
      @ObjectModel.foreignKey.association: '_Supplier'
      Document.supplier                                                    as Supplier,
      Document.referencepurchaseorder                                      as PurchaseOrder,
      Document.deletioncode                                                as IsDeleted,
      @ObjectModel.foreignKey.association: '_ApprovalStatusValueHelp'
      case when Document.deletioncode is not initial
           then cast( '60' as mmpur_ses_approval_status )
           when Document.deletioncode is initial
           then cast( Document.approvalstatus as mmpur_ses_approval_status preserving type )
      end                                                                  as ApprovalStatus,

      Document.approval_date_time                                          as ApprovalDateTime,
      @Consumption.valueHelp: '_ResponsiblePersonValueHelp'
      Document.responsibleperson                                           as ResponsiblePerson,
      Document.originobjecttype                                            as OriginObjectType,
      @Semantics.currencyCode:true
      Document.currency                                                    as Currency,
      Document.mblnr                                                       as MaterialDocument,
      Document.mjahr                                                       as MaterialDocumentYear,

      Document.purchasingorganization                                      as PurchasingOrganization,
      Document.purchasinggroup                                             as PurchasingGroup,

      Document.crea_date_time                                              as CreationDateTime,
      @Semantics.user.createdBy: true
      Document.crea_uname                                                  as CreatedByUser,
      Document.lchg_date_time                                              as LastChangeDateTime,
      @Semantics.user.lastChangedBy: true
      Document.lchg_uname                                                  as LastChangeUser,

// Data Privacy and Protection

      @UI.hidden: true
      @Consumption.hidden: true
      @ObjectModel.readOnly: true
      Document.iseopblocked                                                as IsEndOfPurposeBlocked,

      Document.externalsystem                                              as PurgDocExternalSystem,
      Document.externalreferenceid                                         as PurgDocExternalReference,
      Document.ext_rev_tmstmp                                              as ExternalRevisionDateTime,

      Document.postingdate                                                 as PostingDate,
      Document.knumv                                                       as PricingDocument,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _ServiceEntrySheetItem,
      _Supplier,
      _ApprovalStatusValueHelp,
      _ResponsiblePersonValueHelp,
      _CreatedByUser,
      _LastChangeUser,
      _SESWorkflowStatus
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"MMPUR_SES_HEADER"
],
"ASSOCIATED":
[
"I_SERVICEENTRYSHEETITEMBASIC",
"I_SESWORKFLOWSTATUS",
"I_SRVCENTRSHTAPPROVALSTATUS",
"I_SRVCENTRSHTRESPUSRVALUEHELP",
"I_SUPPLIER",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/