I_SALESORDERBILLINGPLAN

CDS View

Billing Plan of Sales Order

I_SALESORDERBILLINGPLAN is a CDS View in S/4HANA. Billing Plan of Sales Order. It contains 20 fields. 2 CDS views read from this table.

Used by 2 CDS view(s) 20 fields

CDS Views using this table (2)

ViewTypeJoinVDMDescription
A_SalesOrderBillingPlan view_entity from COMPOSITE Header Billing Plan
R_SalesOrderBillingPlanTP view_entity from TRANSACTIONAL Billing Plan for Sales Order - TP

Fields (20)

KeyField CDS FieldsUsed in Views
KEY BillingPlan BillingPlan 2
KEY SalesOrder SalesOrder 2
_BillingPlanCategory _BillingPlanCategory 1
_BillingPlanType _BillingPlanType 1
_BillingPlanUsageCategory _BillingPlanUsageCategory 1
_EndDateRule _EndDateRule 1
_StartDateRule _StartDateRule 1
BillingPlanCategory BillingPlanCategory 2
BillingPlanEndDate BillingPlanEndDate 2
BillingPlanEndDateRule BillingPlanEndDateRule 2
BillingPlanSearchTerm BillingPlanSearchTerm 2
BillingPlanStartDate BillingPlanStartDate 2
BillingPlanStartDateRule BillingPlanStartDateRule 2
BillingPlanType BillingPlanType 2
BillingPlanUsageCategory BillingPlanUsageCategory 1
DistributionChannel DistributionChannel 1
OrganizationDivision OrganizationDivision 1
ReferenceBillingPlan ReferenceBillingPlan 2
SalesOrderType SalesOrderType 1
SalesOrganization SalesOrganization 1 
@EndUserText.label: 'Billing Plan of Sales Order'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   },
   supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET]
}
@Metadata.ignorePropagatedAnnotations: true

define view entity I_SalesOrderBillingPlan
  as select from I_SalesDocumentBillingPlan as SalesDocumentBillingPlan

  association [1..1] to I_SalesOrder                  as _SalesOrder                  on  _SalesOrder.SalesOrder                      = $projection.SalesOrder   

  association [0..*] to I_SalesOrderBillingPlanItem   as _SalesOrderBillingPlanItem   on  _SalesOrderBillingPlanItem.SalesOrder     = $projection.SalesOrder    

{
        @ObjectModel.foreignKey.association: '_SalesOrder'
  key   cast(SalesDocument as vdm_sales_order preserving type)      as SalesOrder,

  key   SalesDocumentBillingPlan.BillingPlan,
        
        @ObjectModel.foreignKey.association: '_BillingPlanCategory'
        SalesDocumentBillingPlan.BillingPlanCategory,
        
        @ObjectModel.foreignKey.association: '_BillingPlanUsageCategory'
        SalesDocumentBillingPlan.BillingPlanUsageCategory,
        
        @ObjectModel.foreignKey.association: '_BillingPlanType'
        SalesDocumentBillingPlan.BillingPlanType,
        
        SalesDocumentBillingPlan.BillingPlanStartDate,
        
        @ObjectModel.foreignKey.association: '_StartDateRule'
        SalesDocumentBillingPlan.BillingPlanStartDateRule,
        
        SalesDocumentBillingPlan.BillingPlanEndDate,
        
        @ObjectModel.foreignKey.association: '_EndDateRule'
        SalesDocumentBillingPlan.BillingPlanEndDateRule,
        
        SalesDocumentBillingPlan.BillingPlanSearchTerm,
        
        SalesDocumentBillingPlan.ReferenceBillingPlan,
        
        // For Access control

        @Consumption.hidden: true
        _SalesOrder.SalesOrderType,
        @Consumption.hidden: true
        _SalesOrder.SalesOrganization,
        @Consumption.hidden: true
        _SalesOrder.DistributionChannel,
        @Consumption.hidden: true
        _SalesOrder.OrganizationDivision,

        //Association

        @ObjectModel.association.type: [#TO_COMPOSITION_ROOT,#TO_COMPOSITION_PARENT]
        _SalesOrder,
        
        @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
        _SalesOrderBillingPlanItem,

        SalesDocumentBillingPlan._BillingPlanCategory,
        SalesDocumentBillingPlan._BillingPlanUsageCategory,
        SalesDocumentBillingPlan._BillingPlanType,
        SalesDocumentBillingPlan._StartDateRule,
        SalesDocumentBillingPlan._EndDateRule
}

where
  SalesDocumentBillingPlan._SalesDocument.SDDocumentCategory = 'C';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESDOCUMENT",
"I_SALESDOCUMENTBILLINGPLAN",
"I_SALESORDER"
],
"ASSOCIATED":
[
"I_BILLGPLNUSGECAT_2",
"I_BILLINGPLANCATEGORY",
"I_BILLINGPLANTYPE",
"I_INDIRECTDATEDETERMINERULE",
"I_SALESORDER",
"I_SALESORDERBILLINGPLANITEM"
],
"BASE":
[
"I_SALESDOCUMENTBILLINGPLAN"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More