I_SALESAREA

CDS View

Sales Area

I_SALESAREA is a CDS View in S/4HANA. Sales Area. It contains 6 fields. 11 CDS views read from this table.

Used by 11 CDS view(s) 6 fields

CDS Views using this table (11)

ViewTypeJoinVDMDescription
A_SalesArea view_entity from BASIC Sales Area
C_JITSalesAreaValueHelp view from CONSUMPTION Sales Area Value Help
C_OrgDivisionValueHelp view from CONSUMPTION Division by Distribution Chain
C_PrepaymentOrgDivisionVH view from CONSUMPTION Sales Org/Dis Ch specific Org Division
C_SalesAreaValueHelp view from CONSUMPTION Sales Area
C_SubscrpnMassProcgDivnVH view_entity from CONSUMPTION Division
I_AllwdOrdTypPerSlsOrg view inner COMPOSITE Allowed Order Types per Sales Org
I_DigitalVehDistrChannel view_entity inner COMPOSITE Digital Vehicle Distribution Channel
I_DigitalVehicleDivision view_entity from BASIC Digital Vehicle Sales Division
I_DistributionChainCountry view from COMPOSITE Distribution Chain Country/Region
P_SrvcProdComDistrChnl view inner CONSUMPTION Common distribution Channel for Product

Fields (6)

KeyField CDS FieldsUsed in Views
KEY DistributionChannel DistributionChannel,ProductDistributionChnl 6
KEY Division Division 3
KEY SalesOrganization ProductSalesOrg,SalesOrganization 5
_DistributionChannel _DistributionChannel 2
_Division _Division 2
_SalesOrganization _SalesOrganization 2 
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #ORGANIZATIONAL
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@EndUserText.label: 'Sales Area'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AbapCatalog.sqlViewName: 'ISDSALESAREA'
@AbapCatalog.buffering.status: #ACTIVE
@AbapCatalog.buffering.type: #FULL
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@Metadata.ignorePropagatedAnnotations: true
@Analytics.dataExtraction: {
    enabled: true,
    delta.changeDataCapture.automatic: true
}
@ObjectModel.supportedCapabilities:  [  #SQL_DATA_SOURCE,
                                        #CDS_MODELING_DATA_SOURCE,
                                        #CDS_MODELING_ASSOCIATION_TARGET,
                                        #EXTRACTION_DATA_SOURCE  ]
/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view I_SalesArea
as select from tvta

association [0..1] to I_SalesOrganization   as _SalesOrganization             on $projection.SalesOrganization = _SalesOrganization.SalesOrganization
association [0..1] to I_DistributionChannel as _DistributionChannel           on $projection.DistributionChannel = _DistributionChannel.DistributionChannel
association [0..1] to I_Division            as _Division                      on $projection.Division = _Division.Division
association [0..1] to I_DistributionChannel as _ReferenceDistributionChannel  on $projection.ReferenceDistributionChannel = _ReferenceDistributionChannel.DistributionChannel
association [0..1] to I_CreditControlArea   as _CreditControlArea             on $projection.CreditControlArea = _CreditControlArea.CreditControlArea
association [0..1] to I_Division            as _ReferenceDivision             on $projection.ReferenceDivision = _ReferenceDivision.Division
{
    @ObjectModel.foreignKey.association: '_SalesOrganization'
    key vkorg as SalesOrganization,

    @ObjectModel.foreignKey.association: '_DistributionChannel'
    key vtweg as DistributionChannel,

    @ObjectModel.foreignKey.association: '_Division'
    key spart as Division, 
    
    @ObjectModel.foreignKey.association: '_ReferenceDistributionChannel'
    vtwku     as ReferenceDistributionChannel,
    
    vkoau     as RefSlsOrgForSlsDocType,
    
    vtwau     as RefDistrChnlForSlsDocType,
    
    spaau     as RefDivisionForSlsDocType,

    revfp     as ATPResultModeControl,

    @ObjectModel.foreignKey.association: '_CreditControlArea'
    kkber     as CreditControlArea,
    
    @ObjectModel.foreignKey.association: '_ReferenceDivision'
    spaku     as ReferenceDivision,
        
    _SalesOrganization,
    _DistributionChannel,
    _Division,
    _ReferenceDistributionChannel,
    _CreditControlArea,
    _ReferenceDivision
};       
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"TVTA"
],
"ASSOCIATED":
[
"I_CREDITCONTROLAREA",
"I_DISTRIBUTIONCHANNEL",
"I_DIVISION",
"I_SALESORGANIZATION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More