I_RECONTRACT
Real Estate Contract
I_RECONTRACT is a CDS View in S/4HANA. Real Estate Contract. It contains 17 fields. 20 CDS views read from this table.
CDS Views using this table (20)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_REContractDEX | view_entity | from | CONSUMPTION | Extraction for REContract |
| C_REContractMgmtApp | view | from | CONSUMPTION | Manage Lease Contract |
| C_REOutpReqContract | view_entity | from | CONSUMPTION | Real Estate Contract for Output Request |
| C_REOutputParamDetn520 | view | inner | CONSUMPTION | RE OM Parameter Determination A520 |
| C_REOutputParamDetnContr | view | from | CONSUMPTION | RE OM Parameter Determination -Contract- |
| ESH_N_RECONTRACT | view | from | ||
| I_REContractAddl | view | from | COMPOSITE | RE Contract additional |
| I_REContractAssignSubject | view | from | COMPOSITE | Real Estate Contract Subject Assignments |
| I_REContractAssignSubjectC_2 | view | from | COMPOSITE | Real Estate Contract Subject Assignments |
| I_REContractCheckTable | view | from | BASIC | Real Estate Contract Check Table |
| I_REContractData | view_entity | from | COMPOSITE | Real Estate Contract |
| I_REContractStatusObject | view | from | COMPOSITE | Real Estate Contract Status |
| I_REContractValid | view | from | COMPOSITE | Valid Real Estate Contracts |
| I_REContractVH | view | from | COMPOSITE | Real Estate Contract Value Help |
| P_FuncnlAreaClmContr | view | from | COMPOSITE | WUFAREA Lease Contract |
| P_FundCLMContr | view | from | COMPOSITE | WUFUND Lease Contract |
| P_GrantClmContr | view | from | COMPOSITE | WUGRANT Lease Contract |
| P_IntOrdSettlmtDistrRuleRE | view_entity | union | COMPOSITE | |
| P_REIntegObjectOccpcyCalc1 | view | inner | COMPOSITE | |
| R_REContractTP | view_entity | from | TRANSACTIONAL | Real Estate Contract TP |
Fields (17)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | CompanyCode | CompanyCode | 5 |
| KEY | InternalRealEstateNumber | InternalRealEstateNumber,REContractInternalNumber | 7 |
| KEY | RealEstateContract | RealEstateContract | 7 |
| KEY | REStatusObject | ObjectInternalID,REContractStatusObject,REStatusObject,StatusObject | 8 |
| _REPartnerAssgmt | _REPartnerAssgmt | 3 | |
| ContractEndDate | ContractEndDate,ValidityEndDate | 6 | |
| ContractStartDate | ContractStartDate,ValidityStartDate | 6 | |
| CreatedByUser | CreatedByUser | 3 | |
| CreationDate | CreationDate | 3 | |
| LastChangeDate | LastChangeDate | 3 | |
| LastChangedByUser | LastChangedByUser | 3 | |
| REAuthorizationGroup | REAuthorizationGroup | 5 | |
| REContractName | REContractName | 5 | |
| REContractNumberOld | REContractNumberOld | 2 | |
| REContractType | REContractType | 5 | |
| REPossessionEndDate | REPossessionEndDate | 1 | |
| REPossessionStartDate | REPossessionStartDate | 1 |
@AbapCatalog.sqlViewName: 'IRECONTRACT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.personalData.blockingIndicator: ['_REPartnerAssgmt._BusinessPartner.IsBusinessPurposeCompleted']
@AccessControl.privilegedAssociations: ['_StatusObject', '_StatusObjectStatus']
@EndUserText.label: 'Real Estate Contract'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: ['InternalRealEstateNumber']
@ObjectModel.semanticKey: ['CompanyCode', 'RealEstateContract']
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@Analytics:{
dataCategory: #DIMENSION,
dataExtraction: {
enabled: true,
delta.changeDataCapture: {
automatic: true
}
}
}
@Metadata.allowExtensions: true
@VDM.viewType: #BASIC
define view I_REContract
as select from vicncn
association [0..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [0..1] to I_CompanyCode as _MainContractCompanyCode on $projection.REMainContractCompanyCode = _MainContractCompanyCode.CompanyCode
association [0..1] to I_User as _CreatedByUser on $projection.CreatedByUser = _CreatedByUser.UserID
association [0..1] to I_User as _ChangedByUser on $projection.LastChangedByUser = _ChangedByUser.UserID
association [0..1] to I_User as _ResponsibleUser on $projection.Responsible = _ResponsibleUser.UserID
association [0..1] to I_Currency as _Currency on $projection.REContractCurrency = _Currency.Currency
association [0..1] to I_REIndustry as _REIndustry on $projection.REIndustrySector = _REIndustry.REIndustrySector
association [0..1] to I_RECreationType as _RECreationType on $projection.RECreationType = _RECreationType.RECreationType
association [1..1] to I_REContractType as _REContractType on $projection.REContractType = _REContractType.REContractType
association [0..1] to I_RETenancyLaw as _RETenancyLaw on $projection.RETenancyLaw = _RETenancyLaw.RETenancyLaw
association [0..1] to I_REContractDepositType as _REContractDepositType on $projection.REContractDepositType = _REContractDepositType.REContractDepositType
association [0..1] to I_REContractNoticeReason as _REContractNoticeReason on $projection.REContractNoticeReason = _REContractNoticeReason.REContractNoticeReason
association [1..1] to I_REKeyAssgmt as _REKeyAssgmt on $projection.InternalRealEstateNumber = _REKeyAssgmt.InternalRealEstateNumber
association [1..1] to I_REObjectType as _REObjectType on $projection.RealEstateObjectType = _REObjectType.RealEstateObjectType
association [0..1] to I_REAuthorizationGroup as _REAuthorizationGroup on $projection.REAuthorizationGroup = _REAuthorizationGroup.REAuthorizationGroup
and $projection.RealEstateObjectType = _REAuthorizationGroup.RealEstateObjectType
association [0..1] to I_REValuationRelevance_2 as _REValuationRelevance on $projection.ValuationRelevance = _REValuationRelevance.ValuationRelevance
association [0..1] to I_StatusObject as _StatusObject on $projection.REStatusObject = _StatusObject.StatusObject
association [1..*] to I_StatusObjectStatus as _StatusObjectStatus on $projection.REStatusObject = _StatusObjectStatus.StatusObject
// children
association [0..*] to I_REPartnerAssgmt as _REPartnerAssgmt on $projection.InternalRealEstateNumber = _REPartnerAssgmt.InternalRealEstateNumber
association [0..*] to I_REObjectAssgmt as _REObjectAssgmt on $projection.REStatusObject = _REObjectAssgmt.REStatusObjectSource
association [0..*] to I_RERenewalTerm as _RERenewalTerm on $projection.InternalRealEstateNumber = _RERenewalTerm.InternalRealEstateNumber
association [0..*] to I_RENoticeTerm as _RENoticeTerm on $projection.InternalRealEstateNumber = _RENoticeTerm.InternalRealEstateNumber
association [1..*] to I_REOrganizationalAssgmtTerm as _REOrganizationalAssgmtTerm on $projection.InternalRealEstateNumber = _REOrganizationalAssgmtTerm.InternalRealEstateNumber
association [1..*] to I_REPostingTerm as _REPostingTerm on $projection.InternalRealEstateNumber = _REPostingTerm.InternalRealEstateNumber
association [1..*] to I_RERhythmTerm as _RERhythmTerm on $projection.InternalRealEstateNumber = _RERhythmTerm.InternalRealEstateNumber
association [0..*] to I_RECondition as _RECondition on $projection.InternalRealEstateNumber = _RECondition.InternalRealEstateNumber
association [0..*] to I_REReminderObjRule as _REReminderRule on $projection.InternalRealEstateNumber = _REReminderRule.InternalRealEstateNumber
association [0..*] to I_REValuationTerm as _REValuationTerm on $projection.InternalRealEstateNumber = _REValuationTerm.InternalRealEstateNumber
association [0..*] to I_REValuationRuleCondition as _REValuationRuleCondition on $projection.InternalRealEstateNumber = _REValuationRuleCondition.InternalRealEstateNumber
association [0..*] to I_REAdjustmentTerm as _REAdjustmentTerm on $projection.InternalRealEstateNumber = _REAdjustmentTerm.InternalRealEstateNumber
association [0..*] to I_RESalesRuleTerm as _RESalesRuleTerm on $projection.InternalRealEstateNumber = _RESalesRuleTerm.InternalRealEstateNumber
association [0..*] to I_RESalesReportingTerm as _RESalesReportingTerm on $projection.InternalRealEstateNumber = _RESalesReportingTerm.InternalRealEstateNumber
association [0..*] to I_RESalesRuleFrequencyTerm as _RESalesRuleFrqcyTerm on $projection.InternalRealEstateNumber = _RESalesRuleFrqcyTerm.InternalRealEstateNumber
// Extensibility
association [1..1] to E_REContract as _Extension on $projection.InternalRealEstateNumber = _Extension.InternalRealEstateNumber
{
key intreno as InternalRealEstateNumber,
@ObjectModel.foreignKey.association: '_CompanyCode'
bukrs as CompanyCode,
cast(recnnr as recnvdmcnnr preserving type ) as RealEstateContract,
@ObjectModel.foreignKey.association: '_StatusObject'
objnr as REStatusObject,
cast(imkey as recaimkeyfi preserving type ) as REInternalFinNumber,
oid as RealEstateContractOID,
alternativeid as REContractAlternativeID,
@ObjectModel.foreignKey.association: '_RECreationType'
creationtype as RECreationType,
@ObjectModel.foreignKey.association: '_CreatedByUser'
rerf as CreatedByUser,
derf as CreationDate,
terf as CreationTime,
reher as RESourceOfCreation,
@ObjectModel.foreignKey.association: '_ChangedByUser'
rbear as LastChangedByUser,
dbear as LastChangeDate,
tbear as LastChangeTime,
rbher as RESourceOfChange,
@ObjectModel.foreignKey.association: '_ResponsibleUser'
responsible as Responsible,
userexclusive as REUserExclusive,
@ObjectModel.foreignKey.association: '_REAuthorizationGroup'
authgrp as REAuthorizationGroup,
@ObjectModel.foreignKey.association: '_REContractType'
recntype as REContractType,
cast( recnbeg as recnvdmcnbeg preserving type ) as ContractStartDate,
@EndUserText.quickInfo: 'End of Term'
cast( recnendabs as recnvdmcnendabs preserving type ) as ContractEndDate,
cast( recntxt as recnvdmcnname preserving type ) as REContractName,
cast(recndactiv as recnvdmdaktv preserving type ) as REContractActivateDate,
@ObjectModel.foreignKey.association: '_RETenancyLaw'
cast( recntlaw as recnvdmcntlaw preserving type) as RETenancyLaw,
cast( recntxtold as recnvdmcntxtold preserving type) as REContractNumberOld,
@ObjectModel.foreignKey.association: '_MainContractCompanyCode'
cast( recnbukrscollect as recnvdmcnbukrscode preserving type) as REMainContractCompanyCode,
recnnrcollect as REMainContract,
@ObjectModel.foreignKey.association: '_Currency'
recncncurr as REContractCurrency,
@ObjectModel.foreignKey.association: '_REIndustry'
industry as REIndustrySector,
srrelevant as REIsSalesRelevant,
@ObjectModel.foreignKey.association: '_REContractDepositType'
cast(dptargettype as recnvdmdepotype preserving type) as REContractDepositType,
recndat as REContractSignDate,
cast(recn2dat as recnvdm2date) as REContract2SignDate,
recndpo as REContractCashFlowDate,
cast(recnend1st as recnvdmcnend1st) as REContractFirstEndDate,
recnnotper as REContractNoticeDate,
recnnotreceipt as REContractNoticeInDate,
@ObjectModel.foreignKey.association: '_REContractNoticeReason'
recnnotreason as REContractNoticeReason,
recndaktku as REContractNoticeActivationDate,
cfarchivedto as RECashFlowArchivedToDate,
cflockedto as RECashFlowLockedToDate,
cfpostingfrom as RECashFlowPostingFromDate,
cast(benocn as rebdvdmbeno preserving type) as REBusinessEntity,
cast(transpossfrom as recnvdmtranspossfrom preserving type) as REObjectAvailableFromDate,
cast ( transpossto as recnvdmtranspossto preserving type ) as REObjectAvailableToDate,
hasmultiassign as REHasMultipleAssignments,
possdatefrom as REPossessionStartDate,
possdateto as REPossessionEndDate,
@ObjectModel.foreignKey.association: '_REValuationRelevance'
relevanteval as ValuationRelevance,
@ObjectModel.foreignKey.association: '_REObjectType'
_REKeyAssgmt.RealEstateObjectType as RealEstateObjectType,
_REKeyAssgmt.REIdentificationKey as REIdentificationKey,
_REContractType.REBusinessPartnerRole1 as REBusinessPartnerRole1,
_CompanyCode,
_MainContractCompanyCode,
_CreatedByUser,
_ChangedByUser,
_ResponsibleUser,
_Currency,
_REIndustry,
_RECreationType,
_REContractType,
_RETenancyLaw,
_REContractDepositType,
_REContractNoticeReason,
_REAuthorizationGroup,
_REValuationRelevance,
_REKeyAssgmt,
// _REKeyAssgmt._REObjectType,
_StatusObject,
_StatusObjectStatus,
_REObjectType,
_REPartnerAssgmt,
_REObjectAssgmt,
_RERenewalTerm,
_RENoticeTerm,
_REOrganizationalAssgmtTerm,
_REPostingTerm,
_RERhythmTerm,
_RECondition,
_REReminderRule,
_REValuationTerm,
_REValuationRuleCondition,
_REAdjustmentTerm,
_RESalesRuleTerm,
_RESalesReportingTerm,
_RESalesRuleFrqcyTerm
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_RECONTRACTTYPE",
"I_REKEYASSGMT",
"VICNCN"
],
"ASSOCIATED":
[
"E_RECONTRACT",
"I_COMPANYCODE",
"I_CURRENCY",
"I_READJUSTMENTTERM",
"I_REAUTHORIZATIONGROUP",
"I_RECONDITION",
"I_RECONTRACTDEPOSITTYPE",
"I_RECONTRACTNOTICEREASON",
"I_RECONTRACTTYPE",
"I_RECREATIONTYPE",
"I_REINDUSTRY",
"I_REKEYASSGMT",
"I_RENOTICETERM",
"I_REOBJECTASSGMT",
"I_REOBJECTTYPE",
"I_REORGANIZATIONALASSGMTTERM",
"I_REPARTNERASSGMT",
"I_REPOSTINGTERM",
"I_REREMINDEROBJRULE",
"I_RERENEWALTERM",
"I_RERHYTHMTERM",
"I_RESALESREPORTINGTERM",
"I_RESALESRULEFREQUENCYTERM",
"I_RESALESRULETERM",
"I_RETENANCYLAW",
"I_REVALUATIONRELEVANCE_2",
"I_REVALUATIONRULECONDITION",
"I_REVALUATIONTERM",
"I_STATUSOBJECT",
"I_STATUSOBJECTSTATUS",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/