I_RESERVICEGROUPBASICDATA

CDS View

Real Estate Service Group

I_RESERVICEGROUPBASICDATA is a CDS View in S/4HANA. Real Estate Service Group. It contains 1 fields. 3 CDS views read from this table.

Used by 3 CDS view(s) 1 fields

CDS Views using this table (3)

ViewTypeJoinVDMDescription
I_REIntegObjectObject2SrvcGrp view_entity inner COMPOSITE Real Estate Object to Service Group
I_REServiceGroup view_entity from COMPOSITE Real Estate Service Group
I_REServiceGroupValidity view_entity from COMPOSITE Real Estate Service Group Validity

Fields (1)

KeyField CDS FieldsUsed in Views
KEY InternalRealEstateNumber InternalRealEstateNumber,InternalRealEstateNumberLvl0 2 
//@AbapCatalog.sqlViewName: 'IRESERVICEGRPBSC'

@EndUserText.label: 'Real Estate Service Group'


@AccessControl.authorizationCheck: #MANDATORY

@ObjectModel.representativeKey: 'InternalRealEstateNumber'
@ObjectModel.semanticKey: ['RealEstateServiceGroupNumber']
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

//@Analytics.internalName:#LOCAL

//@Analytics:{

//    dataCategory: #DIMENSION,

//    dataExtraction: {

//        enabled: true,

//        delta.changeDataCapture: {

//        automatic: true

//        }

//    }

//}


@Metadata.allowExtensions: true

@VDM.viewType: #BASIC

define view entity I_REServiceGroupBasicData
  as select from vicssg
  association [0..1] to I_User                         as _CreatedByUser                on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                         as _ChangedByUser                on  $projection.LastChangedByUser = _ChangedByUser.UserID
  association [0..1] to I_User                         as _ResponsibleUser              on  $projection.Responsible = _ResponsibleUser.UserID
  association [1..1] to I_REKeyAssgmt                  as _REKeyAssgmt                  on  $projection.InternalRealEstateNumber = _REKeyAssgmt.InternalRealEstateNumber
  association [0..1] to I_REAuthorizationGroup         as _REAuthorizationGroup         on  $projection.REAuthorizationGroup           = _REAuthorizationGroup.REAuthorizationGroup
                                                                                        and _REAuthorizationGroup.RealEstateObjectType = 'J6'
  //  association [1..1] to I_REServiceCategory            as _REServiceCategory            on  $projection.REServiceCategory = _REServiceCategory.REServiceCategory

  association [1..1] to I_REServiceGroupType           as _REServiceGroupType           on  $projection.REServiceGroupType = _REServiceGroupType.REServiceGroupType
  association [1..1] to I_REServiceGroupCategory       as _REServiceGroupCategory       on  $projection.REServiceGroupCategory = _REServiceGroupCategory.REServiceGroupCategory
  association [0..1] to I_CompanyCode                  as _CompanyCode                  on  $projection.CompanyCode = _CompanyCode.CompanyCode

  association [0..1] to I_StatusObject                 as _StatusObject                 on  $projection.REStatusObject = _StatusObject.StatusObject
  association [1..*] to I_StatusObjectStatus           as _StatusObjectStatus           on  $projection.REStatusObject = _StatusObjectStatus.StatusObject
  //  association [0..1] to I_REObjectAddress              as _REObjectAddress              on  $projection.InternalRealEstateNumber = _REObjectAddress.InternalRealEstateNumber

  association [1..*] to I_RESrvcGrpToContractAssgmt    as _RESrvcGrpToContractAssgmt    on  $projection.REStatusObject = _RESrvcGrpToContractAssgmt.REStatusObjectSource

  //   parent

  association [0..1] to I_REIntegrationObject          as _REParentIntegrationObject    on  $projection.REParentIntRealEstateNumber = _REParentIntegrationObject.InternalRealEstateNumber
  //  children

  association [0..*] to I_RESrvcGrpObjectRelation      as _RESrvcGrpObjectRelation      on  $projection.InternalRealEstateNumber = _RESrvcGrpObjectRelation.InternalRealEstateNumber
  association [0..*] to I_RESrvcGrpSettlementRule      as _RESrvcGrpSettlementRule      on  $projection.InternalRealEstateNumber = _RESrvcGrpSettlementRule.InternalRealEstateNumber
  association [0..*] to I_RESrvcGrpSettlmtRule2CostCat as _RESrvcGrpSettlmtRule2CostCat on  $projection.InternalRealEstateNumber = _RESrvcGrpSettlmtRule2CostCat.InternalRealEstateNumber
  association [0..*] to I_REApportionmentRule          as _REApportionmentRule          on  $projection.InternalRealEstateNumber = _REApportionmentRule.InternalRealEstateNumber
  association [0..*] to I_REDenominatorRule            as _REDenominatorRule            on  $projection.InternalRealEstateNumber = _REDenominatorRule.InternalRealEstateNumber
  //  association [0..*] to I_REIntegObjectRelationPartial as _REIntegObjectRelationPartial on  $projection.InternalRealEstateNumber = _REIntegObjectRelationPartial.InternalRealEstateNumber

  association [0..*] to I_REPartnerAssgmt              as _REPartnerAssgmt              on  $projection.InternalRealEstateNumber = _REPartnerAssgmt.InternalRealEstateNumber
  association [0..*] to I_REObjectAssgmt               as _REObjectAssgmt               on  $projection.REStatusObject = _REObjectAssgmt.REStatusObjectSource
  association [0..*] to I_REReminderObjRule            as _REReminderRule               on  $projection.InternalRealEstateNumber = _REReminderRule.InternalRealEstateNumber
