I_PRODSUBSTNSET

@AccessControl:{
  authorizationCheck: #CHECK
}
@EndUserText.label: 'Product Substitution Set'
@ObjectModel:{
  usageType:{
    dataClass: #MASTER,
    sizeCategory: #M,
    serviceQuality: #A
  }
}
@VDM: {
  viewType: #COMPOSITE
}

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view entity I_ProdSubstnSet
  as select from I_MDSubstn
  association [1..1] to I_Product   as _Product                   on $projection.Product = _Product.Product
  association [1..1] to I_Product   as _SubstituteProduct         on $projection.SubstituteProduct = _SubstituteProduct.Product
  association [0..1] to I_Plant     as _Plant                     on $projection.Plant = _Plant.Plant
  association [1..1] to I_Indicator as _ExitIndicator             on $projection.MDSubstnIsExit = _ExitIndicator.IndicatorValue
  association [1..1] to I_Indicator as _LeadIndicator             on $projection.MDSubstnIsLeading = _LeadIndicator.IndicatorValue
  association [1..1] to I_Indicator as _MDSubstnIsRlvtForATPProd  on $projection.MDSubstnIsRlvtForATPProd = _MDSubstnIsRlvtForATPProd.IndicatorValue
  association [1..1] to I_Indicator as _MDSubstnIsRelevantForESPP on $projection.MDSubstnIsRelevantForESPP = _MDSubstnIsRelevantForESPP.IndicatorValue
{
  key MDSubstnUUID,
      MDSubstnObjectType,

      @ObjectModel.foreignKey.association: '_Product'
      cast( MDObject as productnumber )                                                                                                         as Product,

      @ObjectModel.foreignKey.association: '_SubstituteProduct'
      cast( MDSubstitute as md_substitute_product )                                                                                             as SubstituteProduct,

      MDSubstnContextObjectType,

      @ObjectModel.foreignKey.association: '_Plant'
      cast( MDSubstnContextObject as werks_d )                                                                                                  as Plant,

      MDSubstnContextObjectType2,
      MDSubstnGroup,
      MDSubstnVersionValue,
      MDSubstnSet,

      @ObjectModel.foreignKey.association: '_ExitIndicator'
      MDSubstnIsExit,

      @ObjectModel.foreignKey.association: '_LeadIndicator'
      MDSubstnIsLeading,

      MDSubstnSequenceValue,
      MDSubstnConversionNumerator,
      MDSubstnConversionDenominator,
      MDSubstnConversionPercent,

      @Semantics.businessDate.from: true
      cast( tstmp_to_dats(MDSubstnValidityStartDateTime, TimeZoneID, $session.client, 'INITIAL') as md_substn_valid_from_date preserving type ) as MDSubstnValidityStartDate,

      @Semantics.time: true
      cast( tstmp_to_tims(MDSubstnValidityStartDateTime, TimeZoneID, $session.client, 'INITIAL') as md_substn_valid_from_time preserving type ) as MDSubstnValidityStartTime,

      @Semantics.businessDate.to: true
      cast( tstmp_to_dats(MDSubstnValidityEndDateTime, TimeZoneID, $session.client, 'INITIAL') as md_substn_valid_to_date preserving type )     as MDSubstnValidityEndDate,

      @Semantics.time: true
      cast( tstmp_to_tims(MDSubstnValidityEndDateTime, TimeZoneID, $session.client, 'INITIAL') as md_substn_valid_to_time preserving type )     as MDSubstnValidityEndTime,

      TimeZoneID,
      MDSubstnReason,
      MDSubstnStatus,

      case MDSubstnStatus
        when 'A' then 3
        else 0
      end                                                                                                                                       as MDSubstnStatusCriticality,

      @ObjectModel.foreignKey.association: '_MDSubstnIsRlvtForATPProd'
      MDSubstnIsRlvtForATPProd,

      @ObjectModel.foreignKey.association: '_MDSubstnIsRelevantForESPP'
      MDSubstnIsRelevantForESPP,

      CreatedByUser,
      CreationDateTime,
      LastChangedByUser,
      LastChangeDateTime,

      /* Associations */
      _MDObjectType,
      _ContextObjectTypeCode,
      _ContextObjectTypeCode2,
      _Product,
      _SubstituteProduct,
      _Plant,
      _Group,
      _ExitIndicator,
      _LeadIndicator,
      _TimeZone,
      _Reason,
      _Status,
      _MDSubstnIsRlvtForATPProd,
      _MDSubstnIsRelevantForESPP
}
where
       MDSubstnObjectType         = 'Product'
  and  MDSubstnContextObjectType  = 'Plant'
  and(
       MDSubstnContextObjectType2 is initial
    or MDSubstnContextObjectType2 is null
  )
  and  MDSubstnSet                is not initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MDSUBSTN"
],
"ASSOCIATED":
[
"I_INDICATOR",
"I_MDSUBSTNGRP",
"I_MDSUBSTNRSN",
"I_MDSUBSTNSTS",
"I_PLANT",
"I_PRODUCT",
"I_SAPOBJECTTYPE",
"I_TIMEZONE"
],
"BASE":
[
"I_MDSUBSTN"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/