I_PRICECHANGEDOCUMENTITEM

CDS View

Material Ledger Document Item Details

I_PRICECHANGEDOCUMENTITEM is a CDS View in S/4HANA. Material Ledger Document Item Details. It contains 2 fields. 3 CDS views read from this table.

Used by 3 CDS view(s) 2 fields

CDS Views using this table (3)

ViewTypeJoinVDMDescription
P_MaterialLedgerDocAggregation view_entity from COMPOSITE Aggregated data for the ML document
P_MaterialLedgerDocItmPrevMnth view_entity from COMPOSITE Document Items from the previous month
P_MatlLdgrDocItmExceptPrevMnth view_entity from COMPOSITE Document Items for the current month

Fields (2)

KeyField CDS FieldsUsed in Views
KEY MaterialLedgerDocument MaterialLedgerDocument 1
KEY MaterialLedgerDocumentYear MaterialLedgerDocumentYear 1 
@AbapCatalog.sqlViewName: 'IPRCHGDOCITEM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Material Ledger Document Item Details'
define view I_PriceChangeDocumentItem
  as select from           I_MatlLdgrDocumentItemPrice    as Price
    left outer to one join I_MatlLdgrDocItemDimension     as Dimension   on  Price.MaterialLedgerDocument     = Dimension.MaterialLedgerDocument
                                                                         and Price.MaterialLedgerDocumentYear = Dimension.MaterialLedgerDocumentYear
                                                                         and Price.DocumentItemNumber         = Dimension.DocumentItemNumber

    left outer to one join I_MatlLdgrDocumentItemQuantity as Quantity    on  Price.MaterialLedgerDocument     = Quantity.MaterialLedgerDocument
                                                                         and Price.MaterialLedgerDocumentYear = Quantity.MaterialLedgerDocumentYear
                                                                         and Price.DocumentItemNumber         = Quantity.PriceChangeDocumentItem

    left outer to one join I_MatlLdgrDocumentItemValue    as Value       on  Price.MaterialLedgerDocument     = Value.MaterialLedgerDocument
                                                                         and Price.MaterialLedgerDocumentYear = Value.MaterialLedgerDocumentYear
                                                                         and Price.DocumentItemNumber         = Value.DocumentItemNumber
                                                                         and Price.FiscalYear                 = Value.FiscalYear
                                                                         and Price.FiscalPeriod               = Value.FiscalPeriod
                                                                         and Price.Ledger                     = Value.Ledger
                                                                         and Price.CurrencyRole               = Value.CurrencyRole

    left outer to one join I_PrChgDocItemRevaluation      as Revaluation on  Price.MaterialLedgerDocument     = Revaluation.MaterialLedgerDocument
                                                                         and Price.MaterialLedgerDocumentYear = Revaluation.MaterialLedgerDocumentYear
                                                                         and Price.DocumentItemNumber         = Revaluation.DocumentItemNumber
                                                                         and Price.FiscalYear                 = Revaluation.FiscalYear
                                                                         and Price.FiscalPeriod               = Revaluation.FiscalPeriod
                                                                         and Price.Ledger                     = Revaluation.Ledger
                                                                         and Price.CurrencyRole               = Revaluation.CurrencyRole

{
  key Dimension.MaterialLedgerDocument,
  key Dimension.MaterialLedgerDocumentYear,
  key Dimension.DocumentItemNumber,
  key Price.Ledger,
  key Price.CurrencyRole,
  key Price.FiscalYear,
  key Price.FiscalPeriod,

      Dimension.CompanyCode,
      Dimension.ValuationArea,
      Dimension.ProdCostEstNumber,
      Dimension.SourceDocumentItem,
      Dimension.Product,
      Dimension.ValuationType,
      Dimension.MaterialBaseUnit,
      Dimension.Division,
      Dimension.BusinessArea,
      Dimension.ValuationAreaGroup,
      Dimension.ChartOfAccounts,
      Dimension.PriceDeterminationControl,
      Dimension.MaterialLedgerItemType,
      Dimension.MaterialLedgerUpdateStructure,
      Dimension.MaterialLedgerProcessType,
      Dimension.SalesDocument,
      Dimension.SalesDocumentItem,
      Dimension.InventorySpecialStockSupplier,
      Dimension.InvtryValnSpecialStockType,
      Dimension.WBSElementInternalID,

      // Quantities

      Quantity.PostingDate,
      Quantity.MaterialLedgerPeriodType,
      Quantity.PreviousInventoryQuantity,
      Quantity.ValuationClass,

      // Prices

      Price.InventoryPrice,
      Price.MovingAveragePrice,
      Price.StandardPrice,
      Price.ProductPriceControl,
      Price.MaterialPriceUnitQty,
      Price.PriceChangeCause,

      //Values

      Value.Currency,
      Value.PreviousProductPriceControl,
      Value.PreviousStandardPrice,
      Value.PreviousMovingAveragePrice,
      Value.PreviousInventoryPrice,
      Value.InventoryAmountChangeAmount,
      Value.PrevInvtryPriceInventoryAmount,
      Value.MvgAvgPrInvtryAmtChangeAmount,
      Value.PrevMvgAvgPriceInventoryAmount,
      Value.PreviousMaterialPriceUnitQty,

      // Revaluation

      Revaluation.MatlLdgrPriceRevaluationAmount,
      Revaluation.MatlLdgrExchRateRevalAmount

}

where
  Dimension.MaterialLedgerItemType = 'PC'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATLLDGRDOCITEMDIMENSION",
"I_MATLLDGRDOCUMENTITEMPRICE",
"I_MATLLDGRDOCUMENTITEMQUANTITY",
"I_MATLLDGRDOCUMENTITEMVALUE",
"I_PRCHGDOCITEMREVALUATION"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More