I_RECONDITIONCALCULATION

CDS View

Condition Calculation Factors

I_RECONDITIONCALCULATION is a CDS View in S/4HANA. Condition Calculation Factors. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_REContractConditionCalc view from CONSUMPTION RE Contract Condition Calculation 
@AbapCatalog.sqlViewName: 'IRECNDNCALC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #BASIC

@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.representativeKey: 'RECndnCalculationUUID'

@Metadata.allowExtensions: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Condition Calculation Factors'

define view I_REConditionCalculation
  as select from vicdcondcalc
  association [1..1] to I_REContract      as _REContract      on $projection.InternalRealEstateNumber = _REContract.InternalRealEstateNumber
  association [0..1] to I_Currency        as _Currency        on $projection.REConditionCurrency = _Currency.Currency
  association [1..1] to I_REConditionType as _REConditionType on $projection.REConditionType = _REConditionType.REConditionType
{
  key calcguid                                                 as RECndnCalculationUUID,
      condguid                                                 as REConditionUUID,
      intreno                                                  as InternalRealEstateNumber,
      objnr                                                    as REStatusObjectCalculation,
      @ObjectModel.foreignKey.association: '_REConditionType'
      condtype                                                 as REConditionType,
      condvalidfrom                                            as REConditionValidityStartDate,
      @Semantics.businessDate.from: true
      cast(valuevalidfrom as rebdvdmvalidfrom preserving type) as ValidityStartDate,
      @Semantics.businessDate.to: true
      cast(valuevalidto as rebdvdmvalidto preserving type)     as ValidityEndDate,
      calcvalue                                                as REConditionCalculationFactor,
      @Semantics.amount.currencyCode: 'REConditionCurrency'
      condvalue                                                as REConditionItemAmount,
      @Semantics.amount.currencyCode: 'REConditionCurrency'
      taxvalue                                                 as REConditionItemTaxAmount,
      @Semantics.amount.currencyCode: 'REConditionCurrency'
      condvaluenet                                             as REConditionNetAmount,
      @Semantics.amount.currencyCode: 'REConditionCurrency'
      condvaluegross                                           as REConditionGrossAmount,
      @Semantics.currencyCode: true
      condcurr                                                 as REConditionCurrency,
      calcnumber                                               as RENumberOfCalculation,
      partner                                                  as BusinessPartner,
      partnerobjnr                                             as REPartnerStatusObject,
      duedate                                                  as REConditionDueDate,

      _REContract,
      _REConditionType,
      _Currency
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"VICDCONDCALC"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_RECONDITIONTYPE",
"I_RECONTRACT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More