I_ORDERCONFMATLDOCITEMASSGMT

CDS View

Assignment Order Confirmation to Material Document Item

I_ORDERCONFMATLDOCITEMASSGMT is a CDS View in S/4HANA. Assignment Order Confirmation to Material Document Item. It contains 2 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 2 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_MfgOrderConfMatlDocItem view inner COMPOSITE Material Document Items of Mfg Order Confirmation

Fields (2)

KeyField CDS FieldsUsed in Views
KEY MaterialDocument MaterialDocument 1
_MaterialDocumentYear _MaterialDocumentYear 1 
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataCategory: #FACT
@Analytics.technicalName: 'IORDCONFMATLDOC'
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #XL, dataClass: #TRANSACTIONAL}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Assignment Order Confirmation to Material Document Item'

define view entity I_OrderConfMatlDocItemAssgmt
  as select from afwi

  association [1..1] to I_ConfirmationGroup        as _ConfirmationGroup      on  $projection.ConfirmationGroup    = _ConfirmationGroup.ConfirmationGroup
  association [1..1] to I_ConfirmationCount        as _ConfirmationCount      on  $projection.ConfirmationGroup    = _ConfirmationCount.ConfirmationGroup
                                                                              and $projection.ConfirmationCount    = _ConfirmationCount.ConfirmationCount
  association [1..1] to I_MaterialDocumentYear     as _MaterialDocumentYear   on  $projection.MaterialDocumentYear = _MaterialDocumentYear.MaterialDocumentYear
  association [1..1] to I_MaterialDocumentHeader_2 as _MaterialDocumentHeader on  $projection.MaterialDocument     = _MaterialDocumentHeader.MaterialDocument
                                                                              and $projection.MaterialDocumentYear = _MaterialDocumentHeader.MaterialDocumentYear
  association [1..1] to I_MaterialDocumentItem_2   as _MaterialDocumentItem   on  $projection.MaterialDocumentYear = _MaterialDocumentItem.MaterialDocumentYear 
                                                                              and $projection.MaterialDocument     = _MaterialDocumentItem.MaterialDocument
                                                                              and $projection.MaterialDocumentItem = _MaterialDocumentItem.MaterialDocumentItem
{
      // Key

      @ObjectModel.foreignKey.association: '_ConfirmationGroup'
  key rueck as ConfirmationGroup,
      @ObjectModel.foreignKey.association: '_ConfirmationCount'
  key rmzhl as ConfirmationCount,
      @ObjectModel.foreignKey.association: '_MaterialDocumentHeader'  
  key mblnr as MaterialDocument,
      @ObjectModel.foreignKey.association: '_MaterialDocumentYear'
  key mjahr as MaterialDocumentYear, 
      @ObjectModel.foreignKey.association: '_MaterialDocumentItem'
  key mblpo as MaterialDocumentItem,
      
      // Associations

      _ConfirmationGroup,
      _ConfirmationCount,
      _MaterialDocumentHeader,
      _MaterialDocumentItem,
      _MaterialDocumentYear
}
  where mjahr != '0000';   // only material documents

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"AFWI"
],
"ASSOCIATED":
[
"I_CONFIRMATIONCOUNT",
"I_CONFIRMATIONGROUP",
"I_MATERIALDOCUMENTHEADER_2",
"I_MATERIALDOCUMENTITEM_2",
"I_MATERIALDOCUMENTYEAR"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More