I_SPECDEFIDFRFORSPECCAT

CDS View

Default description of a specification

I_SPECDEFIDFRFORSPECCAT is a CDS View in S/4HANA. Default description of a specification. 4 CDS views read from this table.

Used by 4 CDS view(s)

CDS Views using this table (4)

ViewTypeJoinVDMDescription
A_AllergenDescription view from CONSUMPTION Allergen Description
A_NutrientDescription view from CONSUMPTION Nutrient Description
A_PureSubstanceDescription view from CONSUMPTION Pure Substance Description
I_ProdSpecComponentDescription view from COMPOSITE Description of a Product Spec Component 
@AbapCatalog.sqlViewName: 'ISPECDEFSPECCAT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK

@EndUserText.label: 'Default description of a specification'

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MASTER

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #COMPOSITE

define view I_SpecDefIdfrForSpecCat
  with parameters
    @Environment.systemField: #SYSTEM_DATE
    P_KeyDate               : sydate,
    P_SpecificationCategory : eseobjtype

  as select from I_SpecIdentifierForKeyDate( P_KeyDate: $parameters.P_KeyDate )                               as idn

    inner join   I_SpecificationForKeyDate( P_KeyDate: $parameters.P_KeyDate )                                as specification    on specification.SpecificationInternalID = idn.SpecificationInternalID

    inner join   I_SpecTypeAssignedCategory                                                                   as spectypecategory on  spectypecategory.SpecificationCategory = $parameters.P_SpecificationCategory
                                                                                                                                  and spectypecategory.SpecificationType     = specification.SpecificationType

    inner join   I_SpecIdnListingDefinition                                                                   as listingCust      on  listingCust.SpecificationIdnListing     = 'D_DEFAULT'
                                                                                                                                  and listingCust.SpecificationIdnListingPrio = '0001'
                                                                                                                                  and listingCust.SpecificationIdnListingPos  = '0002'
                                                                                                                                  and listingCust.SpecificationCategory       = $parameters.P_SpecificationCategory
                                                                                                                                  and listingCust.SpecIdfgDescCategory        = idn.SpecIdfgDescCategory
                                                                                                                                  and listingCust.SpecIdfgDescType            = idn.SpecIdfgDescType

    inner join   I_SpecPrimIdfrForSpecCatMin ( P_KeyDate : $parameters.P_KeyDate ,
                                               P_SpecificationCategory :$parameters.P_SpecificationCategory ) as single           on single.SpecIdfgDescInternalID = idn.SpecIdfgDescInternalID

{

  key idn.SpecificationInternalID,
  key idn.SpecIdfgDescInternalID,

      idn.SpecIdfgDescCreatedByUser,
      idn.SpecIdfgDescCreationDate,
      idn.SpecIdfgDescLastChangedByUser,
      idn.SpecIdfgDescLastChangeDate,

      idn.SpecIdfgDescText,
      SpecificationIdnListingPrio,
      SpecificationIdnListingPos,

      @Consumption.hidden: true
      idn.SpecIdfgDescCategory,
      @Consumption.hidden: true
      idn.SpecIdfgDescType,
      @Consumption.hidden: true
      idn.SpecIdfgDescLanguage,

      _SpecificationForKeyDate
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SPECIDENTIFIERFORKEYDATE",
"I_SPECIDNLISTINGDEFINITION",
"I_SPECIFICATIONFORKEYDATE",
"I_SPECPRIMIDFRFORSPECCATMIN",
"I_SPECTYPEASSIGNEDCATEGORY"
],
"ASSOCIATED":
[
"I_SPECIFICATIONFORKEYDATE"
],
"BASE":
[
"I_SPECIDENTIFIERFORKEYDATE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More