I_REINVOICE

CDS View

Real Estate Invoice Header

I_REINVOICE is a CDS View in S/4HANA. Real Estate Invoice Header. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_REOutpReqInvoice view_entity from CONSUMPTION Real Estate Invoice Header 
@AbapCatalog.sqlViewName: 'IREINVOICE'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL}
@ObjectModel.representativeKey: 'REInvoiceNumber'
@ObjectModel.semanticKey: ['REInvoiceNumber', 'CompanyCode', 'RealEstateContract', 'FiscalYear']
@EndUserText.label: 'Real Estate Invoice Header'
define view I_REInvoice
  as select from I_REInvoiceHeader

  association [1..1] to I_REProcess       as _REProcess       on  $projection.REInvoiceUUID   = _REProcess.REProcessUUID
                                                              and _REProcess.REProcessVersion = ' '

  association [1..1] to I_REContract      as _REContract      on  $projection.RealEstateContract = _REContract.RealEstateContract
                                                              and $projection.CompanyCode        = _REContract.CompanyCode

  association [0..1] to I_BusinessPartner as _BusinessPartner on  $projection.Partner = _BusinessPartner.BusinessPartner
  
  association [0..1] to I_BusinessPartnerRole        as _BusinessPartnerRole        on  $projection.Role = _BusinessPartnerRole.BusinessPartnerRole
 
{
  key CompanyCode,
  key REInvoiceNumber,
  key FiscalYear,
      REInvoiceUUID,
      Partner,
      Role,
      StatusObject,
      cast( substring( StatusObject , 7, 13 ) as recnnumber preserving type) as RealEstateContract,
      _REProcess.RealEstateProcess                                           as RealEstateProcess,
      REInvoiceDuePeriodStartDate,
      REInvoiceDuePeriodEndDate,
      REInvoiceIsReversed,
      
      GrossAmountInCoCodeCurrency,
      NetAmountInCoCodeCurrency,
      RETrnsltnRuleLoclTaxAmount,
      @UI.hidden: true
      Currency,

      _BusinessPartner,
      @Consumption.valueHelp: '_BusinessPartnerRole'
      _BusinessPartnerRole, 
      _REProcess,
      _REContract

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_REINVOICEHEADER",
"I_REPROCESS"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_BUSINESSPARTNERROLE",
"I_RECONTRACT",
"I_REPROCESS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More