//  association [0..*] to I_REServiceGroupMeasurement    as _REMeasurement                on  $projection.InternalRealEstateNumber = _REMeasurement.InternalRealEstateNumber

  association [0..*] to I_REServiceGroupAcctObjAssgmt  as _REServiceGroupAcctObjAssgmt  on  $projection.InternalRealEstateNumber = _REServiceGroupAcctObjAssgmt.InternalRealEstateNumber
  //  Extensibility

  association [1..1] to E_REServiceGroup               as _Extension                    on  $projection.InternalRealEstateNumber = _Extension.InternalRealEstateNumber
{
  key intreno       as InternalRealEstateNumber,
      @ObjectModel.foreignKey.association: '_StatusObject'
      objnr         as REStatusObject,
      sgnr          as RealEstateServiceGroupNumber,
      @ObjectModel.foreignKey.association: '_REServiceGroupType'
      sgtype        as REServiceGroupType,
      @ObjectModel.foreignKey.association: '_REServiceGroupCategory'
      sgcategory    as REServiceGroupCategory,
      sgxstext      as REServiceGroupName,
      sgxltext      as REServiceGroupLongName,
      parentintreno as REParentIntRealEstateNumber,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      bukrs         as CompanyCode,
      rerf          as CreatedByUser,
      derf          as CreationDate,
      terf          as CreationTime,
      reher         as RESourceOfCreation,
      rbear         as LastChangedByUser,
      dbear         as LastChangeDate,
      tbear         as LastChangeTime,
      rbher         as RESourceOfChange,
      responsible   as Responsible,
      @ObjectModel.foreignKey.association: '_REAuthorizationGroup'
      authgrp       as REAuthorizationGroup,

      _CreatedByUser,
      _ChangedByUser,
      _ResponsibleUser,
      _REAuthorizationGroup,
      _REServiceGroupType,
      _REServiceGroupCategory,
      _REKeyAssgmt,
      _StatusObject,
      _StatusObjectStatus,
      _REParentIntegrationObject,
      _CompanyCode,
      _REPartnerAssgmt,
      _REObjectAssgmt,
      _REReminderRule,
//      _REMeasurement,

      _RESrvcGrpObjectRelation,
      _RESrvcGrpToContractAssgmt,
      _REServiceGroupAcctObjAssgmt,
      _RESrvcGrpSettlementRule,
      _RESrvcGrpSettlmtRule2CostCat,
      _REApportionmentRule,
      _REDenominatorRule
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"VICSSG"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_REAPPORTIONMENTRULE",
"I_REAUTHORIZATIONGROUP",
"I_REDENOMINATORRULE",
"I_REINTEGRATIONOBJECT",
"I_REKEYASSGMT",
"I_REOBJECTASSGMT",
"I_REPARTNERASSGMT",
"I_REREMINDEROBJRULE",
"I_RESERVICEGROUPACCTOBJASSGMT",
"I_RESERVICEGROUPCATEGORY",
"I_RESERVICEGROUPTYPE",
"I_RESRVCGRPOBJECTRELATION",
"I_RESRVCGRPSETTLEMENTRULE",
"I_RESRVCGRPSETTLMTRULE2COSTCAT",
"I_RESRVCGRPTOCONTRACTASSGMT",
"I_STATUSOBJECT",
"I_STATUSOBJECTSTATUS",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More