I_PRODUCTIONHOLDBASIC

@AbapCatalog.sqlViewName: 'IMPEPRODNHLDBSC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'ProductionHold'
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@Search.searchable: true
@VDM.viewType: #BASIC
@EndUserText.label: 'Production Hold'
define view I_ProductionHoldBasic
  as select from mpe_exec_hold as hold
  association [1..1] to I_ProductionHoldObjectType    as _ProductionHoldObjectType  on  $projection.ProductionHoldObjectType = _ProductionHoldObjectType.ProductionHoldObjectType
  association [1..1] to I_Plant                       as _ProductionPlant           on  $projection.ProductionPlant = _ProductionPlant.Plant
  association [0..1] to I_Material                    as _Material                  on  $projection.Material = _Material.Material
  association [0..1] to I_WorkCenter                  as _WorkCenter                on  $projection.WorkCenterTypeCode   = _WorkCenter.WorkCenterTypeCode
                                                                                    and $projection.WorkCenterInternalID = _WorkCenter.WorkCenterInternalID
  association [0..1] to I_MfgOrder                    as _MfgOrder                  on  $projection.ManufacturingOrder = _MfgOrder.ManufacturingOrder
  association [1..1] to I_OrdInternalBillOfOperations as _OrderInternalID           on  $projection.OrderInternalID = _OrderInternalID.OrderInternalBillOfOperations
  association [0..1] to I_MfgOrderOperation           as _MfgOrderOperation         on  $projection.OrderInternalID          = _MfgOrderOperation.OrderInternalBillOfOperations
                                                                                    and $projection.OrderOperationInternalID = _MfgOrderOperation.OrderIntBillOfOperationsItem
  association [0..1] to I_ShopFloorItem               as _ShopFloorItem             on  $projection.ShopFloorItem = _ShopFloorItem.ShopFloorItem
  association [1..1] to I_ProductionHoldStatus        as _ProductionHoldStatus      on  $projection.ProductionHoldStatus = _ProductionHoldStatus.ProductionHoldStatus
  association [0..1] to I_OpActyNtwkInstance          as _OpActyNtwkInstance        on  $projection.OpActyNtwkInstance = _OpActyNtwkInstance.OpActyNtwkInstance
  association [0..1] to I_OperationActivityInstance   as _OperationActivityInstance on  $projection.OpActyNtwkInstance = _OperationActivityInstance.OpActyNtwkInstance
                                                                                    and $projection.OpActyNtwkElement  = _OperationActivityInstance.OpActyNtwkElement
  association [0..1] to I_Defect                      as _Defect                    on  $projection.DefectInternalID = _Defect.DefectInternalID
  association [0..1] to I_Notification                as _Notification              on  $projection.Notification = _Notification.Notification
  association [0..1] to I_NotificationItem            as _NotificationItem          on  $projection.Notification     = _NotificationItem.Notification
                                                                                    and $projection.NotificationItem = _NotificationItem.NotificationItem
  association [0..1] to I_OperationActivitySFIGroup   as _OperationActivitySFIGroup on  $projection.OperationActivitySFIGroup = _OperationActivitySFIGroup.OperationActivitySFIGroup
{
      //Key

      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key hold_nmbr                               as ProductionHold,

      @ObjectModel.foreignKey.association: '_ProductionHoldObjectType'
      hold_object_type                        as ProductionHoldObjectType,
      @ObjectModel.foreignKey.association: '_ProductionPlant'
      werks                                   as ProductionPlant,
      @ObjectModel.foreignKey.association: '_Material'
      matnr                                   as Material,
      @ObjectModel.foreignKey.association: '_WorkCenter'
      arbid                                   as WorkCenterInternalID,
      cast('A ' as cr_objty preserving type)  as WorkCenterTypeCode,
      @ObjectModel.foreignKey.association: '_MfgOrder'
      aufnr                                   as ManufacturingOrder,
      @ObjectModel.foreignKey.association: '_OrderInternalID'
      aufpl                                   as OrderInternalID,
      aplzl                                   as OrderOperationInternalID,
      @ObjectModel.foreignKey.association: '_ShopFloorItem'
      sfi_id                                  as ShopFloorItem,
      @ObjectModel.foreignKey.association: '_OperationActivitySFIGroup'
      sfi_at_oai_group_id                     as OperationActivitySFIGroup,
      @ObjectModel.foreignKey.association: '_OpActyNtwkInstance'
      oan_instance_id                         as OpActyNtwkInstance,
      @ObjectModel.foreignKey.association: '_OperationActivityInstance'
      oan_element_number                      as OpActyNtwkElement,
      started_at                              as ProductionHoldStartDateTime,
      ended_at                                as ProductionHoldEndDateTime,
      @Semantics.durationInSeconds: true
      gross_duration                          as HoldDurationInSeconds,
      @Semantics.durationInSeconds: true
      net_calendar_duration                   as CalendarBasedNetDurnInSeconds,
      @Semantics.durationInSeconds: true
      net_work_center_duration                as WorkCenterBsdNetDurnInSeconds,
      @ObjectModel.foreignKey.association: '_Defect'
      qmnum                                   as DefectInternalID,
      @ObjectModel.foreignKey.association: '_Notification'
      notification                            as Notification,
      @ObjectModel.foreignKey.association: '_NotificationItem'
      notification_item                       as NotificationItem,
      is_applied_for_order_chg                as ProdnHoldIsAppldForOrderChg,
      @ObjectModel.foreignKey.association: '_ProductionHoldStatus'
      cast(case ended_at
        when 0 then ''
        else 'X'
      end as mpe_hold_status preserving type) as ProductionHoldStatus,

      // Associations

      _ProductionHoldObjectType,
      _ProductionPlant,
      _Material,
      _WorkCenter,
      _MfgOrder,
      _OrderInternalID,
      _MfgOrderOperation,
      _ShopFloorItem,
      _ProductionHoldStatus,
      _OpActyNtwkInstance,
      _OperationActivityInstance,
      _Defect,
      _Notification,
      _NotificationItem,
      _OperationActivitySFIGroup
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"MPE_EXEC_HOLD"
],
"ASSOCIATED":
[
"I_DEFECT",
"I_MATERIAL",
"I_MFGORDER",
"I_MFGORDEROPERATION",
"I_NOTIFICATION",
"I_NOTIFICATIONITEM",
"I_OPACTYNTWKINSTANCE",
"I_OPERATIONACTIVITYINSTANCE",
"I_OPERATIONACTIVITYSFIGROUP",
"I_ORDINTERNALBILLOFOPERATIONS",
"I_PLANT",
"I_PRODUCTIONHOLDOBJECTTYPE",
"I_PRODUCTIONHOLDSTATUS",
"I_SHOPFLOORITEM",
"I_WORKCENTER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/