I_RSHORDER

@AbapCatalog.sqlViewName: 'IRSHORDER'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Maintenance Orders'

@VDM.viewType: #COMPOSITE
//@VDM.private: true

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@AccessControl.personalData.blocking: #NOT_REQUIRED

/*
CONTRACT*************************************************************************************************************************
Name:                       Maintenance Order
Specification:              This view will return the Maintenance Order
Requires:                   NA
Ensures:                    RSH relevant fields and associations of Maintenance Order are returned
Owners:                     CK
Contributors:
Unit Test required Y/N:     Y
Additional comments         For Performance reasons fields from _Order association of I_MaintenanceOrder shall not be exposed here.
                            Instead request field to be added to I_MaintenanceOrder!
                            MaterialStatus Association moved to I_RSHOperationAndSubOperation for performance reasons.

END OF CONTRACT******************************************************************************************************************
*/

define view I_RSHOrder
  as select from I_MaintenanceOrder as _MaintenanceOrder

  //  association [1..1] to I_RSHOrderMaterialStatus as _MaterialStatus on _MaintenanceOrder.MaintenanceOrderInternalID = _MaterialStatus.StatusObject

  //  -> association moved to I_RSHOperationAndSubOperation for performance


{
  key MaintenanceOrder,
      MaintOrderRoutingNumber,

      BasicSchedulingType,
      OrdIsNotSchedldAutomatically,

      MaintenanceOrderInternalID,

      MaintPriority,
      MaintPriorityType,

      MaintenanceOrderType,

      MaintenanceActivityType,
      MaintenancePlanningPlant,

      WBSElementInternalID,
      cast( ProjectInternalID as rsh_eam_project_int_id preserving type )                               as ProjectInternalID,

      MaintenanceOrderDesc,
      OrderHasLongText,

      MaintOrdBasicStartDate,
      MaintOrdBasicStartTime,
      MaintOrdBasicEndDate,
      MaintOrdBasicEndTime,

      ScheduledBasicStartDate,
      ScheduledBasicStartTime,
      ScheduledBasicEndDate,
      ScheduledBasicEndTime,

      LatestAcceptableCompletionDate,

      MaintenancePlannerGroup,
      cast( MaintenanceRevision as rsh_eam_maint_event )                                                as MaintenanceRevision,
      cast(_MaintenanceOrder._MaintenanceRevision.MaintenanceRevisionDesc as rsh_eam_maint_event_desc ) as MaintenanceRevisionDesc,
      OperationSystemCondition,

      MaintenanceNotification,

      Equipment,

      MaintObjectLocAcctAssgmtNmbr,
      MaintenancePlan,
      MaintenancePlant,

      SuperiorProjectNetwork,
      ControllingArea,
      ResponsibleCostCenter,
      _MaintenanceOrder._MainWorkCenter.WorkCenter                                                      as MainWorkCenter,
      MainWorkCenterPlant,

      _BasicSchedulingType.SchedulingIsPerformedBackward,
      _BasicSchedulingType.SchedulingType,

      MaintOrderProcessingContext,

      //    Order Phase and sub-phase

      MaintOrdProcessPhaseCode,
      MaintOrdProcessSubPhaseCode,

      //      _MaterialStatus, -> moved to I_RSHOperationAndSubOperation for performance

      _BasicSchedulingType,
      _MaintenancePriority,
      _MaintenanceActivityType,
      _MaintenanceNotification,
      _Equipment,
      _LocationAccountAssignment,
      _OperationSystemCondition,
      _EAMProcessPhase,
      _EAMProcessSubPhase,
      _WBSElement,
      _Project


}
where
  MaintOrderProcessingContext <> 'B'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MAINTENANCEORDER",
"I_MAINTENANCEREVISION",
"I_SCHEDULINGTYPE",
"I_WORKCENTER"
],
"ASSOCIATED":
[
"I_EAMPROCESSPHASE",
"I_EAMPROCESSSUBPHASE",
"I_EQUIPMENT",
"I_LOCATIONACCOUNTASSIGNMENT",
"I_MAINTENANCEACTIVITYTYPE",
"I_MAINTENANCENOTIFICATION",
"I_MAINTOPERATIONSYSTCONDITION",
"I_PMNOTIFICATIONPRIORITY",
"I_PROJECTBYINTERNALKEY",
"I_SCHEDULINGTYPE",
"I_WBSELEMENTBYINTERNALKEY"
],
"BASE":
[
"I_MAINTENANCEORDER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/