I_PURCHASINGCATEGORY

@EndUserText.label: 'Purchasing Category'
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@AbapCatalog.sqlViewName: 'IPURGCATRT'
@AbapCatalog.preserveKey:true
@ObjectModel.usageType.dataClass:  #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.semanticKey: ['PurchasingCategory']
@ObjectModel.representativeKey: ['PurgCatUUID']
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.compositionRoot: true


define view I_PurchasingCategory as select from /srmsmc/d_puc_rt
  association [0..*] to I_PurchasingCategoryDesc as _PurchasingCategoryDesc on $projection.PurgCatUUID = _PurchasingCategoryDesc.PurgCatUUID
  association [0..*] to I_PurchasingCategoryPlanSpend as _PurchasingCategoryPlanSpend on $projection.PurgCatUUID = _PurchasingCategoryPlanSpend.PurgCatUUID
  association [0..*] to I_PurchasingCategoryMatlGroup as _PurchasingCategoryMatlGroup on $projection.PurgCatUUID = _PurchasingCategoryMatlGroup.PurgCatUUID
  association [0..1] to I_InactiveStatus as _InactiveStatus on $projection.PurgCatIsInactive = _InactiveStatus.PurgCatIsInactive
  association [0..1] to I_Language as _Language on $projection.Language = _Language.Language   
  
  //Obsolete

  association [0..1] to I_SLCTranslationStatus as _SLCTranslationStatus on $projection.PurgCatTranslationOvrlStatus = _SLCTranslationStatus.SLCTranslationStatus
  association [0..1] to I_SLCTranslationStatus as _PurgCatTranslationOvrlStatus on $projection.PurgCatTranslationOvrlStatus = _PurgCatTranslationOvrlStatus.SLCTranslationStatus
//  association [0..*] to I_PurchasingCategoryPurchResp as _PurchaserResponsible on $projection.PurgCatUUID = _PurchaserResponsible.PurgCatUUID

  
  association [0..*] to I_PurchasingCategoryParty as _PurchasingCategoryParty on $projection.PurgCatUUID = _PurchasingCategoryParty.PurgCatUUID
  association [0..1] to I_PurchasingCategorySupplier as _Supplier on $projection.PurgCatUUID = _Supplier.PurgCatUUID
  association [0..*] to I_SupplierActivity as _SupplierActivity on $projection.PurgCatUUID = _SupplierActivity.PurgCatUUID
  association [0..*] to I_PurchasingCatTranslationSts as _PurchasingCatTranslationSts on $projection.PurgCatUUID = _PurchasingCatTranslationSts.PurgCatUUID
  association [0..1] to I_User as _CreatedByUser on $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User as _LastChangedByUser on $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [0..*] to I_SLCContactCard as _ContactCard on (ContactCardType = '/srmsmc/d_puc_py' and ContactCardUUID = $projection.PurgCatUUID)
  association [0..1] to I_PurchasingCategoryPurchResp as _PurchaserResponsible on $projection.PurgCatUUID = _PurchaserResponsible.PurgCatUUID
{
    //ID

    @UI.hidden: true
    @ObjectModel.text.element: 'PurgCatName' 
    key cast (db_key as /srmsmc/puc_uuid preserving type) as PurgCatUUID,
 
    @ObjectModel.text.element: 'PurgCatName' 
    cast( id as /srmsmc/purchasing_category_id preserving type) as PurchasingCategory,

    //Details 

    @Semantics.text: true  
    cast( name as /srmsmc/puc_name preserving type) as PurgCatName,
    
            
    //Admin

    cast( crea_date_time as /srmsmc/created_on_ts preserving type) as CreationDateTime,
    
    @Semantics.user.createdBy: true
//    @ObjectModel.foreignKey.association: '_CreatedByUser'

    cast( crea_uname as vdm_createdbyuserid) as CreatedByUser,
    
    cast( lchg_date_time as /srmsmc/last_changed_on_ts) as  LastChangeDateTime,
    
    @Semantics.user.lastChangedBy: true
//    @ObjectModel.foreignKey.association: '_LastChangedByUser'

    cast( lchg_uname as vdm_lastchangedbyuserid) as LastChangedByUser,
    
    @Semantics.language: true
    @ObjectModel.foreignKey.association: '_Language'
    cast( language_code as /srmsmc/language preserving type) as Language,
    
    //Status

    @UI.textArrangement: #TEXT_ONLY
    @ObjectModel.foreignKey.association: '_InactiveStatus'
    cast( inactive as /srmsmc/inactive_status preserving type) as PurgCatIsInactive,
    
    @ObjectModel.foreignKey.association: '_PurgCatTranslationOvrlStatus'
    cast(trans_status as /srmsmc/overall_transl_status preserving type ) as PurgCatTranslationOvrlStatus,   
    
    //obsolete

    @Consumption.hidden: true
    @UI.hidden:true
    cast(trans_status as /srmsmc/overall_transl_status preserving type ) as SLCTranslationStatus,   
               
    // Associations

    _CreatedByUser, 
    _LastChangedByUser,
    _ContactCard, //do not use!

    _Supplier,
    
    @ObjectModel.association.type: #TO_COMPOSITION_CHILD    
    _PurchasingCategoryParty,
    @ObjectModel.association.type: #TO_COMPOSITION_CHILD
    _PurchasingCategoryMatlGroup,
    @ObjectModel.association.type: #TO_COMPOSITION_CHILD
    _PurchasingCategoryDesc,
    @ObjectModel.association.type: #TO_COMPOSITION_CHILD
    _PurchasingCategoryPlanSpend,
    @ObjectModel.association.type: #TO_COMPOSITION_CHILD
    _PurchaserResponsible,

    _SupplierActivity,

    
    //Status or Text Views

    _InactiveStatus,
    _PurgCatTranslationOvrlStatus,
    _SLCTranslationStatus,
    _PurchasingCatTranslationSts,
    _Language
    
}                                                                                          
  
  
  
  
  
  
  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"/SRMSMC/D_PUC_RT"
],
"ASSOCIATED":
[
"I_INACTIVESTATUS",
"I_LANGUAGE",
"I_PURCHASINGCATEGORYDESC",
"I_PURCHASINGCATEGORYMATLGROUP",
"I_PURCHASINGCATEGORYPARTY",
"I_PURCHASINGCATEGORYPLANSPEND",
"I_PURCHASINGCATEGORYPURCHRESP",
"I_PURCHASINGCATEGORYSUPPLIER",
"I_PURCHASINGCATTRANSLATIONSTS",
"I_SLCCONTACTCARD",
"I_SLCTRANSLATIONSTATUS",
"I_SUPPLIERACTIVITY",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/