I_SAFTGENLEDGERONETIMESUPPLIER

@AbapCatalog.sqlViewName: 'ISAFTGLOTSUP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@EndUserText.label: 'SAF-T Gen Ledger OneTimeSupplier'
define view I_SAFTGenLedgerOneTimeSupplier
  as select from I_JournalEntryItem as a

    inner join   I_JournalEntryItemOneTimeData    as  b on  a.CompanyCode            = b.CompanyCode
                                                  and a.AccountingDocument     = b.AccountingDocument
                                                  and a.FiscalYear             = b.FiscalYear
                                                  and a.AccountingDocumentItem = b.AccountingDocumentItem

  association [0..1] to I_OperationalAcctgDocItem as _AccdocItem on  a.CompanyCode               =  _AccdocItem.CompanyCode
                                                                 and a.AccountingDocument        =  _AccdocItem.AccountingDocument
                                                                 and a.FiscalYear                =  _AccdocItem.FiscalYear
                                                                 and a.AccountingDocumentItem    =  _AccdocItem.AccountingDocumentItem
                                                                 and _AccdocItem.VATRegistration <> ''


  association [0..1] to I_SupplierCompany         as _RecAccount on  a.Supplier    = _RecAccount.Supplier
                                                                 and a.CompanyCode = _RecAccount.CompanyCode

{
      @ObjectModel.foreignKey.association: '_SourceLedger'
  key a.SourceLedger                                                         as SourceLedger,
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key a.CompanyCode                                                          as CompanyCode,
      @ObjectModel.foreignKey.association: '_FiscalYear'
  key a.FiscalYear                                                           as FiscalYear,
      @ObjectModel.foreignKey.association: '_JournalEntry'
  key a.AccountingDocument                                                   as AccountingDocument,
  key a.LedgerGLLineItem                                                     as LedgerGLLineItem,
      @ObjectModel.foreignKey.association: '_Ledger'
  key a.Ledger                                                               as Ledger,

      @ObjectModel.foreignKey.association: '_ChartOfAccounts'
      a.ChartOfAccounts,
      @ObjectModel.foreignKey.association: '_GLAccountInChartOfAccounts'
      a.GLAccount,

      @ObjectModel.foreignKey.association: '_AccountingDocumentCategory'
      a.AccountingDocumentCategory,

      a.AccountingDocumentItem                                               as AccountingDocumentItem,
      a.Supplier                                                             as Supplier,
      a.PostingDate                                                          as PostingDate,

      a.CompanyCodeCurrency,

      //BSEC

      b.AddressID,
      case when b.TaxID1 is not initial and b.TaxID1 is not null
            then substring(b.TaxID1 ,3,18)
           when _AccdocItem.VATRegistration is not initial and _AccdocItem.VATRegistration is not null
            then substring(_AccdocItem.VATRegistration ,3,18)
           else
           ''
      end                                                                    as VATRegistration,

      concat( concat( b.BusinessPartnerName1, ' '), b.BusinessPartnerName2 ) as CompanyName,
      //b.StreetAddressName                                                    as StreetAddressName,

      b._Address.StreetName                                                  as StreetAddressName,
      b._Address.StreetPrefixName                                            as StreetPrefixName,
      b._Address.AdditionalStreetPrefixName                                  as AdditionalStreetPrefixName,
      b._Address.StreetSuffixName                                            as StreetSuffixName,
      b._Address.AdditionalStreetSuffixName                                  as AdditionalStreetSuffixName,
      b._Address.HouseNumber                                                 as HouseNumber,

      b.CityName                                                             as CityName,
      b.PostalCode                                                           as PostalCode,
      b.Country                                                              as Country,
      b.POBox,
      b.POBoxPostalCode,
      b.Region,
      b._Address._DefaultEmailAddress.EmailAddress                           as EmailAddress,
      b._Address._DefaultURLAddress.SearchURLAddress                         as SearchURLAddress,

      //Associations

      _CompanyCode,
      _JournalEntry,
      _Ledger,
      _FiscalYear,
      _RecAccount.ReconciliationAccount,
      _Address,
      _ChartOfAccounts,
      _GLAccountInChartOfAccounts,
      _AccountingDocumentCategory,
      _SourceLedger,
      _Supplier

}
where
  a.FinancialAccountType = 'K'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS",
"I_ADDRESSEMAILADDRESS",
"I_ADDRESSHOMEPAGEURL",
"I_JOURNALENTRYITEM",
"I_JOURNALENTRYITEMONETIMEDATA",
"I_OPERATIONALACCTGDOCITEM",
"I_SUPPLIERCOMPANY"
],
"ASSOCIATED":
[
"I_ACCOUNTINGDOCUMENTCATEGORY",
"I_ADDRESS",
"I_CHARTOFACCOUNTS",
"I_COMPANYCODE",
"I_FISCALYEARFORCOMPANYCODE",
"I_GLACCOUNTINCHARTOFACCOUNTS",
"I_JOURNALENTRY",
"I_LEDGER",
"I_OPERATIONALACCTGDOCITEM",
"I_SUPPLIER",
"I_SUPPLIERCOMPANY"
],
"BASE":
[
"I_JOURNALENTRYITEM",
"I_JOURNALENTRYITEMONETIMEDATA"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/