I_ORGANIZATIONALCHANGEACTIVITY

CDS View

Organizational Change Activity

I_ORGANIZATIONALCHANGEACTIVITY is a CDS View in S/4HANA. Organizational Change Activity. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
C_OrglChangeActivityTP view_entity from CONSUMPTION Organizational Change Activity
I_OrglChangeActivityTP view_entity from TRANSACTIONAL Organizational Change Activity - TP 
@AbapCatalog.sqlViewName: 'IFINOCACTIVITY'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Organizational Change Activity'
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {
  dataClass: #TRANSACTIONAL,
  serviceQuality: #C,
  sizeCategory: #L
}
@Analytics.internalName:#LOCAL


define view I_OrganizationalChangeActivity
  as select from    finoc_activity as _Activity
    left outer join tbtco          as _ApplicationJob on  _Activity.jobname  = _ApplicationJob.jobname
                                                      and _Activity.jobcount = _ApplicationJob.jobcount
    left outer join dd07t          as _JobStatustext  on  _Activity.jobstatus       = _JobStatustext.domvalue_l
                                                      and _JobStatustext.domname    = 'APJ_STATUS'
                                                      and _JobStatustext.as4local   = 'A'
                                                      and _JobStatustext.as4vers    = '0000'
                                                      and _JobStatustext.ddlanguage = $session.system_language
    left outer join dd07t          as _Statustext     on  _ApplicationJob.status = _Statustext.domvalue_l
                                                      and _Statustext.domname    = 'APJ_STATUS'
                                                      and _Statustext.as4local   = 'A'
                                                      and _Statustext.as4vers    = '0000'
                                                      and _Statustext.ddlanguage = $session.system_language

  //  association [1]    to tbtcp                       as _Job                       on  _Activity.jobname  = _Job.jobname

  //                                                                                  and _Activity.jobcount = _Job.jobcount

  //                                                                                  and _Job.stepcount = 1

  association [0..*] to I_OrglChangeJobTypeText     as _JobTypeText               on $projection.OrganizationalChangeJobType = _JobTypeText.OrganizationalChangeJobType
  association [0..1] to I_UserContactCard           as _UserContactCard           on $projection.OrglChangeActivityProcdByUser = _UserContactCard.ContactCardID
  association [0..*] to I_OrglChangeProcgStatusText as _OrglChangeProcgStatusText on $projection.OrglChangeProcessingStatus = _OrglChangeProcgStatusText.OrglChangeProcessingStatus
  association [1]    to I_OrganizationalChange      as _OrganizationalChange      on $projection.OrganizationalChange = _OrganizationalChange.OrganizationalChange //xfm


{

  key   _Activity.activity                                     as OrganizationalChangeActivity,
  key   _Activity.orgl_change                                  as OrganizationalChange,
        _Activity.job_type                                     as OrganizationalChangeJobType,
        _Activity.jobname                                      as ApplicationJobName,
        _Activity.jobcount                                     as ApplicationJob,
        _Activity.appl_log_number                              as ApplicationLog,
        _Activity.num_wmsg                                     as NumberOfUniqueWarnings,
        _Activity.num_emsg                                     as NumberOfUniqueErrors,
        coalesce (_ApplicationJob.status, _Activity.jobstatus) as JobStatusValue,
        coalesce (_Statustext.ddtext, _JobStatustext.ddtext)   as ApplicationJobStatusText,
        _Activity.activity_timestamp                           as OrglChangeActivityDateTime,
        _Activity.triggered_by                                 as OrglChangeActivityProcdByUser,
        _Activity.status_to                                    as OrglChangeProcessingStatus,
        //        _Job.progname                                          as OrglChangeJobCatalogEntryName,

        _JobTypeText,
        _UserContactCard,
        _OrglChangeProcgStatusText,
        _OrganizationalChange

}
where
  _Activity.orgl_change != ' '
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T",
"FINOC_ACTIVITY",
"TBTCO"
],
"ASSOCIATED":
[
"I_ORGANIZATIONALCHANGE",
"I_ORGLCHANGEJOBTYPETEXT",
"I_ORGLCHANGEPROCGSTATUSTEXT",
"I_USERCONTACTCARD"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More