I_RECIPEFORKEYDATE

CDS View

Recipe for Key Date

I_RECIPEFORKEYDATE is a CDS View in S/4HANA. Recipe for Key Date. 10 CDS views read from this table.

Used by 10 CDS view(s)

CDS Views using this table (10)

ViewTypeJoinVDMDescription
C_RcpOvwPageCreatedByCurUsr view from CONSUMPTION Recipe Overview Page
C_RcpOvwPageLastAccByCurUsr view from CONSUMPTION Recipe Overview Page
C_RcpOvwPageLastChgdByCurUsr view from CONSUMPTION Recipe Overview Page
C_RcpOvwPageValidSoon view from CONSUMPTION Recipe Overview Page
C_RecipeCurrentObjPg view from CONSUMPTION Manage Recipes
ESH_N_RECIPE view from
ESH_N_RECIPE_INT view from
I_RecipeForKeyDateTP view from TRANSACTIONAL Recipe for Key Date (Transactional Processing)
P_RecipeOverview view from CONSUMPTION
R_RecipeWithPrimaryOutput view from COMPOSITE Recipe for Key Date with PO Data 
@AbapCatalog.sqlViewName: 'IRECIPEKD'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MASTER

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #COMPOSITE

@AbapCatalog.preserveKey: true

@EndUserText.label: 'Recipe for Key Date'
define view I_RecipeForKeyDate
  with parameters
    @Environment.systemField: #SYSTEM_DATE
    P_KeyDate : sydate
  as select from I_Recipe 
  association [0..1] to I_SpecificationForKeyDate      as _PrimaryOutputSpecification    on  $projection.RecipePrimaryOutputInternalID = _PrimaryOutputSpecification.SpecificationInternalID
  association [1..*] to I_RecipeFormulaItemForKeyDate  as _FormulaForKeyDate             on  $projection.RcpFmlaUUID = _FormulaForKeyDate.RcpFmlaUUID
  association [0..*] to I_RecipeProcessEquipRqmt       as _RecipeProcessEquipRqmt        on  $projection.RecipeUUID = _RecipeProcessEquipRqmt.RecipeUUID
  association [0..*] to I_RecipeProcessElementBasic    as _RecipeProcessElementBasic     on  $projection.RecipeUUID = _RecipeProcessElementBasic.RecipeUUID
  association [0..*] to I_RecipeProcessParamValue      as _RecipeProcessParamValue       on  $projection.RecipeUUID = _RecipeProcessParamValue.RecipeUUID

  association [1..*] to I_RecipeFormulaItemForKeyDate  as _PrimOutputFormulaForKeyDate   on  $projection.RcpFmlaUUID                      = _PrimOutputFormulaForKeyDate.RcpFmlaUUID
                                                                                         and _PrimOutputFormulaForKeyDate.RcpFmlaItemType = 'PO'
  association [0..*] to I_RecipeFormulaItemForKeyDate  as _InputFormulaForKeyDate        on  $projection.RcpFmlaUUID                 = _InputFormulaForKeyDate.RcpFmlaUUID
                                                                                         and _InputFormulaForKeyDate.RcpFmlaItemType = 'IN'
  association [0..*] to I_RecipeFormulaItemForKeyDate  as _OutputStreamFormulaForKeyDate on  $projection.RcpFmlaUUID                        = _OutputStreamFormulaForKeyDate.RcpFmlaUUID
                                                                                         and _OutputStreamFormulaForKeyDate.RcpFmlaItemType = 'OS'
  association [0..*] to I_RecipeFormulaItemForKeyDate  as _SecOutputFormulaForKeyDate    on  $projection.RcpFmlaUUID                     = _SecOutputFormulaForKeyDate.RcpFmlaUUID
                                                                                         and _SecOutputFormulaForKeyDate.RcpFmlaItemType = 'SO'
  association [0..*] to I_ClfnObjectClassForKeyDate    as _ClfnObjectClassForKeyDate     on  $projection.RecipeUniqueID                 = _ClfnObjectClassForKeyDate.ClfnObjectID
                                                                                         and _ClfnObjectClassForKeyDate.ClfnObjectTable = '/PLMB/RCP_RECIPE'
  association [0..*] to I_ClfnObjectCharcValForKeyDate as _ClfnObjectCharcValForKeyDate  on  $projection.RecipeUniqueID                    = _ClfnObjectCharcValForKeyDate.ClfnObjectID
                                                                                         and _ClfnObjectCharcValForKeyDate.ClfnObjectTable = '/PLMB/RCP_RECIPE'
  association [1..1] to E_Recipe                       as _Extension                     on  $projection.RecipeUUID = _Extension.RecipeUUID
{
  key RecipeUUID,
      RecipeUniqueID,
      Recipe,
      RecipePrimaryOutputInternalID,
      RecipeAlternativeNumber,
      RecipeVersionNumber,
      RecipeCreatedByUser,
      RecipeCreationDateTime,
      RecipeLastChangedByUser,
      RecipeLastChangeDateTime,
      RecipeType,
      RecipePurpose,
      RecipeStatus,
      _RecipeStatusText.StsActnMgmtStatusText,
      RecipeStatusSchema,
      RcpFmlaUUID,
      RecipeProcessUUID,
      RecipePropertySpecInternalID,
      RecipeChangeNumber,
      RecipeIsDeleted,
      RecipeIsArchived,
      RecipeValidityStartDate,
      RecipeValidityEndDate,
      RecipeValidityMinQuantity,
      RecipeValidityMaxQuantity,
      RecipeValidityUnit,
      RecipeAuthorizationGroup,

      /* Associations */
      _CreatedByUser,
      _LastChangedByUser,
      _Plant,
      _RecipeDescription,
      _TextObjectPlainLongText,
      _RecipePurpose,
      _RecipeStatus,
      _RecipeStatusText,
      _RecipeType,
      _AuthorizationGroup,

      _PrimaryOutputSpecification,
      _FormulaForKeyDate,

      _RecipeProcessEquipRqmt,
      _RecipeProcessElementBasic,
      _RecipeProcessParamValue,
      _RecipeDocInfoRecordObjectLink,

      // For Search

      _PrimOutputFormulaForKeyDate,
      _InputFormulaForKeyDate,
      _OutputStreamFormulaForKeyDate,
      _SecOutputFormulaForKeyDate,
      _ClfnObjectClassForKeyDate,
      _ClfnObjectCharcValForKeyDate,

      _LogAccMObjectTypeActive,
      _LogAccMObjectUserAuthzn,
      _LogAccMObjSecureIDAssgmt

}
where _PrimaryOutputSpecification( P_KeyDate : $parameters.P_KeyDate ).Specification != '' // PO specification must be valid on key date "Note 2761375

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_RECIPE",
"I_SPECIFICATIONFORKEYDATE",
"I_STSACTNMGMTSTATUSTEXT"
],
"ASSOCIATED":
[
"E_RECIPE",
"I_CLFNOBJECTCHARCVALFORKEYDATE",
"I_CLFNOBJECTCLASSFORKEYDATE",
"I_DOCUMENTINFORECORDOBJECTLINK",
"I_LOGACCMOBJECTTYPEACTIVE",
"I_LOGACCMOBJECTUSERAUTHZN",
"I_LOGACCMOBJSECUREIDASSGMT",
"I_RECIPEASSGDPLANT",
"I_RECIPEAUTHORIZATIONGROUP",
"I_RECIPEFORMULAITEMFORKEYDATE",
"I_RECIPEPROCESSELEMENTBASIC",
"I_RECIPEPROCESSEQUIPRQMT",
"I_RECIPEPROCESSPARAMVALUE",
"I_RECIPEPURPOSE",
"I_RECIPESTATUS",
"I_RECIPETEXT",
"I_RECIPETYPE",
"I_SPECIFICATIONFORKEYDATE",
"I_STSACTNMGMTSTATUSTEXT",
"I_TEXTOBJECTPLAINLONGTEXT",
"I_USER"
],
"BASE":
[
"I_RECIPE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More