I_PURREQNACCOUNTASSIGNMENT
Purchase Requisition Account Assignment
I_PURREQNACCOUNTASSIGNMENT is a CDS View in S/4HANA. Purchase Requisition Account Assignment. It contains 39 fields. 8 CDS views read from this table.
CDS Views using this table (8)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| I_MRPPurchaseRequisition | view | left_outer | COMPOSITE | MRP Purchase Requisition |
| I_PurReqnQuickView | view | left_outer | COMPOSITE | Purchase Requisition Details |
| P_PurReqItemAcctmntr | view | from | CONSUMPTION | PR Items by Account Assignment |
| P_PurReqnAvgApprvlCrcyConvrsn | view | left_outer | CONSUMPTION | Purchase requisiton currency conversion |
| P_PurReqnCurrencyConvrsn | view | left_outer | CONSUMPTION | |
| P_PurReqnItemTypeAnalysis | view | left_outer | CONSUMPTION | Purchase Requistion No Touch for OVP |
| P_PurReqnItmAccountAssignment | view | from | CONSUMPTION | PR Item Account Assignment |
| P_PurRequisitionNoTouch1 | view | left_outer | CONSUMPTION | Purchase Requisition No Touch1 |
Fields (39)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | CostCenter | CostCenter | 5 |
| KEY | PurchaseReqnAcctAssgmtNumber | AccountAssignmentNumber,PurchaseReqnAcctAssgmtNumber | 3 |
| KEY | PurchaseRequisition | PurchaseRequisition | 1 |
| KEY | PurchaseRequisitionItem | PurchaseRequisitionItem | 1 |
| _BusinessArea | _BusinessArea | 1 | |
| _ControllingArea | _ControllingArea | 1 | |
| _CostCenter | _CostCenter | 1 | |
| _GLAccount | _GLAccount | 1 | |
| _ProfitCenter | _ProfitCenter | 1 | |
| _SalesOrder | _SalesOrder | 1 | |
| _SalesOrderItem | _SalesOrderItem | 1 | |
| BudgetPeriod | BudgetPeriod | 1 | |
| BusinessArea | BusinessArea | 1 | |
| CommitmentItemShortID | CommitmentItemShortID | 1 | |
| ControllingArea | ControllingArea | 1 | |
| CostObject | CostObject | 1 | |
| EarmarkedFunds | EarmarkedFunds | 1 | |
| EarmarkedFundsItem | EarmarkedFundsItem | 1 | |
| FixedAsset | FixedAsset | 1 | |
| FunctionalArea | FunctionalArea | 1 | |
| Fund | Fund | 1 | |
| FundsCenter | FundsCenter | 1 | |
| GLAccount | GLAccount | 1 | |
| GrantID | GrantID | 1 | |
| MasterFixedAsset | MasterFixedAsset | 1 | |
| MultipleAcctAssgmtDistrPercent | MultipleAcctAssgmtDistrPercent | 1 | |
| ProcessOrder | ProcessOrder | 1 | |
| ProfitabilitySegment | ProfitabilitySegment | 1 | |
| ProfitabilitySegment_2 | ProfitabilitySegment_2 | 1 | |
| ProfitCenter | ProfitCenter | 1 | |
| ProjectNetwork | ProjectNetwork | 1 | |
| ProjectNetworkInternalID | ProjectNetworkInternalID | 1 | |
| PurReqnNetAmount | PurReqnNetAmount | 1 | |
| Quantity | Quantity | 1 | |
| SalesOrder | SalesDocument,SalesOrder | 3 | |
| SalesOrderItem | SalesDocumentItem,SalesOrderItem | 3 | |
| SalesOrderScheduleLine | SalesOrderScheduleLine | 1 | |
| UnloadingPointName | UnloadingPointName | 1 | |
| WBSElementInternalID | WBSElementInternalID | 2 |
@EndUserText.label: 'Purchase Requisition Account Assignment'
@AccessControl.authorizationCheck:#PRIVILEGED_ONLY
@VDM.viewType : #BASIC
@AbapCatalog.sqlViewName: 'IMMPURREQACCASS'
@ObjectModel.usageType.serviceQuality: #A
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
define view I_PurReqnAccountAssignment
as select from ebkn
association [0..*] to I_CostCenter as _CostCenter on $projection.CostCenter = _CostCenter.CostCenter
and $projection.ControllingArea = _CostCenter.ControllingArea
association [0..*] to I_GLAccount as _GLAccount on $projection.GLAccount = _GLAccount.GLAccount
association [0..1] to I_BusinessArea as _BusinessArea on $projection.BusinessArea = _BusinessArea.BusinessArea
association [0..*] to I_ProfitCenter as _ProfitCenter on $projection.ControllingArea = _ProfitCenter.ControllingArea
and $projection.ProfitCenter = _ProfitCenter.ProfitCenter
association [0..1] to I_SalesOrder as _SalesOrder on $projection.SalesOrder = _SalesOrder.SalesOrder
association [0..1] to I_SalesOrderItem as _SalesOrderItem on $projection.SalesOrderItem = _SalesOrderItem.SalesOrder
and $projection.SalesOrder = _SalesOrderItem.SalesOrderItem
association [0..1] to I_ControllingArea as _ControllingArea on $projection.ControllingArea = _ControllingArea.ControllingArea
{
key banfn as PurchaseRequisition,
key cast (bnfpo as vdm_purchaserequisitionitem) as PurchaseRequisitionItem,
key zebkn as PurchaseReqnAcctAssgmtNumber,
kostl as CostCenter,
anln1 as MasterFixedAsset,
nplnr as ProjectNetwork,
aufnr as ProcessOrder,
menge as Quantity,
vproz as MultipleAcctAssgmtDistrPercent,
@UI.hidden: true
@Semantics.currencyCode: true
cast ('' as abap.cuky) as Currency,
@Semantics.amount.currencyCode: 'Currency'
netwr as PurReqnNetAmount,
loekz as IsDeleted,
sakto as GLAccount,
gsber as BusinessArea,
vbeln as SalesOrder,
vbelp as SalesOrderItem,
veten as SalesOrderScheduleLine,
anln2 as FixedAsset,
aufnr as OrderID,
ablad as UnloadingPointName,
kokrs as ControllingArea,
kstrg as CostObject,
// paobjnr as ProfitabilitySegment,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'ProfitabilitySegment_2'
paobjnr as ProfitabilitySegment,
cast( paobjnr as rkeobjnr_char ) as ProfitabilitySegment_2,
prctr as ProfitCenter,
@API.element.releaseState: #DEPRECATED
@API.element.successor: 'WBSElementInternalID_2'
ps_psp_pnr as WBSElementInternalID,
cast( ps_psp_pnr as ps_s4_pspnr ) as WBSElementInternalID_2,
aufpl as ProjectNetworkInternalID,
@API.element.releaseState: #DEPRECATED
@API.element.successor: 'CommitmentItemShortID'
fipos as CommitmentItem,
cast( fipos as fmis_ci_internalname ) as CommitmentItemShortID,
fistl as FundsCenter,
geber as Fund,
fkber as FunctionalArea,
budget_pd as BudgetPeriod,
grant_nbr as GrantID,
kblnr as EarmarkedFunds,
kblpos as EarmarkedFundsItem,
_CostCenter,
_BusinessArea,
_ProfitCenter,
_SalesOrderItem,
_SalesOrder,
_ControllingArea,
_GLAccount
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"EBKN"
],
"ASSOCIATED":
[
"I_BUSINESSAREA",
"I_CONTROLLINGAREA",
"I_COSTCENTER",
"I_GLACCOUNT",
"I_PROFITCENTER",
"I_SALESORDER",
"I_SALESORDERITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/