I_PROVIDERCONTRACT

CDS View

Provider Contract

I_PROVIDERCONTRACT is a CDS View in S/4HANA. Provider Contract. It contains 4 fields. 7 CDS views read from this table.

Used by 7 CDS view(s) 4 fields

CDS Views using this table (7)

ViewTypeJoinVDMDescription
C_BSOrdItmProcFlwSubscrpnItem view from CONSUMPTION Subscription Item Attrib for BSOrd Prgrs
C_BSOrdProcFlwSubscription view from CONSUMPTION Subscription Attrib for BSOrd Prgrs
C_BSQPMProviderContract view_entity from CONSUMPTION BSQPM Provider Contract Attribute
I_CAProviderContractHeader view from BASIC Provider Contract Header
I_ProviderContractVH view_entity from COMPOSITE Provider Contract
I_SalesBillingProviderContract view_entity from BASIC Provider Contract for Sales Billing
I_SalesProviderContract view from BASIC Provider-Vertrag für Sales Billing

Fields (4)

KeyField CDS FieldsUsed in Views
KEY ProviderContract UI5NetworkGraphAttributeValue 1
CAPrvdrContrEndDateTime CAPrvdrContrEndDateTime 1
CAPrvdrContrStartDateTime CAPrvdrContrStartDateTime 1
CreationDate CreationDate 1 
@AbapCatalog: { compiler.compareFilter:true,
                preserveKey:true,
                sqlViewName: 'IPRVDRCONTR' }

@AccessControl: { authorizationCheck: #CHECK,
                  personalData.blocking : #REQUIRED }

@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Provider Contract'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: { representativeKey: 'ProviderContract',
                supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET,
                                         #SQL_DATA_SOURCE,
                                         #CDS_MODELING_DATA_SOURCE ],
                usageType: { dataClass: #MASTER,
                             serviceQuality: #B,
                             sizeCategory: #XL } }

@VDM.viewType: #BASIC

define view I_ProviderContract
  as select from dfkk_vt_h

  association [1..1] to I_BusinessPartner           as _BusinessPartner           on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [0..1] to I_CAAuthorizationGroup      as _CAAuthorizationGroup      on  $projection.CAAuthorizationGroup                 = _CAAuthorizationGroup.CAAuthorizationGroup
                                                                                  and _CAAuthorizationGroup.CAAuthorizationGroupObject = 'CA_BILLCTR'
  association [1..1] to I_CompanyCode               as _CompCode                  on  $projection.CompanyCode = _CompCode.CompanyCode
  association [1..1] to I_ProviderContractCategory  as _ProviderContractCategory  on  $projection.CAProviderContractCategory = _ProviderContractCategory.CAProviderContractCategory
  association [0..1] to I_ProviderContractMigrtnSts as _ProviderContractMigrtnSts on  $projection.CAProviderContractMigrtnStatus = _ProviderContractMigrtnSts.CAProviderContractMigrtnStatus
  association [1..1] to I_ProviderContractType      as _ProviderContractType      on  $projection.CAProviderContractType = _ProviderContractType.CAProviderContractType
  association [1..1] to I_ProviderContractStatus    as _ProviderContractStatus    on  $projection.CAProviderContractStatus = _ProviderContractStatus.CAProviderContractStatus
  association [0..1] to I_ProviderContractSender    as _ProviderContractSender    on  $projection.CAProviderContractSender = _ProviderContractSender.CAProviderContractSender

  association [1..1] to I_User                      as _CreatedByUser             on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                      as _LastChangedByUser         on  $projection.LastChangedByUser = _LastChangedByUser.UserID

  association [1..1] to I_TimeZone                  as _TimeZone                  on  $projection.TimeZoneID = _TimeZone.TimeZoneID
{
  key vtkey                                           as ProviderContract,

      @ObjectModel.foreignKey.association: '_BusinessPartner'
      cast(gpart as bu_partner preserving type )      as BusinessPartner,
      erdat                                           as CreationDate,
      cast(ertim as ttet_dt_cr_time preserving type ) as CreationTime,
      @ObjectModel.foreignKey.association: '_CreatedByUser'
      ernam                                           as CreatedByUser,
      cast(loevm as loevm preserving type )           as IsMarkedForDeletion,
      aedat                                           as LastChangeDate,
      aetim                                           as LastChangeTime,
      @ObjectModel.foreignKey.association: '_LastChangedByUser'
      aenam                                           as LastChangedByUser,
      vtbez                                           as CAProviderContractName,
      vtalt                                           as CAProviderContractExtReference,
      vtbeg                                           as CAPrvdrContrStartDateTime,
      vtend                                           as CAPrvdrContrEndDateTime,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'CAAuthorizationGroup'
      begru                                           as AuthorizationGroup,
      @ObjectModel.foreignKey.association: '_CAAuthorizationGroup'
      begru                                           as CAAuthorizationGroup,
      @ObjectModel.foreignKey.association: '_CompCode'
      bukrs                                           as CompanyCode,
      @ObjectModel.foreignKey.association: '_TimeZone'
      cast(tzone as tznzone preserving type )         as TimeZoneID,
      @ObjectModel.foreignKey.association: '_ProviderContractCategory'
      vtcat                                           as CAProviderContractCategory,
      @ObjectModel.foreignKey.association: '_ProviderContractMigrtnSts'
      migst                                           as CAProviderContractMigrtnStatus,
      @ObjectModel.foreignKey.association: '_ProviderContractType'
      vtchr                                           as CAProviderContractType,
      @ObjectModel.foreignKey.association: '_ProviderContractStatus'
      statu                                           as CAProviderContractStatus,
      @ObjectModel.foreignKey.association: '_ProviderContractSender'
      sender                                          as CAProviderContractSender,
      vtend_min                                       as PrvdrContrEarliestEndDateTime,
      vtper_min                                       as MinNrOfMonthsForContractPeriod,
      vtper_rnwl                                      as NrOfMonthsForContractRenewal,
      vtper_canc                                      as NrOfDaysForContrNoticePeriod,
      uti_bbptype                                     as BudgetBillingPlanType,

      /* association */
      _BusinessPartner,
      _CAAuthorizationGroup,
      _CompCode,
      _ProviderContractCategory,
      _ProviderContractMigrtnSts,
      _ProviderContractType,
      _ProviderContractStatus,
      _ProviderContractSender,
      _CreatedByUser,
      _LastChangedByUser,
      _TimeZone

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DFKK_VT_H"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CAAUTHORIZATIONGROUP",
"I_COMPANYCODE",
"I_PROVIDERCONTRACTCATEGORY",
"I_PROVIDERCONTRACTMIGRTNSTS",
"I_PROVIDERCONTRACTSENDER",
"I_PROVIDERCONTRACTSTATUS",
"I_PROVIDERCONTRACTTYPE",
"I_TIMEZONE",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More