I_PROCORDMGMTOPBASIC

@AbapCatalog.sqlViewName: 'IPROORMGMTOPBSC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Process order operation afvg'
//@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')

@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@Metadata.ignorePropagatedAnnotations: true
//@ObjectModel.representativeKey: 'OrderOperationInternalID'

@ObjectModel.semanticKey: ['OrderInternalID', 'OrderOperationInternalID']
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #TRANSACTIONAL}
@VDM.viewType: #BASIC
define view I_ProcOrdMgmtOpBasic
  as select from P_ProcOrdMgmtOpBasic as afvg
  association [1..1] to I_OrderInternalID as _OrderInternalID on $projection.OrderInternalID = _OrderInternalID.OrderInternalID
  association [1..1] to I_UnitOfMeasure   as _OperationUnit   on $projection.OperationUnit = _OperationUnit.UnitOfMeasure
{
      @ObjectModel.foreignKey.association: '_OrderInternalID'
  key afvg.aufpl    as OrderInternalID,
  key afvg.aplzl    as OrderOperationInternalID,

      ProcessOrder,
      ManufacturingOrderCategory,
      ProductionPlant,
      ProductionSupervisor,

      // Semantic key

      afvg.aplfl    as Sequence,
      afvg.vornr    as Operation,

      // BOO data

      afvg.plnfl    as BillOfOperationsSequence,
      afvg.plnty    as BillOfOperationsType,
      afvg.plnnr    as BillOfOperationsGroup,
      afvg.plnal    as BillOfOperationsVariant,
      afvg.plnkn    as BOOOperationInternalID,
      afvg.tl_versn as BillOfOperationsVersion,

      // BOM data

      afvg.istty    as BillOfMaterialCategory,
      afvg.istnr    as BillOfMaterialInternalID,
      afvg.istkn    as BillOfMaterialItemNodeNumber,
      afvg.istpo    as BOMItemNodeCount,

      // Assignments

      afvg.sumnr    as SuperiorOperationInternalID,
      afvg.arbid    as WorkCenterInternalID,
      afvg.werks    as Plant,

      afvg.objnr    as ObjectInternalID,
      @Semantics.text: true
      afvg.ltxa1    as OperationText,
      afvg.txtsp    as Language,
      // PP-PI data

      afvg.pvzkn    as OrderIntBillOfOpItemOfPhase,
      afvg.phflg    as MfgOrderOperationIsPhase,

      // Operation Unit

      @Semantics.unitOfMeasure: true
      afvg.meinh    as OperationUnit,

      // Quantities

      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      afvg.mgvrg    as OpPlannedTotalQuantity,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      afvg.asvrg    as OpPlannedScrapQuantity,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      afvg.lmnga    as OpTotalConfirmedYieldQty,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      afvg.xmnga    as OpTotalConfirmedScrapQty,

      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      OpPlannedYieldQuantity,

      afvg.fsedd    as OpErlstSchedldExecEndDte,
      afvg.fsedz    as OpErlstSchedldExecEndTme,
      afvg.ssavd    as OpLtstSchedldExecStrtDte,
      afvg.ssavz    as OpLtstSchedldExecStrtTme,
      afvg.ssedd    as OpLtstSchedldExecEndDte,
      afvg.ssedz    as OpLtstSchedldExecEndTme,
      afvg.isdd     as OpActualExecutionStartDate,
      afvg.isdz     as OpActualExecutionStartTime,
      afvg.iedd     as OpActualExecutionEndDate,
      afvg.iedz     as OpActualExecutionEndTime,

      @Semantics.booleanIndicator: true
      case when ( afvg.lmnga < OpPlannedYieldQuantity )
           then 'X'
           else ''
           end      as ProcOrdOpHasQuantityIssue,

      @Semantics.booleanIndicator: true
      case
      when ( afvg.xmnga > afvg.asvrg)
      then 'X'
      else ''
      end           as ProcOrdOpHasQualityIssue,

      // Associations

      _OrderInternalID,
      _OperationUnit
}
where
      ManufacturingOrderCategory = '40'
  and afvg.sumnr                 is initial //SuperiorOperationInternalID

  and afvg.aplfl                 = '000000' //Sequence

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_PROCORDMGMTOPBASIC"
],
"ASSOCIATED":
[
"I_ORDERINTERNALID",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/