I_PURGDOCACCOUNTASSIGNMENT
Purchasing Document Account Assignment
I_PURGDOCACCOUNTASSIGNMENT is a CDS View in S/4HANA. Purchasing Document Account Assignment. It contains 65 fields. 34 CDS views read from this table.
CDS Views using this table (34)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_Arberp_Ordrout_Accassignment | view | from | CONSUMPTION | View: purchase order account assignment |
| C_GB_StRpAuditMMFileC | view_entity | inner | CONSUMPTION | GB HRMC Audit File for MM - Cube |
| C_PurgDocAccountAssignmentObj | view | from | CONSUMPTION | Purchasing Document Account Assignments For Object Page |
| I_CFinPurgDocAccountAssignment | view | union_all | COMPOSITE | CFin Purchasing Doc: Account Assignment |
| I_MRPPurchaseOrder | view | left_outer | COMPOSITE | MRP Purchase Order |
| I_MstrProjPurOrdItem | view | inner | COMPOSITE | View for Master Project Purchase Order Item |
| I_MstrProjPurOrdItemSimple | view | inner | COMPOSITE | Simplified PO Items for Master Project |
| I_PurchaseOrderQuickView | view | left_outer | COMPOSITE | Purchase Order Data |
| I_PurContrAccountAssgmt | view | from | COMPOSITE | Purchase Contract Account Assignment |
| I_PurCtrAccount | view | from | COMPOSITE | Account Assignment For Contracts |
| I_PurOrdAccountAssignment | view | from | COMPOSITE | Purchase Order Account Assignment |
| I_PurOrdAccrsCFinPurgDocAssgmt | view | union_all | COMPOSITE | PurOrdAccrs: CFin PO Item Assgmt |
| I_Schedagrmtacct | view | from | COMPOSITE | Scheduling Agreement Account Assignment |
| P_MaintBacklogNonStkCompUnion | view | inner | CONSUMPTION | Maintenance Backlog Non Stock Component Union |
| P_MaintOrdDepdntRqmtStatus | view | union_all | COMPOSITE | |
| P_MaintOrdDirectProcmtViaPO | view | left_outer | COMPOSITE | |
| P_MaintOrdDirectProcmtViaPO | view | union_all | COMPOSITE | |
| P_MaintOrdNmbrOfOpenPO | view | from | CONSUMPTION | |
| P_MaintOrdNmbrOfOpenServices | view | from | CONSUMPTION | |
| P_MaintOrdNonStkCompFromPurOrd | view | from | CONSUMPTION | |
| P_Mpnwepurdoc | view | from | COMPOSITE | |
| P_Mpsopurdoc | view | from | COMPOSITE | |
| P_Mpwbspurdoc | view | from | COMPOSITE | |
| P_ProjPurDocItems | view | union_all | COMPOSITE | |
| P_PurchasingSpndComparison2 | view | left_outer | CONSUMPTION | Purchasing Spend Comparison 2 |
| P_PurgSpndComprnAcctAssgmt | view | left_outer | CONSUMPTION | AccountAssignment for PurchasingSpend Comparison |
| P_PurOrdItemAcctAssgmt | view | left_outer | CONSUMPTION | Purchase Order Item Account Assignment |
| P_PurOrdItmAccountAssignment | view | from | CONSUMPTION | PO Item Account Assignment |
| P_PurOrdItmAcctAssgmt | view | inner | CONSUMPTION | |
| P_PurOrdItmAcctAssgmt1 | view | left_outer | CONSUMPTION | |
| P_PurOrdMaintainPdocAccAssHlpr | view | from | CONSUMPTION | |
| P_PurOrdMaintainPDocAccAssLine | view | from | CONSUMPTION | |
| P_RFM_SlsOrdPrgrsMntrPOSchLine | view | inner | COMPOSITE | |
| P_SlsOrderInSupplyPurgIssue3 | view | inner | COMPOSITE |
Fields (65)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | AccountAssignmentNumber | AccountAssignmentNumber | 12 |
| KEY | PurchasingDocument | PurchaseDocument,PurchaseOrder,PurchasingDocument | 8 |
| KEY | PurchasingDocumentItem | PurchaseItem,PurchaseOrderItem,PurchasingDocumentItem | 10 |
| KEY | SalesOrder | CentralFinanceSalesDocument,SalesDocument,SalesOrder | 7 |
| KEY | SalesOrderItem | CFinSalesDocumentItem,SalesDocumentItem,SalesOrderItem | 7 |
| _SalesOrder | _SalesOrder | 1 | |
| _SalesOrderItem | _SalesOrderItem | 1 | |
| _WBSElementByInternalKey | _WBSElementByInternalKey | 1 | |
| AcctLineFinalReason | AcctLineFinalReason | 1 | |
| BudgetPeriod | BudgetPeriod | 3 | |
| BusinessArea | BusinessArea | 3 | |
| BusinessProcess | BusinessProcess | 1 | |
| ChartOfAccounts | ChartOfAccounts | 3 | |
| CommitmentItem | CommitmentItem,CommitmentItemShortID | 3 | |
| CommitmentItemShortID | CommitmentItemShortID | 1 | |
| ControllingArea | ControllingArea | 7 | |
| CostCenter | CostCenter | 11 | |
| CostCtrActivityType | CostCtrActivityType | 3 | |
| CostObject | CostObject | 2 | |
| CreationDate | CreationDate | 1 | |
| DocumentCurrency | DocumentCurrency | 2 | |
| EarmarkedFundsDocument | EarmarkedFundsDocument | 1 | |
| EarmarkedFundsDocumentItem | EarmarkedFundsDocumentItem | 1 | |
| EarmarkedFundsItem | EarmarkedFundsItem | 1 | |
| FixedAsset | FixedAsset | 4 | |
| FunctionalArea | FunctionalArea | 4 | |
| Fund | Fund | 3 | |
| FundsCenter | FundsCenter | 3 | |
| GLAccount | GLAccount | 9 | |
| GoodsRecepientName | GoodsRecepientName,GoodsRecipientName | 3 | |
| GrantID | GrantID | 3 | |
| IsAcctLineFinal | IsAcctLineFinal | 1 | |
| IsDeleted | IsDeleted | 4 | |
| IsFinallyInvoiced | IsFinallyInvoiced | 1 | |
| JointVentureRecoveryCode | JointVentureRecoveryCode | 1 | |
| LastChangedDate | LastChangedDate | 1 | |
| MasterFixedAsset | FixedAsset,MasterFixedAsset | 6 | |
| MultipleAcctAssgmtDistrPercent | MultipleAcctAssgmtDistrPercent | 9 | |
| NetworkActivityInternalID | MaintOrderOperationCounter,NetworkActivityInternalID | 6 | |
| NonDeductibleInputTaxAmount | NonDeductibleInputTaxAmount | 3 | |
| OrderID | MaintenanceOrder,OrderID | 7 | |
| OrderIntBillOfOperationsItem | OrderIntBillOfOperationsItem | 2 | |
| OrderInternalID | MaintOrderRoutingNumber,OrderInternalID | 2 | |
| OrderQuantityUnit | OrderQuantityUnit | 2 | |
| PartnerAccountNumber | PartnerAccountNumber | 1 | |
| ProfitabilitySegment_2 | ProfitabilitySegment,ProfitabilitySegment_2 | 1 | |
| ProfitCenter | ProfitCenter | 7 | |
| ProjectNetwork | ProjectNetwork | 4 | |
| ProjectNetworkInternalID | ProjectNetworkInternalID | 5 | |
| PubSecSplitAuthznGroup | PubSecSplitAuthznGroup | 1 | |
| PubSecSplitBatchNumberID | PubSecSplitBatchNumberID | 1 | |
| PurgDocNetAmount | PurgDocNetAmount | 5 | |
| Quantity | Quantity | 6 | |
| RealEstateObject | RealEstateObject | 2 | |
| REInternalFinNumber | REInternalFinNumber | 1 | |
| SalesOrderScheduleLine | CFinRpldSalesDocScheduleLine,SalesOrderScheduleLine | 3 | |
| ServiceDocument | ServiceDocument | 1 | |
| ServiceDocumentItem | ServiceDocumentItem | 1 | |
| ServiceDocumentType | ServiceDocumentType | 1 | |
| SettlementReferenceDate | SettlementReferenceDate | 3 | |
| TaxCode | TaxCode | 4 | |
| TaxJurisdiction | TaxJurisdiction | 2 | |
| UnloadingPointName | UnloadingPointName | 1 | |
| ValidityDate | ValidityDate | 3 | |
| WBSElementInternalID | WBSElementInternalID | 12 |
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Purchasing Document Account Assignment'
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IPDACCTASSGMT'
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@ClientHandling.algorithm: #SESSION_VARIABLE
@UI.headerInfo: {
typeName: 'Account Assignment Details',
typeNamePlural: 'Accounts',
description.label: 'Account Assignment Number',
description.value: 'AccountAssignmentNumber',
title.label: 'Purchasing Document',
title.value: 'PurchasingDocument'
}
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
define view I_PurgDocAccountAssignment //with parameters P_CompanyCode:BUKRS , P_ChartOfAccounts:KTOPL
as select from I_PurgDocAccountAssignmentBsc
// association [1..1] to I_PurchasingDocument as _PurchasingDocument on $projection.PurchasingDocument = _PurchasingDocument.PurchasingDocument
association [1..1] to I_PurchasingDocumentItem as _PurchasingDocumentItem on $projection.PurchasingDocument = _PurchasingDocumentItem.PurchasingDocument
and $projection.PurchasingDocumentItem = _PurchasingDocumentItem.PurchasingDocumentItem
// association [0..1] to I_MM_CostCenterValueHelp as _CostCenterValueHelp on $projection.CostCenter = _CostCenterValueHelp.CostCenter
// and $projection.ControllingArea = _CostCenterValueHelp.ControllingArea
// and $projection.ValidityDate <= _CostCenterValueHelp.ValidityEndDate
// and $projection.ValidityDate >= _CostCenterValueHelp.ValidityStartDate
association [0..1] to I_CostCenter as _CostCenter on $projection.CostCenter = _CostCenter.CostCenter
and $projection.ControllingArea = _CostCenter.ControllingArea
and $projection.ValidityDate <= _CostCenter.ValidityEndDate
and $projection.ValidityDate >= _CostCenter.ValidityStartDate
association [0..*] to I_CostCenterText as _CostCenterText on $projection.CostCenter = _CostCenterText.CostCenter
and $projection.ControllingArea = _CostCenterText.ControllingArea
and $projection.ValidityDate <= _CostCenterText.ValidityEndDate
and $projection.ValidityDate >= _CostCenterText.ValidityStartDate
association [0..*] to I_GLAccount as _GLAccount on $projection.GLAccount = _GLAccount.GLAccount
//and $projection.CompanyCode = _GLAccount.CompanyCode // to change cardinality to [0..1] when uncommenting this
association [0..*] to I_GLAccountText as _GLAccountText on $projection.GLAccount = _GLAccountText.GLAccount
and $projection.ChartOfAccounts = _GLAccountText.ChartOfAccounts
association [0..1] to I_BusinessArea as _BusinessArea on $projection.BusinessArea = _BusinessArea.BusinessArea
association [0..*] to I_BusinessAreaText as _BusinessAreaText on $projection.BusinessArea = _BusinessAreaText.BusinessArea
association [0..1] to I_ProfitCenter as _ProfitCenter on $projection.ControllingArea = _ProfitCenter.ControllingArea
and $projection.ProfitCenter = _ProfitCenter.ProfitCenter
and $projection.ValidityDate <= _ProfitCenter.ValidityEndDate
and $projection.ValidityDate >= _ProfitCenter.ValidityStartDate
association [0..*] to I_ProfitCenterText as _ProfitCenterText on $projection.ControllingArea = _ProfitCenterText.ControllingArea
and $projection.ProfitCenter = _ProfitCenterText.ProfitCenter
and $projection.ValidityDate <= _ProfitCenterText.ValidityEndDate
association [0..1] to I_SalesOrder as _SalesOrder on $projection.SalesOrder = _SalesOrder.SalesOrder
association [0..1] to I_SalesOrderItem as _SalesOrderItem on $projection.SalesOrderItem = _SalesOrderItem.SalesOrderItem
and $projection.SalesOrder = _SalesOrderItem.SalesOrder
association [0..1] to I_ControllingArea as _ControllingArea on $projection.ControllingArea = _ControllingArea.ControllingArea
association [0..1] to I_SalesDocumentScheduleLine as _SalesDocumentScheduleLine on $projection.SalesOrder = _SalesDocumentScheduleLine.SalesDocument
and $projection.SalesOrderItem = _SalesDocumentScheduleLine.SalesDocumentItem
and $projection.SalesOrderScheduleLine = _SalesDocumentScheduleLine.ScheduleLine
association [0..1] to I_WBSElementByInternalKey as _WBSElementByInternalKey on $projection.WBSElementInternalID = _WBSElementByInternalKey.WBSElementInternalID
association [0..1] to I_WBSElementBasicData as _WBSElement on _WBSElement.WBSElementInternalID = $projection.WBSElementInternalID
association [0..1] to I_FunctionalArea as _FunctionalArea on $projection.FunctionalArea = _FunctionalArea.FunctionalArea
association [0..1] to I_CommitmentItemShortID as _CommitmentItemShortID on $projection.CommitmentItemShortID = _CommitmentItemShortID.CommitmentItemShortID
association [0..*] to I_FunctionalAreaText as _FunctionalAreaText on $projection.FunctionalArea = _FunctionalAreaText.FunctionalArea
association [0..1] to I_CostCenterActivityType as _CostCenterActivityType on $projection.ControllingArea = _CostCenterActivityType.ControllingArea
and $projection.CostCtrActivityType = _CostCenterActivityType.CostCtrActivityType
and $projection.ValidityDate <= _CostCenterActivityType.ValidityEndDate
and $projection.ValidityDate >= _CostCenterActivityType.ValidityStartDate
association [0..*] to I_CostCenterActivityTypeText as _CostCenterActivityTypeText on $projection.ControllingArea = _CostCenterActivityTypeText.ControllingArea
and $projection.CostCtrActivityType = _CostCenterActivityTypeText.CostCtrActivityType
and $projection.ValidityDate <= _CostCenterActivityTypeText.ValidityEndDate
association [0..1] to I_BusinessProcess as _BusinessProcess on $projection.ControllingArea = _BusinessProcess.ControllingArea
and $projection.BusinessProcess = _BusinessProcess.BusinessProcess
association [0..*] to I_BusinessProcessText as _BusinessProcessText on $projection.ControllingArea = _BusinessProcessText.ControllingArea
and $projection.BusinessProcess = _BusinessProcessText.BusinessProcess
and $projection.ValidityDate <= _BusinessProcessText.ValidityEndDate
association [0..*] to I_TaxCode as _TaxCode on $projection.TaxCode = _TaxCode.TaxCode
association [0..*] to I_TaxCodeText as _TaxCodeText on $projection.TaxCode = _TaxCodeText.TaxCode
association [0..*] to I_TaxJurisdiction as _TaxJurisdiction on $projection.TaxJurisdiction = _TaxJurisdiction.TaxJurisdiction
association [0..*] to I_TaxJurisdictionText as _TaxJurisdictionText on $projection.TaxJurisdiction = _TaxJurisdictionText.TaxJurisdiction
//association[0..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [0..*] to I_FixedAsset as _FixedAssetWorklist on $projection.MasterFixedAsset = _FixedAssetWorklist.MasterFixedAsset
and $projection.FixedAsset = _FixedAssetWorklist.FixedAsset
// and $projection.CompanyCode = _FixedAssetWorklist.CompanyCode // to change cardinality to [0..1] when uncommenting this
association [0..*] to I_FixedAsset as _FixedAsset on $projection.MasterFixedAsset = _FixedAsset.MasterFixedAsset
and $projection.FixedAsset = _FixedAsset.FixedAsset
// and $projection.CompanyCode = _FixedAssetWorklist.CompanyCode // to change cardinality to [0..1] when uncommenting this
association [0..*] to I_FundStdVH as _FundStdVH on _FundStdVH.Fund = $projection.Fund
association [0..1] to I_BudgetPeriodStdVH as _BudgetPeriodStdVH on _BudgetPeriodStdVH.BudgetPeriod = $projection.BudgetPeriod
// association [0..1] to I_FundedProgramStdVH as _FundedProgramStdVH on _FundedProgramStdVH.FundedProgram = $projection.fundedprogram
association [0..*] to I_FundsCenterStdVH as _FundsCenterStdVH on _FundsCenterStdVH.FundsCenter = $projection.FundsCenter
association[0..*] to I_CommitmentItemStdVH as _CommitmentItemStdVH on _CommitmentItemStdVH.CommitmentItem = $projection.CommitmentItem
association[0..*] to I_EmrkdFndsDocumentItemStdVH as _EarmarkedFundsStdVH on _EarmarkedFundsStdVH.EarmarkedFundsDocument = $projection.EarmarkedFundsDocument
association[0..1] to I_FndsMgmtFuncnlAreaStdVH as _FndsMgmtFuncnlAreaStdVH on _FndsMgmtFuncnlAreaStdVH.FunctionalArea = $projection.FunctionalArea
association [0..*] to I_MM_CostCenterValueHelp as _MM_CostCenterValueHelp on $projection.CostCenter = _MM_CostCenterValueHelp.CostCenter
association [0..1] to I_WBSElementByInternalKey as _WBSElementByInternalKeyVH on $projection.WBSElementInternalID = _WBSElementByInternalKeyVH.WBSElementInternalID
association [0..*] to I_MM_GLAccountVH as _MM_GLAccountVH on $projection.GLAccount = _MM_GLAccountVH.GLAccount
association [0..1] to I_AcctgServiceDocumentTypeVH as _AcctgServiceDocumentTypeVH on $projection.ServiceDocumentType = _AcctgServiceDocumentTypeVH.ServiceDocumentType
association [0..*] to I_AcctgServiceDocumentVH as _AcctgServiceDocumentVH on $projection.ServiceDocument = _AcctgServiceDocumentVH.ServiceDocument
association [0..*] to I_AcctgServiceDocumentItemVH as _AcctgServiceDocumentItemVH on $projection.ServiceDocumentItem = _AcctgServiceDocumentItemVH.ServiceDocumentItem
and $projection.ServiceDocument = _AcctgServiceDocumentItemVH.ServiceDocument
{
key PurchasingDocument,
key PurchasingDocumentItem,
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
key AccountAssignmentNumber,
--@Consumption: { valueHelp: '_CostCenterValueHelp', semanticObject: 'CostCenter' }
@ObjectModel.foreignKey.association: '_CostCenter' -- to be clarified --
@ObjectModel.text.association: '_CostCenterText'
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
@Consumption.valueHelp: '_MM_CostCenterValueHelp'
CostCenter,
@ObjectModel.foreignKey.association: '_FixedAsset'
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
MasterFixedAsset,
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
ProjectNetwork,
@Semantics.unitOfMeasure: true
_PurchasingDocumentItem.OrderQuantityUnit,
@Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
Quantity,
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
MultipleAcctAssgmtDistrPercent,
@Semantics.currencyCode: true
_PurchasingDocumentItem.DocumentCurrency,
@Semantics.amount.currencyCode: 'DocumentCurrency'
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
PurgDocNetAmount,
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
IsDeleted,
@ObjectModel.foreignKey.association: '_GLAccount'
//@ObjectModel.text.association: '_GLAccountText'
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
@Consumption.valueHelp: '_MM_GLAccountVH'
GLAccount,
@ObjectModel.foreignKey.association: '_BusinessArea'
@ObjectModel.text.association: '_BusinessAreaText'
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
BusinessArea,
@ObjectModel.foreignKey.association: '_SalesOrder'
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
SalesOrder,
@ObjectModel.foreignKey.association: '_SalesOrderItem'
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
SalesOrderItem,
@ObjectModel.foreignKey.association: '_SalesDocumentScheduleLine'
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
SalesOrderScheduleLine,
@ObjectModel.foreignKey.association: '_FixedAsset'
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
FixedAsset,
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
OrderID,
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
UnloadingPointName,
@ObjectModel.foreignKey.association: '_ControllingArea'
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
ControllingArea,
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
CostObject,
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'ProfitabilitySegment_2'
cast( ProfitabilitySegment as rkeobjnr ) as ProfitabilitySegment,
ProfitabilitySegment as ProfitabilitySegment_2,
@ObjectModel.foreignKey.association: '_ProfitCenter'
@ObjectModel.text.association: '_ProfitCenterText'
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
ProfitCenter,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'WBSElementInternalID_2'
@ObjectModel.foreignKey.association: '_WBSElementByInternalKey'
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
cast( WBSElementInternalID as ps_psp_pnr ) as WBSElementInternalID,
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
WBSElementInternalID as WBSElementInternalID_2,
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
ProjectNetworkInternalID,
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
@Consumption.valueHelp: '_CommitmentItemStdVH'
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'CommitmentItemShortID'
cast( CommitmentItemShortID as fipos ) as CommitmentItem,
CommitmentItemShortID,
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
@Consumption.valueHelp: '_FundsCenterStdVH'
FundsCenter,
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
@Consumption.valueHelp: '_FundStdVH'
Fund,
//@ObjectModel.readOnly: 'undefined'
//@ObjectModel.mandatory: 'undefined'
//geber as Funds,//Deprectaed . Please use AssetFund
@ObjectModel.foreignKey.association: '_FunctionalArea'
@ObjectModel.text.association: '_FunctionalAreaText'
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
@Consumption.valueHelp: '_FndsMgmtFuncnlAreaStdVH'
FunctionalArea,
LastChangedDate, // obsolete, do not use
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
CreationDate, //new , modified
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
GoodsRecepientName, //obsolete, use GoodsRecipientName instead
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
GoodsRecipientName, //new , added
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
IsFinallyInvoiced, //new , added
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'REInternalFinNumber'
cast( REInternalFinNumber as imkey ) as RealEstateObject, //new , added
REInternalFinNumber,
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
NetworkActivityInternalID, //new, added
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
PartnerAccountNumber, //new, added
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
JointVentureRecoveryCode, // new, added
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
SettlementReferenceDate, // new, added
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
OrderInternalID, // new, added
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
OrderIntBillOfOperationsItem, // new, added
@ObjectModel.foreignKey.association: '_TaxCode'
@ObjectModel.text.association: '_TaxCodeText'
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
TaxCode, // new, added
@ObjectModel.foreignKey.association: '_TaxJurisdiction'
@ObjectModel.text.association: '_TaxJurisdictionText'
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
TaxJurisdiction, // new, added
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
@Semantics.amount.currencyCode: 'DocumentCurrency'
NonDeductibleInputTaxAmount, //new, added
@ObjectModel.foreignKey.association: '_CostCenterActivityType'
@ObjectModel.text.association: '_CostCenterActivityTypeText'
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
CostCtrActivityType, // new, added
@ObjectModel.foreignKey.association: '_BusinessProcess'
@ObjectModel.text.association: '_BusinessProcessText'
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
BusinessProcess, // new, added
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
@Consumption.valueHelp: '_BudgetPeriodStdVH'
GrantID, // new, added
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
// @Consumption.valueHelp: ' '
BudgetPeriod, // new, added
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
@Consumption.valueHelp: '_EarmarkedFundsStdVH'
EarmarkedFundsDocument, // new, added
@Semantics.businessDate.at: true
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
@EndUserText.label: 'Validity Date'
$session.system_date as ValidityDate, // new, added
_ControllingArea.ChartOfAccounts as ChartOfAccounts,
cast( EarmarkedFundsDocumentItem as kblpos) as EarmarkedFundsItem, // new, added
EarmarkedFundsDocumentItem, // new, added
PubSecSplitBatchNumberID, // new, added
PubSecSplitAuthznGroup, // new, added
IsAcctLineFinal, // new, added
AcctLineFinalReason, // new, added
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
@Consumption.valueHelp: '_AcctgServiceDocumentTypeVH'
ServiceDocumentType, // new, added
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
@Consumption.valueHelp: '_AcctgServiceDocumentVH'
ServiceDocument, // new, added
@ObjectModel.readOnly: 'undefined'
@ObjectModel.mandatory: 'undefined'
@Consumption.valueHelp: '_AcctgServiceDocumentItemVH'
ServiceDocumentItem, // new, added
//@ObjectModel.foreignKey.association: '_CompanyCode'
//@UI:{
// fieldGroup: {qualifier: 'ThirdGroup', position: 10, importance: #HIGH}
// }
//@ObjectModel.readOnly: 'undefined'
//@ObjectModel.mandatory: 'undefined'
//_GLAccount.CompanyCode as CompanyCode, //new, added
//_CostCenterValueHelp,
_CostCenter,
_BusinessArea,
_ProfitCenter,
_SalesOrderItem,
_SalesOrder,
_ControllingArea,
_GLAccount,
_SalesDocumentScheduleLine, // new, added
_WBSElementByInternalKey, // new, added
_WBSElement,
_CommitmentItemShortID,
_FunctionalArea, // new, added
_CostCenterActivityType, // new, added
_BusinessProcess, // new, added
_TaxCode, // new, added
_TaxJurisdiction, //new, added
//_CompanyCode, // new, added
_FixedAssetWorklist,
_FixedAsset,
_CostCenterText, // new, added
_GLAccountText, //new, added
_BusinessAreaText, //new, added
_ProfitCenterText, //new, added
_FunctionalAreaText, //new, added
_CostCenterActivityTypeText, //new, added
_BusinessProcessText, // new, added
_TaxCodeText, //new, added
_TaxJurisdictionText, // new, added
_FundStdVH,
_BudgetPeriodStdVH,
_FundsCenterStdVH,
_CommitmentItemStdVH,
_EarmarkedFundsStdVH,
_FndsMgmtFuncnlAreaStdVH,
_MM_CostCenterValueHelp,
_WBSElementByInternalKeyVH,
_MM_GLAccountVH,
_AcctgServiceDocumentTypeVH,
_AcctgServiceDocumentVH,
_AcctgServiceDocumentItemVH
}