I_PRODUCTVARIANTCHARCVALUATION

CDS View

Product variant-creating characteristic valuation

I_PRODUCTVARIANTCHARCVALUATION is a CDS View in S/4HANA. Product variant-creating characteristic valuation. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_ProductObjPgVariantCharcValn view from CONSUMPTION Product Object Page - Variant Characteristic Valuation 
@AbapCatalog.sqlViewName: 'IPRDVARCHARCVALN'
@EndUserText.label: 'Product variant-creating characteristic valuation'

@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
    usageType: {
        serviceQuality: #C,
        sizeCategory: #XXL,
        dataClass: #MASTER
   }
}

@VDM.viewType: #COMPOSITE

define view I_ProductVariantCharcValuation
  as select from           P_ProductVariantCharcValuation
    join                   I_Characteristic      on I_Characteristic.CharacteristicInternalID = P_ProductVariantCharcValuation.CharacteristicInternalID
    left outer to one join I_CharacteristicValue on  I_CharacteristicValue.CharacteristicInternalID       = P_ProductVariantCharcValuation.CharacteristicInternalID
                                                 and I_CharacteristicValue.CharacteristicValue            = P_ProductVariantCharcValuation.CharacteristicValue
                                                 and I_CharacteristicValue.CharacteristicMinimumValue     = P_ProductVariantCharcValuation.CharacteristicMinimumValue
                                                 and I_CharacteristicValue.CharacteristicMinimumValueUnit = P_ProductVariantCharcValuation.CharacteristicMinimumValueUnit
                                                 and I_CharacteristicValue.CharacteristicMaximumValue     = P_ProductVariantCharcValuation.CharacteristicMaximumValue
                                                 and I_CharacteristicValue.CharacteristicMaximumValueUnit = P_ProductVariantCharcValuation.CharacteristicMaximumValueUnit
                                                 and I_CharacteristicValue.CharacteristicValueDpndcyCode  = P_ProductVariantCharcValuation.CharacteristicValueDpndcyCode
  association [0..1] to I_RetailCharacteristicValue as _RetailCharacteristicValue on  $projection.CharacteristicInternalID = _RetailCharacteristicValue.CharacteristicInternalID
                                                                                  and $projection.CharacteristicValue      = _RetailCharacteristicValue.RetailCharacteristicValue
  association [0..1] to I_UnitOfMeasure             as _UnitOfMeasureBase         on  $projection.CharacteristicBaseUnit = _UnitOfMeasureBase.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure             as _UnitOfMeasureMinimumValue on  $projection.CharacteristicMinimumValueUnit = _UnitOfMeasureMinimumValue.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure             as _UnitOfMeasureMaximumValue on  $projection.CharacteristicMaximumValueUnit = _UnitOfMeasureMaximumValue.UnitOfMeasure
  association [0..*] to I_CharacteristicText        as _CharacteristicText        on  $projection.CharacteristicInternalID = _CharacteristicText.CharacteristicInternalID
  association [0..*] to I_CharacteristicValueText   as _CharacteristicValueText   on  $projection.CharacteristicInternalID      = _CharacteristicValueText.CharacteristicInternalID
                                                                                  and $projection.CharacteristicValueInternalID = _CharacteristicValueText.CharacteristicValueInternalID
  association [1..1] to I_Product                   as _Product                   on  $projection.Product = _Product.Product
{
  key Product,
  key P_ProductVariantCharcValuation.CharacteristicInternalID,

      P_ProductVariantCharcValuation.CharacteristicValue,
      P_ProductVariantCharcValuation.CharacteristicMinimumValue,
      @ObjectModel.foreignKey.association: '_UnitOfMeasureMinimumValue'
      case when P_ProductVariantCharcValuation.CharacteristicMinimumValueUnit != ''
           then P_ProductVariantCharcValuation.CharacteristicMinimumValueUnit
           else I_Characteristic.CharacteristicBaseUnit
      end                                                                            as CharacteristicMinimumValueUnit,
      P_ProductVariantCharcValuation.CharacteristicMaximumValue,
      @ObjectModel.foreignKey.association: '_UnitOfMeasureMaximumValue'
      case when P_ProductVariantCharcValuation.CharacteristicMaximumValueUnit != ''
           then P_ProductVariantCharcValuation.CharacteristicMaximumValueUnit
           else I_Characteristic.CharacteristicBaseUnit
      end                                                                            as CharacteristicMaximumValueUnit,
      P_ProductVariantCharcValuation.CharacteristicValueDpndcyCode,
      I_CharacteristicValue.CharacteristicValueInternalID,
      @ObjectModel.foreignKey.association: '_UnitOfMeasureBase'
      I_Characteristic.CharacteristicBaseUnit,

      _RetailCharacteristicValue,
      _UnitOfMeasureMinimumValue,
      _UnitOfMeasureMaximumValue,
      _UnitOfMeasureBase,
      _CharacteristicText,
      _CharacteristicValueText,
      _Product
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHARACTERISTIC",
"I_CHARACTERISTICVALUE",
"P_PRODUCTVARIANTCHARCVALUATION"
],
"ASSOCIATED":
[
"I_CHARACTERISTICTEXT",
"I_CHARACTERISTICVALUETEXT",
"I_PRODUCT",
"I_RETAILCHARACTERISTICVALUE",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More