I_RECONDITIONDISTRIBUTION

CDS View

Condition Distribution Factors

I_RECONDITIONDISTRIBUTION is a CDS View in S/4HANA. Condition Distribution Factors. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_REContractConditionDistr view from CONSUMPTION RE Contract Condition Distribution 
@AbapCatalog.sqlViewName: 'IRECNDNDISTR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Condition Distribution Factors'
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.representativeKey: 'RECndnDistributionUUID'
@Metadata.allowExtensions: true
@VDM.viewType: #BASIC

define view I_REConditionDistribution
  as select from vicdconddist
  association [1..1] to I_REContract         as _REContract          on $projection.InternalRealEstateNumber = _REContract.InternalRealEstateNumber
  association [0..1] to I_Currency           as _Currency           on $projection.REConditionCurrency = _Currency.Currency
  association [1..1] to I_REConditionType    as _REConditionType    on $projection.REConditionType = _REConditionType.REConditionType
  association [0..1] to I_REAccountingObject as _REAccountingObject on $projection.REStatusObjectDistribution = _REAccountingObject.REAccountingObject

{
  key distguid                                                 as RECndnDistributionUUID,
      condguid                                                 as REConditionUUID,
      intreno                                                  as InternalRealEstateNumber,
      objnr                                                    as REStatusObjectCalculation,
      @ObjectModel.foreignKey.association: '_REConditionType'
      condtype                                                 as REConditionType,
      condvalidfrom                                            as REConditionValidityStartDate,
      @Semantics.businessDate.from: true
      cast(valuevalidfrom as rebdvdmvalidfrom preserving type) as ValidityStartDate,
      @Semantics.businessDate.to: true
      cast(valuevalidto as rebdvdmvalidto preserving type)     as ValidityEndDate,
      @ObjectModel.foreignKey.association: '_REAccountingObject'
      distobjnr                                                as REStatusObjectDistribution,
      distvalue                                                as REConditionDistributionValue,
      distvaluefac                                             as REConditionDistributionFactor,
      distvaluecol                                             as REConditionDistrNmbrOfColls,
      @Semantics.amount.currencyCode: 'REConditionCurrency'
      distcondvalueorg                                         as REConditionDistrValueOrgAmt,
      @Semantics.amount.currencyCode: 'REConditionCurrency'
      distcondvalue                                            as REConditionDistributionAmount,
      @Semantics.amount.currencyCode: 'REConditionCurrency'
      condvalue                                                as REConditionItemAmount,
      @Semantics.amount.currencyCode: 'REConditionCurrency'
      taxvalue                                                 as REConditionItemTaxAmount,
      @Semantics.amount.currencyCode: 'REConditionCurrency'
      condvaluenet                                             as REConditionNetAmount,
      @Semantics.amount.currencyCode: 'REConditionCurrency'
      condvaluegross                                           as REConditionGrossAmount,
      @Semantics.currencyCode: true
      condcurr                                                 as REConditionCurrency,
      calcnumber                                               as RENumberOfCalculation,

      _REContract,
      _REConditionType,
      _REAccountingObject,
      _Currency
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"VICDCONDDIST"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_REACCOUNTINGOBJECT",
"I_RECONDITIONTYPE",
"I_RECONTRACT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More