I_PRODUCTIONMODEL

CDS View

Production Model Header

I_PRODUCTIONMODEL is a CDS View in S/4HANA. Production Model Header. It contains 12 fields. 8 CDS views read from this table.

Used by 8 CDS view(s) 12 fields

CDS Views using this table (8)

ViewTypeJoinVDMDescription
I_ProdnModelComponentInstance view_entity inner COMPOSITE Production Model Component Instance
I_ProdnModOpActyCompInstance view_entity inner COMPOSITE Prodn Model Op Acty Component Instance
I_ProdnModOpActyComponent view_entity inner COMPOSITE Production Model Activity Component
I_ProdnModOperationActivity view_entity inner COMPOSITE Production Model Operation Activity
I_ProdnModOperationComponent view_entity inner COMPOSITE Production Model Operation Component
I_ProductionModelComponent view_entity inner COMPOSITE Production Model Component
I_ProductionModelOperation view_entity inner COMPOSITE Production Model Operation
R_ProductionModelTP view_entity from TRANSACTIONAL Production Model Header

Fields (12)

KeyField CDS FieldsUsed in Views
KEY ProductionModelUUID ProductionModelUUID 7
BillOfMaterial BillOfMaterial 3
BillOfMaterialCategory BillOfMaterialCategory 5
BillOfMaterialVariant BillOfMaterialVariant 5
BillOfMaterialVariantUsage BillOfMaterialVariantUsage 6
BillOfMaterialVersion BillOfMaterialVersion 3
BillOfOperationsGroup BillOfOperationsGroup 6
BillOfOperationsType BillOfOperationsType 7
BillOfOperationsVariant BillOfOperationsVariant 6
BillOfOperationsVersion BillOfOperationsVersion 4
Material Material 3
Plant Plant 6 
@EndUserText.label: 'Production Model Header'
@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType: #COMPOSITE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
define view entity I_ProductionModel
  as select from I_ProductionModelBasic     as ProductionModel
    inner join   P_ProdnModLatestBOOVersion as BooLatestVersion    on  BooLatestVersion.BillOfOperationsType    = ProductionModel.BillOfOperationsType
                                                                   and BooLatestVersion.BillOfOperationsGroup   = ProductionModel.BillOfOperationsGroup
                                                                   and BooLatestVersion.BillOfOperationsVariant = ProductionModel.BillOfOperationsVariant
    inner join   I_BOOVersionBOMAssignment  as BooVersionBOMAssgmt on  BooVersionBOMAssgmt.BillOfOperationsType    = ProductionModel.BillOfOperationsType
                                                                   and BooVersionBOMAssgmt.BillOfOperationsGroup   = ProductionModel.BillOfOperationsGroup
                                                                   and BooVersionBOMAssgmt.BillOfOperationsVariant = ProductionModel.BillOfOperationsVariant
                                                                   and BooVersionBOMAssgmt.BillOfOperationsVersion = BooLatestVersion.BillOfOperationsVersion
  association [0..*] to I_ProductionModelComponent as _HeaderComponent       on  $projection.ProductionModelUUID = _HeaderComponent.ProductionModelUUID
  association [0..*] to I_ProductionModelOperation as _Operation             on  $projection.ProductionModelUUID = _Operation.ProductionModelUUID
  association [0..1] to I_Plant                    as _Plant                 on  $projection.Plant = _Plant.Plant
                                                                             and _Plant.Language   = $session.system_language
  association [0..1] to I_MaterialText             as _MaterialText          on  $projection.Material   = _MaterialText.Material
                                                                             and _MaterialText.Language = $session.system_language
  association [0..1] to I_BOOVersionStatusText     as _BOOVersionStatusText  on  $projection.billofoperationsversionstatus = _BOOVersionStatusText.BillOfOperationsVersionStatus
                                                                             and _BOOVersionStatusText.Language            = $session.system_language
  association [0..1] to I_BillOfMaterialUsage      as _BOMUsageText          on  $projection.BillOfMaterialVariantUsage = _BOMUsageText.BillOfMaterialVariantUsage
                                                                             and _BOMUsageText.Language                 = $session.system_language
  association [0..1] to I_BillOfOperationsTypeText as _BOOTypeText           on  $projection.BillOfOperationsType = _BOOTypeText.BillOfOperationsType
                                                                             and _BOOTypeText.Language            = $session.system_language
  association [0..1] to I_SalesDocumentItem        as _SalesDocumentItemText on  $projection.SalesOrder     = _SalesDocumentItemText.SalesDocument
                                                                             and $projection.SalesOrderItem = _SalesDocumentItemText.SalesDocumentItem
{

  key ProductionModel.ProductionModelUUID,
      ProductionModel.ProductionModelProcessType,
      ProductionModel.ProdnModComplexAssemblyType,
      ProductionModel.Material,
      ProductionModel.BillOfMaterial,
      ProductionModel.BillOfMaterialVariant,
      ProductionModel.BillOfMaterialCategory,
      ProductionModel.BillOfMaterialVariantUsage,
      BooVersionBOMAssgmt.BillOfMaterialVersion,
      ProductionModel.Plant,
      ProductionModel.BillOfOperationsType,
      ProductionModel.BillOfOperationsGroup,
      ProductionModel.BillOfOperationsVariant,
      BooVersionBOMAssgmt.BillOfOperationsVersion,
      ProductionModel.SalesOrder,
      ProductionModel.SalesOrderItem,
      @ObjectModel.text.association: '_BOOVersionStatusText'
      BooVersionBOMAssgmt._BillOfOperationsVersion.BillOfOperationsVersionStatus,
      ProductionModel.ProdnModelCreationDateTime,
      ProductionModel.ProductionModelCreatedByUser,
      ProductionModel.ProdnModelChangedDateTime,
      ProductionModel.ProductionModelChangedByUser,
      _HeaderComponent,
      _Operation,
      _Plant,
      _MaterialText,
      _BOOVersionStatusText,
      _BOMUsageText,
      _BOOTypeText,
      _SalesDocumentItemText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONSVERSION",
"I_BOOVERSIONBOMASSIGNMENT",
"I_PRODUCTIONMODELBASIC",
"P_PRODNMODLATESTBOOVERSION"
],
"ASSOCIATED":
[
"I_BILLOFMATERIALUSAGE",
"I_BILLOFOPERATIONSTYPETEXT",
"I_BOOVERSIONSTATUSTEXT",
"I_MATERIALTEXT",
"I_PLANT",
"I_PRODUCTIONMODELCOMPONENT",
"I_PRODUCTIONMODELOPERATION",
"I_SALESDOCUMENTITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More