I_PARKEDRECEIVABLESITEM

@AbapCatalog.sqlViewName: 'IFIPARKEDARITEM'
@AbapCatalog.compiler.compareFilter:true
@AbapCatalog.preserveKey:true
@Analytics: { dataCategory: #FACT }
@VDM.viewType: #BASIC
@EndUserText.label: 'Parked Receivables Item'
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@VDM.lifecycle.status: #DEPRECATED       
@VDM.lifecycle.successor: 'I_ParkedOplAcctgDocRblsItem'  

define view I_ParkedReceivablesItem
  as select from vbsegd
    inner join   vbkpf as _header on  vbsegd.belnr = _header.belnr
                                  and vbsegd.ausbk = _header.ausbk
                                  and vbsegd.gjahr = _header.gjahr
                                  and vbsegd.bukrs = _header.bukrs

  association [0..1] to I_CompanyCode               as _CompanyCode               on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_PostingKey                as _PostingKey                on  $projection.PostingKey = _PostingKey.PostingKey
  association [0..1] to I_DebitCreditCode           as _DebitCreditCode           on  $projection.DebitCreditCode = _DebitCreditCode.DebitCreditCode
  association [0..1] to I_BusinessArea              as _BusinessArea              on  $projection.BusinessArea = _BusinessArea.BusinessArea
  association [0..1] to I_BusinessArea              as _PartnerBusinessArea       on  $projection.PartnerBusinessArea = _PartnerBusinessArea.BusinessArea
  association [0..1] to I_FinancialTransactionType  as _FinancialTransactionType  on  $projection.FinancialTransactionType = _FinancialTransactionType.FinancialTransactionType
  association [0..1] to I_GLAccount                 as _GLAccount                 on  $projection.GLAccount   = _GLAccount.GLAccount // for field HKONT

                                                                                  and $projection.CompanyCode = _GLAccount.CompanyCode

  association [0..1] to I_PaymentBlockingReason     as _PaymentBlockingReason     on  $projection.PaymentBlockingReason = _PaymentBlockingReason.PaymentBlockingReason
  association [0..1] to I_Country                   as _SupplyingCountry          on  $projection.SupplyingCountry = _SupplyingCountry.Country
  association [0..1] to I_DunningBlockingReasonCode as _DunningBlockingReasonCode on  $projection.DunningBlockingReason = _DunningBlockingReasonCode.DunningBlockingReason
  association [0..1] to I_DunningArea               as _DunningArea               on  $projection.CompanyCode = _DunningArea.CompanyCode
                                                                                  and $projection.DunningArea = _DunningArea.DunningArea

  association [0..1] to I_PaymentDifferenceReason   as _PaymentDiffReason         on  $projection.PaymentDifferenceReason = _PaymentDiffReason.PaymentDifferenceReason
                                                                                  and $projection.CompanyCode             = _PaymentDiffReason.CompanyCode
  association [0..1] to I_CreditControlArea         as _CreditControlArea         on  $projection.CreditControlArea = _CreditControlArea.CreditControlArea

  association [0..1] to I_Currency                  as _PaymentCurrency           on  $projection.PaymentCurrency = _PaymentCurrency.Currency
  association [0..1] to I_Currency                  as _Currency                  on  $projection.TransactionCurrency = _Currency.Currency
  association [0..1] to I_Currency                  as _CompanyCodeCurrency       on  $projection.CompanyCodeCurrency = _CompanyCode.Currency


{

      //key vbsegd.ausbk as SourceCompanyCode,

  key cast( vbsegd.belnr as farp_belnr_d preserving type )  as  AccountingDocument,
  key cast( vbsegd.gjahr as fis_gjahr preserving type )     as  FiscalYear,
      //key vbsegd.bzkey as ParkedAccountingDocumentItem,

  key cast( vbsegd.buzei as farp_buzei preserving type )    as  AccountingDocumentItem,
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key cast( vbsegd.bukrs as fis_bukrs preserving type )     as  CompanyCode,
      cast( bschl as farp_bschl preserving type )           as  PostingKey,
      cast(umskz as fac_umskz preserving type )             as  SpecialGLCode,
      cast(umsks as farp_umsks preserving type )            as  SpecialGLTransactionType,
      //  XNEGP is not exposed any longer since it is applied to SHKZG already here

      // cast( xnegp as farp_xnegp )         as IsNegativePosting, 

      //  write corrected SHKZG to DebitCreditCode but use original SHKZG to derive signs of amounts

      case xnegp when 'X' then case shkzg when 'S' then 'H'
                                          when 'H' then 'S'
                                          else ''
                          end
                 else shkzg
      end                                                   as  DebitCreditCode,
      cast(gsber as fis_rbusa preserving type )             as  BusinessArea,
      cast(vbsegd.pargb as fis_pargb preserving type )      as  PartnerBusinessArea,
      cast(mwskz as farp_mwskz preserving type )            as  TaxCode,
      tax_country                                           as  TaxCountry,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      case shkzg  when 'H' then   cast( cast(-dmbtr as abap.curr(23, 2)) as dmbtr_farp)
                  when 'S' then   cast( cast( dmbtr as abap.curr(23, 2)) as dmbtr_farp)
                  else cast( cast(dmbtr as abap.curr(23, 2)) as dmbtr_farp)
      end                                                   as  AmountInCompanyCodeCurrency,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      case shkzg  when 'H' then   cast(-wrbtr as abap.curr( 23,2))
                  when 'S' then   cast( wrbtr as abap.curr( 23,2))
                  else cast( wrbtr as abap.curr( 23,2))
      end                                                   as  AmountInTransactionCurrency,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      case shkzg  when 'H' then   cast(-mwsts as abap.curr( 23,2))
                  when 'S' then   cast( mwsts as abap.curr( 23,2))
                  else cast( mwsts as abap.curr( 23,2))
      end                                                   as  TaxAmountInCoCodeCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      case shkzg  when 'H' then   cast(-wmwst as abap.curr( 23,2))
                  when 'S' then   cast( wmwst as abap.curr( 23,2))
                  else cast( wmwst as abap.curr( 23,2))
      end                                                   as  TaxAmount,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      case shkzg  when 'H' then   cast(-fwbas as abap.curr( 23,2))
                  when 'S' then   cast( fwbas as abap.curr( 23,2))
                  else cast( fwbas as abap.curr( 23,2))
      end                                                   as  TaxBaseAmountInTransCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      case shkzg  when 'H' then   cast(-hwbas as abap.curr( 23,2))
                  when 'S' then   cast( hwbas as abap.curr( 23,2))
                  else cast( hwbas as abap.curr( 23,2))
      end                                                   as  TaxBaseAmountInCoCodeCrcy,
      mwart                                                 as  TaxType,
      valut                                                 as  ValueDate,
      cast(zuonr as fis_zuonr preserving type )             as  AssignmentReference,
      cast(sgtxt as farp_sgtxt )                            as  DocumentItemText,
      cast(bewar as fis_rmvct preserving type )             as  FinancialTransactionType,
      fdlev                                                 as  PlanningLevel,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      case shkzg  when 'H' then   cast(-fdwbt as abap.curr( 23,2))
                  when 'S' then   cast( fdwbt as abap.curr( 23,2))
                  else cast( fdwbt as abap.curr( 23,2))
      end                                                   as  PlannedAmtInTransactionCrcy,
      cast(anbwa as fac_anbwa preserving type )             as  AssetTransactionType,
      cast(xumsw as farp_xumsw)                             as  IsSalesRelated,
      cast(hkont as fis_racct preserving type )             as  GLAccount,
      cast(kunnr as fis_kunnr preserving type )             as  Debtor,
      cast(filkd as farp_filkd preserving type )            as  BranchAccount,
      cast(hzuon as hzuon preserving type )                 as  SpecialGLAccountAssignment,
      zfbdt                                                 as  DueCalculationBaseDate,
      cast(zterm as farp_dzterm preserving type )           as  PaymentTerms,
      cast(zbd1t as farp_dzbd1t preserving type )           as  CashDiscount1Days,
      cast(zbd2t as farp_dzbd2t preserving type )           as  CashDiscount2Days,
      cast(zbd3t as farp_dzbd3t preserving type )           as  NetPaymentDays,
      zbd1p                                                 as  CashDiscount1Percent,
      zbd2p                                                 as  CashDiscount2Percent,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      case shkzg  when 'H' then   cast(-skfbt as abap.curr( 23,2))
                  when 'S' then   cast( skfbt as abap.curr( 23,2))
                  else cast( skfbt as abap.curr( 23,2))
      end                                                   as  CashDiscountBaseAmount,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      case shkzg  when 'H' then   cast(-sknto as abap.curr( 23,2))
                  when 'S' then   cast( sknto as abap.curr( 23,2))
                  else cast( sknto as abap.curr( 23,2))
      end                                                   as  CashDiscountAmtInCoCodeCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      case shkzg  when 'H' then   cast(-wskto as abap.curr( 23,2))
                  when 'S' then   cast( wskto as abap.curr( 23,2))
                  else cast( wskto as abap.curr( 23,2))
      end                                                   as  CashDiscountAmount,
      cast(zlsch as farp_schzw_bseg preserving type )       as  PaymentMethod,
      cast(zlspr as farp_dzlspr preserving type )           as  PaymentBlockingReason,
      cast(hbkid as farp_hbkid preserving type )            as  HouseBank,
      cast(rebzg as farp_rebzg preserving type )            as  InvoiceReference,
      cast(rebzj as fis_rebzj preserving type )             as  InvoiceReferenceFiscalYear,
      cast(rebzz as fis_rebzz preserving type )             as  InvoiceItemReference,
      cast(rebzt as farp_rebzt preserving type )            as  FollowOnDocumentType,
      cast( lzbkz as fac_lzbkz preserving type )            as  StateCentralBankPaymentReason,
      cast(landl as fac_landl preserving type )             as  SupplyingCountry,
      cast(samnr as farp_samnr preserving type )            as  InvoiceList,
      cast(mschl as farp_mschl preserving type )            as  DunningKey,
      cast(mansp as farp_mansp preserving type )            as  DunningBlockingReason,
      cast(madat as farp_madat preserving type )            as  LastDunningDate,
      cast(manst as farp_mahns_d preserving type )          as  DunningLevel,
      cast(maber as farp_maber preserving type )            as  DunningArea,
      cast(stceg as farp_stceg preserving type )            as  VATRegistration,
      cast(rstgr as farp_rstgr preserving type )            as  PaymentDifferenceReason,
      vname                                                 as  JointVenture,
      egrup                                                 as  JointVentureEquityGroup,
      vertt                                                 as  TreasuryContractType,
      vertn                                                 as  AssetContract,
      cast(vbewa as farp_sbewart preserving type )          as  CashFlowType,
      cast(fipos as fis_fipos_shortid preserving type )     as  CommitmentItemShortID,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'AdditionalCurrency1'
      case shkzg  when 'H' then   cast( cast(-dmbe2 as abap.curr(23, 2)) as dmbe2_farp)
                  when 'S' then   cast( cast( dmbe2 as abap.curr(23, 2)) as dmbe2_farp)
                  else cast( cast( dmbe2 as abap.curr(23, 2)) as dmbe2_farp)
      end                                                   as  AmountInAdditionalCurrency1,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'AdditionalCurrency2'
      case shkzg  when 'H' then   cast( cast(-dmbe3 as abap.curr(23, 2)) as dmbe3_farp)
                  when 'S' then   cast( cast( dmbe3 as abap.curr(23, 2)) as dmbe3_farp)
                  else cast( cast( dmbe3 as abap.curr(23, 2)) as dmbe3_farp)
      end                                                   as  AmountInAdditionalCurrency2,
      cast( uzawe as farp_uzawe preserving type )           as  PaymentMethodSupplement,
      cast( fistl as farp_fistl preserving type )           as  FundsCenter,
      geber                                                 as  Fund,
      cast( xref1 as farp_xref1)                            as  Reference1IDByBusinessPartner,
      cast( xref2 as farp_xref2)                            as  Reference2IDByBusinessPartner,

      //  XNEGP is not exposed any longer since it is applied to SHKZG already here

      //  cast(xnegp as FARP_XNEGP) as IsNegativePosting,


      cast( kkber as farp_kkber preserving type )           as  CreditControlArea,
      xref3                                                 as  Reference3IDByBusinessPartner,
      cast( dtws1 as farp_dtat16)                           as  DataExchangeInstruction1,
      cast( dtws2 as farp_dtat17)                           as  DataExchangeInstruction2,
      cast( dtws3 as farp_dtat18)                           as  DataExchangeInstruction3,
      cast( dtws4 as farp_dtat19)                           as  DataExchangeInstruction4,
      empfb                                                 as  AlternativePayeePayer,
      cast( kidno as farp_kidno)                            as  PaymentReference,
      @Semantics.currencyCode: true
      cast(  pycur as farp_pycur preserving type )          as  PaymentCurrency,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'PaymentCurrency'
      case shkzg  when 'H' then   cast( cast(-pyamt as abap.curr( 23,2)) as pyamt_farp)
                  when 'S' then   cast( cast( pyamt as abap.curr( 23,2)) as pyamt_farp)
                  else cast( cast( pyamt as abap.curr( 23,2)) as pyamt_farp)
      end                                                   as  AmountInPaymentCurrency,
      cast( bupla as farp_bupla preserving type )           as  BusinessPlace,
      secco                                                 as  TaxSection,
      grant_nbr                                             as  GrantID,
      fkber                                                 as  FunctionalArea,
      cast(gmvkz as gmvkzd)                                 as  CustomerIsInExecution,
      hktid                                                 as  HouseBankAccount,
      cast(  netdt as farp_netdt preserving type )          as  NetDueDate,
      cast( sk1dt as farp_sk1dt preserving type )           as  CashDiscount1DueDate,
      sk2dt                                                 as  CashDiscount2DueDate,
      j_1tpbupl                                             as  BranchCode,
      budget_pd                                             as  BudgetPeriod,
      bvtyp                                                 as  BPBankAccountInternalID,
      _header.usnam                                         as  AccountingDocCreatedByUser,
      _header.vatdate                                       as  TaxReportingDate,
      @Semantics.currencyCode: true
      _header.waers                                         as  TransactionCurrency,
      @Semantics.currencyCode: true
      cast( _header.hwaer as farp_hwaer preserving type )   as  CompanyCodeCurrency,
      @Semantics.currencyCode:true
      cast( _header.hwae2 as fis_hwae2 preserving type )    as  AdditionalCurrency1,
      @Semantics.currencyCode:true
      cast( _header.hwae3 as fis_hwae3 preserving type )    as  AdditionalCurrency2,
      cast( _header.awtyp as fis_awtyp )                    as  ReferenceDocumentType,
      cast( _header.awkey as fac_awkey )                    as  OriginalReferenceDocument,
      cast( _header.awsys as fis_awsys )                    as  ReferenceDocumentLogicalSystem,
      payt_rsn                                              as PaymentReason,
      _CompanyCode,
      _PostingKey,
      _DebitCreditCode,
      _BusinessArea,
      _PartnerBusinessArea,
      _FinancialTransactionType,
      _GLAccount,
      _PaymentBlockingReason,
      _SupplyingCountry,
      _DunningBlockingReasonCode,
      _DunningArea,
      _Currency

};                                                             
  
  
  
  
  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"VBKPF",
"VBSEGD"
],
"ASSOCIATED":
[
"I_BUSINESSAREA",
"I_COMPANYCODE",
"I_COUNTRY",
"I_CREDITCONTROLAREA",
"I_CURRENCY",
"I_DEBITCREDITCODE",
"I_DUNNINGAREA",
"I_DUNNINGBLOCKINGREASONCODE",
"I_FINANCIALTRANSACTIONTYPE",
"I_GLACCOUNT",
"I_PAYMENTBLOCKINGREASON",
"I_PAYMENTDIFFERENCEREASON",
"I_POSTINGKEY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/