I_PUBSECBUDGETACCOUNTTEXT

CDS View

Budget Account - Text

I_PUBSECBUDGETACCOUNTTEXT is a CDS View in S/4HANA. Budget Account - Text. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_BudgetAccountCoreText view_entity from BASIC API for Budget Account Text 
@AbapCatalog.sqlViewName: 'IPSMS4CBDACCTT'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Budget Account - Text'

@ObjectModel.dataCategory: #TEXT
@VDM.viewType: #BASIC
@AbapCatalog.buffering.status: #NOT_ALLOWED
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
     representativeKey: 'PubSecBudgetAccount',
     usageType: {
         dataClass: #MASTER,
         serviceQuality: #B,
         sizeCategory: #S
     },
     supportedCapabilities: [ #LANGUAGE_DEPENDENT_TEXT ]          
}
@Search.searchable: true
// added to have type ahead functionality

@Consumption.ranked: true

define view I_PubSecBudgetAccountText
  as select from I_BudgetAccountText as MainText
    inner join   P_Glacct_In_Cc      as I_GLAccountInCompanyCode on  MainText.ChartOfAccounts     = I_GLAccountInCompanyCode.ChartOfAccounts
                                                                 and MainText.PubSecBudgetAccount = I_GLAccountInCompanyCode.GLAccount
  association [0..1] to I_Language        as _Language                  on $projection.Language = _Language.Language
  association [0..1] to I_CompanyCode     as _PubSecBudgetAccountCoCode on $projection.PubSecBudgetAccountCoCode = _PubSecBudgetAccountCoCode.CompanyCode
  association [0..1] to I_ChartOfAccounts as _ChartOfAccounts           on $projection.ChartOfAccounts = _ChartOfAccounts.ChartOfAccounts
{
      @Search.defaultSearchElement:true
      @Search.fuzzinessThreshold:0.8
      @Search.ranking:#LOW
      @ObjectModel.text.element: 'BudgetAccountDescription'
  key MainText.PubSecBudgetAccount,
      @ObjectModel.foreignKey.association: '_PubSecBudgetAccountCoCode' //Inserted by VDM CDS Suite Plugin

  key cast( I_GLAccountInCompanyCode.CompanyCode as psm_bdgt_account_cocode preserving type ) as PubSecBudgetAccountCoCode,
      @Semantics.language
      @ObjectModel.foreignKey.association: '_Language' //Inserted by VDM CDS Suite Plugin

  key MainText.Language,
      @ObjectModel.foreignKey.association: '_ChartOfAccounts' //Inserted by VDM CDS Suite Plugin

      MainText.ChartOfAccounts,

      @Semantics.text: true
      @Search.defaultSearchElement:true
      @Search.fuzzinessThreshold:0.8
      @Search.ranking:#LOW
      MainText.BudgetAccountName,
      @Semantics.text: true
      @Search.defaultSearchElement:true
      @Search.fuzzinessThreshold:0.8
      @Search.ranking:#LOW
      MainText.BudgetAccountDescription,
      _Language,
      _PubSecBudgetAccountCoCode,
      _ChartOfAccounts
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUDGETACCOUNTTEXT",
"P_GLACCT_IN_CC"
],
"ASSOCIATED":
[
"I_CHARTOFACCOUNTS",
"I_COMPANYCODE",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More