I_ORGANIZATIONADDRESS
Address of an Organization
I_ORGANIZATIONADDRESS is a CDS View in S/4HANA. Address of an Organization. It contains 86 fields. 14 CDS views read from this table.
CDS Views using this table (14)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_PurchasingDeliveryAddressVH | view | from | CONSUMPTION | Master Delivery Addresses |
| I_KanbanContainerDeliveryAddr | view | inner | BASIC | Kanban Container Delivery Address |
| I_OrgAddressDefaultRprstn | view_entity | from | COMPOSITE | Default Representation of an Org Address |
| I_ProductionSupplyAreaAddrTP | view | inner | TRANSACTIONAL | Production Supply Area Address |
| P_Address_2 | view_entity | union_all | COMPOSITE | |
| P_EG_CompanyCode_Address | view | inner | COMPOSITE | |
| P_KR_BusinessPlace | view | left_outer | COMPOSITE | |
| P_RU_CompanyCodeData | view | left_outer | COMPOSITE | |
| P_RU_CompanyCodeData_Lang | view | left_outer | COMPOSITE | |
| P_SA_CompanyCode_Address | view | inner | COMPOSITE | |
| R_BankAddressDepTP | view_entity | inner | TRANSACTIONAL | Bank Address |
| R_BankAddressTP | view_entity | left_outer | TRANSACTIONAL | Bank Address |
| R_BankScriptedAddressTP | view_entity | inner | TRANSACTIONAL | Bank Scripted Address |
| R_ProductionSupplyAreaAddrTP | view_entity | inner | TRANSACTIONAL | Production Supply Area Address - TP |
Fields (86)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | AddressID | AddressID,ProductionSupplyAreaAddressID | 6 |
| KEY | AddressRepresentationCode | AddressRepresentationCode | 5 |
| _AddressGroup | _AddressGroup | 1 | |
| _AddressObjectType | _AddressObjectType | 2 | |
| _AddressPersonName | _AddressPersonName | 2 | |
| _AddressRepresentationCode | _AddressRepresentationCode | 5 | |
| _CorrespondenceLanguage | _CorrespondenceLanguage | 4 | |
| _Country | _Country | 5 | |
| _CurrentDfltEmailAddress | _CurrentDfltEmailAddress | 2 | |
| _CurrentDfltFaxNumber | _CurrentDfltFaxNumber | 2 | |
| _CurrentDfltLandlinePhoneNmbr | _CurrentDfltLandlinePhoneNmbr | 2 | |
| _CurrentDfltMobilePhoneNumber | _CurrentDfltMobilePhoneNumber | 2 | |
| _DeliveryServiceTypeCode | _DeliveryServiceTypeCode | 2 | |
| _EmailAddress | _EmailAddress | 2 | |
| _FaxNumber | _FaxNumber | 2 | |
| _FormOfAddress | _FormOfAddress | 4 | |
| _MainWebsiteURL | _MainWebsiteURL | 2 | |
| _PhoneNumber | _PhoneNumber | 2 | |
| _POBoxAddrNonDeliverableReason | _POBoxAddrNonDeliverableReason | 2 | |
| _POBoxDeviatingCityCode | _POBoxDeviatingCityCode | 1 | |
| _POBoxDeviatingCountry | _POBoxDeviatingCountry | 2 | |
| _POBoxDeviatingRegion | _POBoxDeviatingRegion | 2 | |
| _PostalCity | _PostalCity | 1 | |
| _PrfrdCommMediumType | _PrfrdCommMediumType | 2 | |
| _Region | _Region | 4 | |
| _RegionalStructureCheckStatus | _RegionalStructureCheckStatus | 1 | |
| _SecondaryRegion | _SecondaryRegion | 1 | |
| _Street | _Street | 1 | |
| _StreetAddrNonDeliverableRsn | _StreetAddrNonDeliverableRsn | 2 | |
| _TertiaryRegion | _TertiaryRegion | 1 | |
| _TimeZone | _TimeZone | 2 | |
| _TransportationZone | _TransportationZone | 2 | |
| _UniformResourceIdentifier | _UniformResourceIdentifier | 2 | |
| AddresseeFullName | AddresseeFullName | 5 | |
| AddresseeName1 | AddresseeName1 | 4 | |
| AddresseeName2 | AddresseeName2 | 4 | |
| AddresseeName3 | AddresseeName3 | 2 | |
| AddresseeName4 | AddresseeName4 | 2 | |
| AddressGroup | AddressGroup | 2 | |
| AddressObjectType | AddressObjectType | 4 | |
| AddressPersonID | AddressPersonID | 3 | |
| AddressSearchTerm1 | AddressSearchTerm1 | 4 | |
| AddressSearchTerm2 | AddressSearchTerm2 | 4 | |
| AddressTimeZone | AddressTimeZone | 4 | |
| Building | Building | 5 | |
| CareOfName | CareOfName | 4 | |
| CityName | CityName | 7 | |
| CityNumber | CityNumber | 1 | |
| CompanyPostalCode | CompanyPostalCode | 4 | |
| CorrespondenceLanguage | CorrespondenceLanguage | 4 | |
| Country | Country | 8 | |
| DeliveryServiceNumber | DeliveryServiceNumber | 4 | |
| DeliveryServiceTypeCode | DeliveryServiceTypeCode | 4 | |
| DistrictName | DistrictName | 4 | |
| Floor | Floor | 4 | |
| FormOfAddress | FormOfAddress | 4 | |
| HouseNumber | HouseNumber | 8 | |
| HouseNumberSupplementText | HouseNumberSupplementText | 4 | |
| POBox | POBox | 6 | |
| POBoxAddrNonDeliverableReason | POBoxAddrNonDeliverableReason | 4 | |
| POBoxDeviatingCityCode | POBoxDeviatingCityCode | 1 | |
| POBoxDeviatingCityName | POBoxDeviatingCityName | 4 | |
| POBoxDeviatingCountry | POBoxDeviatingCountry | 4 | |
| POBoxDeviatingRegion | POBoxDeviatingRegion | 4 | |
| POBoxIsWithoutNumber | POBoxIsWithoutNumber | 4 | |
| POBoxLobbyName | POBoxLobbyName | 4 | |
| POBoxPostalCode | POBoxPostalCode | 4 | |
| PostalCode | PostalCode | 6 | |
| PrfrdCommMediumType | PrfrdCommMediumType | 4 | |
| Region | Region | 7 | |
| RegionalStructureCheckStatus | RegionalStructureCheckStatus | 1 | |
| RoomNumber | RoomNumber | 4 | |
| SecondaryRegion | SecondaryRegion | 1 | |
| SecondaryRegionName | SecondaryRegionName | 4 | |
| Street | Street | 1 | |
| StreetAddrNonDeliverableReason | StreetAddrNonDeliverableReason | 4 | |
| StreetName | StreetName | 7 | |
| StreetPrefixName1 | StreetPrefixName1 | 5 | |
| StreetPrefixName2 | StreetPrefixName2 | 5 | |
| StreetSuffixName1 | StreetSuffixName1 | 5 | |
| StreetSuffixName2 | StreetSuffixName2 | 5 | |
| TaxJurisdiction | TaxJurisdiction | 4 | |
| TertiaryRegion | TertiaryRegion | 1 | |
| TertiaryRegionName | TertiaryRegionName | 4 | |
| TransportZone | TransportZone | 4 | |
| VillageName | VillageName | 4 |
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@Analytics : {
dataCategory: #DIMENSION,
dataExtraction: {
enabled: true }
}
@AccessControl.privilegedAssociations: ['_EmailAddress', '_CurrentDfltEmailAddress', '_PhoneNumber', '_CurrentDfltLandlinePhoneNmbr', '_CurrentDfltMobilePhoneNumber', '_FaxNumber', '_CurrentDfltFaxNumber', '_UniformResourceIdentifier', '_MainWebsiteURL']
@EndUserText.label: 'Address of an Organization'
//@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE,
#EXTRACTION_DATA_SOURCE]
@ObjectModel.representativeKey: 'AddressID'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MIXED
@VDM: {
viewType: #BASIC,
lifecycle.contract.type: #PUBLIC_LOCAL_API
}
define view entity I_OrganizationAddress
as select from I_AddrOrgNamePostalAddress
association [0..*] to I_AddressEmailAddress_2 as _EmailAddress on _EmailAddress.AddressID = $projection.AddressID
and _EmailAddress.AddressPersonID = $projection.AddressPersonID
association [0..1] to I_AddrCurDefaultEmailAddress as _CurrentDfltEmailAddress on _CurrentDfltEmailAddress.AddressID = $projection.AddressID
and _CurrentDfltEmailAddress.AddressPersonID = $projection.AddressPersonID
association [0..*] to I_AddressPhoneNumber_2 as _PhoneNumber on _PhoneNumber.AddressID = $projection.AddressID
and _PhoneNumber.AddressPersonID = $projection.AddressPersonID
association [0..1] to I_AddrCurDfltLandlinePhoneNmbr as _CurrentDfltLandlinePhoneNmbr on _CurrentDfltLandlinePhoneNmbr.AddressID = $projection.AddressID
and _CurrentDfltLandlinePhoneNmbr.AddressPersonID = $projection.AddressPersonID
association [0..1] to I_AddrCurDfltMobilePhoneNumber as _CurrentDfltMobilePhoneNumber on _CurrentDfltMobilePhoneNumber.AddressID = $projection.AddressID
and _CurrentDfltMobilePhoneNumber.AddressPersonID = $projection.AddressPersonID
association [0..*] to I_AddressFaxNumber_2 as _FaxNumber on _FaxNumber.AddressID = $projection.AddressID
and _FaxNumber.AddressPersonID = $projection.AddressPersonID
association [0..1] to I_AddrCurDefaultFaxNumber as _CurrentDfltFaxNumber on _CurrentDfltFaxNumber.AddressID = $projection.AddressID
and _CurrentDfltFaxNumber.AddressPersonID = $projection.AddressPersonID
association [0..*] to I_AddressURI as _UniformResourceIdentifier on _UniformResourceIdentifier.AddressID = $projection.AddressID
and _UniformResourceIdentifier.AddressPersonID = $projection.AddressPersonID
association [0..1] to I_AddressMainWebsiteURL as _MainWebsiteURL on _MainWebsiteURL.AddressID = $projection.AddressID
and _MainWebsiteURL.AddressPersonID = $projection.AddressPersonID
association [0..1] to I_Region as _Region on $projection.Region = _Region.Region
and $projection.Country = _Region.Country
association [0..1] to I_Country as _Country on $projection.Country = _Country.Country
association [0..1] to I_FormOfAddress as _FormOfAddress on $projection.FormOfAddress = _FormOfAddress.FormOfAddress
association [0..1] to I_AddressNonDeliverableReason as _POBoxAddrNonDeliverableReason on $projection.POBoxAddrNonDeliverableReason = _POBoxAddrNonDeliverableReason.AddressNonDeliverableReason
association [0..1] to I_AddressNonDeliverableReason as _StreetAddrNonDeliverableRsn on $projection.StreetAddrNonDeliverableReason = _StreetAddrNonDeliverableRsn.AddressNonDeliverableReason
association [0..1] to I_TransportationZone as _TransportationZone on $projection.TransportZone = _TransportationZone.TransportZone
and $projection.Country = _TransportationZone.CountryCode
association [0..1] to I_Region as _POBoxDeviatingRegion on $projection.POBoxDeviatingRegion = _POBoxDeviatingRegion.Region
and $projection.POBoxDeviatingCountry = _POBoxDeviatingRegion.Country
association [0..1] to I_Country as _POBoxDeviatingCountry on $projection.POBoxDeviatingCountry = _POBoxDeviatingCountry.Country
association [0..1] to I_AddressCommunicationMethod as _PrfrdCommMediumType on $projection.PrfrdCommMediumType = _PrfrdCommMediumType.CommunicationMediumType
association [0..1] to I_AddressDeliveryServiceType as _DeliveryServiceTypeCode on $projection.DeliveryServiceTypeCode = _DeliveryServiceTypeCode.DeliveryServiceTypeCode
association [0..1] to I_Language as _CorrespondenceLanguage on $projection.CorrespondenceLanguage = _CorrespondenceLanguage.Language
association [0..1] to I_AddressRepresentation as _AddressRepresentationCode on $projection.AddressRepresentationCode = _AddressRepresentationCode.AddressRepresentationCode
association [0..1] to I_AddressObjectType as _AddressObjectType on $projection.AddressObjectType = _AddressObjectType.AddressObjectType
association [0..1] to I_TimeZone as _TimeZone on $projection.AddressTimeZone = _TimeZone.TimeZoneID
association [0..1] to I_SecondaryRegion as _SecondaryRegion on $projection.SecondaryRegion = _SecondaryRegion.SecondaryRegion
and $projection.Country = _SecondaryRegion.Country
and $projection.Region = _SecondaryRegion.Region
association [0..1] to I_TertiaryRegion as _TertiaryRegion on $projection.TertiaryRegion = _TertiaryRegion.TertiaryRegion
and $projection.SecondaryRegion = _TertiaryRegion.SecondaryRegion
and $projection.Country = _TertiaryRegion.Country
and $projection.Region = _TertiaryRegion.Region
association [0..1] to I_PostalCity as _PostalCity on $projection.CityNumber = _PostalCity.CityNumber
and $projection.Country = _PostalCity.Country
association [0..1] to I_PostalCity as _POBoxDeviatingCityCode on $projection.POBoxDeviatingCityCode = _POBoxDeviatingCityCode.CityNumber
and $projection.Country = _POBoxDeviatingCityCode.Country
association [0..1] to I_RegionalStructureCheckStatus as _RegionalStructureCheckStatus on $projection.RegionalStructureCheckStatus = _RegionalStructureCheckStatus.RegionalStructureCheckStatus
association [0..1] to I_Street as _Street on $projection.Country = _Street.Country
and $projection.Street = _Street.Street
association [0..1] to I_AddressGroup as _AddressGroup on $projection.AddressGroup = _AddressGroup.AddressGroup
association [0..1] to I_AddressPersonName as _AddressPersonName on $projection.AddressPersonID = _AddressPersonName.AddressPersonID
and $projection.AddressRepresentationCode = _AddressPersonName.AddressRepresentationCode
{
key AddressID as AddressID,
@ObjectModel.foreignKey.association: '_AddressPersonName'
key cast('' as ad_persnum ) as AddressPersonID,
@ObjectModel.foreignKey.association: '_AddressRepresentationCode'
@ObjectModel.sapObjectNodeTypeReference: 'AddressRepresentationCode'
key AddressRepresentationCode as AddressRepresentationCode,
@ObjectModel.foreignKey.association: '_AddressObjectType'
@ObjectModel.sapObjectNodeTypeReference: 'AddressObjectType'
cast('1' as ad_adrtype) as AddressObjectType,
@ObjectModel.foreignKey.association: '_CorrespondenceLanguage'
CorrespondenceLanguage,
@ObjectModel.foreignKey.association: '_PrfrdCommMediumType'
@ObjectModel.sapObjectNodeTypeReference: 'CommunicationMediumType'
PrfrdCommMediumType,
cast(concat_with_space(AddresseeName1, AddresseeName2, 1) as ad_namtext ) as AddresseeFullName,
@ObjectModel.foreignKey.association: '_PostalCity'
@ObjectModel.sapObjectNodeTypeReference: 'CityNumber'
CityNumber,
CityName,
DistrictName,
VillageName,
PostalCode,
CompanyPostalCode,
@ObjectModel.foreignKey.association: '_Street'
@ObjectModel.sapObjectNodeTypeReference: 'Street'
Street,
StreetName,
@ObjectModel.foreignKey.association: '_StreetAddrNonDeliverableRsn'
@ObjectModel.sapObjectNodeTypeReference: 'AddressNonDeliverableReason'
@EndUserText.label: 'Street Address Non-Deliverable Reason'
StreetAddrNonDeliverableReason,
StreetPrefixName1,
StreetPrefixName2,
StreetSuffixName1,
StreetSuffixName2,
HouseNumber,
HouseNumberSupplementText,
Building,
Floor,
RoomNumber,
@ObjectModel.foreignKey.association: '_Country'
@ObjectModel.sapObjectNodeTypeReference: 'Country'
Country,
@ObjectModel.foreignKey.association: '_Region'
@ObjectModel.sapObjectNodeTypeReference: 'Region'
Region,
@ObjectModel.foreignKey.association: '_FormOfAddress'
@ObjectModel.sapObjectNodeTypeReference: 'FormOfAddress'
FormOfAddress,
AddresseeName1,
AddresseeName2,
AddresseeName3,
AddresseeName4,
AddressSearchTerm1,
AddressSearchTerm2,
TaxJurisdiction,
@ObjectModel.foreignKey.association: '_TransportationZone'
@ObjectModel.sapObjectNodeTypeReference: 'TransportationZone'
TransportZone,
POBox,
@ObjectModel.foreignKey.association: '_POBoxAddrNonDeliverableReason'
@ObjectModel.sapObjectNodeTypeReference: 'AddressNonDeliverableReason'
@EndUserText.label: 'PO Box Address Non-Deliverable Reason'
POBoxAddrNonDeliverableReason,
POBoxIsWithoutNumber,
POBoxPostalCode,
POBoxLobbyName,
POBoxDeviatingCityName,
@ObjectModel.foreignKey.association: '_POBoxDeviatingCityCode'
@ObjectModel.sapObjectNodeTypeReference: 'CityNumber'
POBoxDeviatingCityCode,
@ObjectModel.foreignKey.association: '_POBoxDeviatingRegion'
@ObjectModel.sapObjectNodeTypeReference: 'Region'
POBoxDeviatingRegion,
@ObjectModel.foreignKey.association: '_POBoxDeviatingCountry'
@ObjectModel.sapObjectNodeTypeReference: 'Country'
POBoxDeviatingCountry,
CareOfName,
@ObjectModel.foreignKey.association: '_DeliveryServiceTypeCode'
@ObjectModel.sapObjectNodeTypeReference: 'DeliveryServiceTypeCode'
DeliveryServiceTypeCode,
DeliveryServiceNumber,
@ObjectModel.foreignKey.association: '_TimeZone'
@ObjectModel.sapObjectNodeTypeReference: 'TimeZone'
AddressTimeZone,
@ObjectModel.foreignKey.association: '_SecondaryRegion'
@ObjectModel.sapObjectNodeTypeReference: 'SecondaryRegion'
SecondaryRegion,
SecondaryRegionName,
@ObjectModel.foreignKey.association: '_TertiaryRegion'
@ObjectModel.sapObjectNodeTypeReference: 'TertiaryRegion'
TertiaryRegion,
TertiaryRegionName,
@ObjectModel.foreignKey.association: '_RegionalStructureCheckStatus'
@ObjectModel.sapObjectNodeTypeReference: 'RegionalStructureCheckStatus'
RegionalStructureCheckStatus,
@ObjectModel.foreignKey.association: '_AddressGroup'
@ObjectModel.sapObjectNodeTypeReference: 'AddressGroup'
AddressGroup,
@Semantics.user.createdBy: true
AddressCreatedByUser,
@Semantics.systemDateTime.createdAt: true
@Analytics.hidden: true
AddressCreatedOnDateTime,
@Semantics.user.lastChangedBy: true
AddressChangedByUser,
@Semantics.systemDateTime.lastChangedAt: true
@Analytics.hidden: true
AddressChangedOnDateTime,
_EmailAddress,
_PhoneNumber,
_FaxNumber,
_UniformResourceIdentifier,
_CurrentDfltEmailAddress,
_CurrentDfltMobilePhoneNumber,
_CurrentDfltLandlinePhoneNmbr,
_CurrentDfltFaxNumber,
_MainWebsiteURL,
_Region,
_Country,
_FormOfAddress,
_StreetAddrNonDeliverableRsn,
_POBoxAddrNonDeliverableReason,
_TransportationZone,
_POBoxDeviatingRegion,
_POBoxDeviatingCountry,
_PrfrdCommMediumType,
_DeliveryServiceTypeCode,
_CorrespondenceLanguage,
_AddressObjectType,
_AddressRepresentationCode,
_TimeZone,
_SecondaryRegion,
_TertiaryRegion,
_PostalCity,
_RegionalStructureCheckStatus,
_Street,
_AddressGroup,
_AddressPersonName,
_POBoxDeviatingCityCode
}
where
AddressIsPersonAddress is initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRORGNAMEPOSTALADDRESS"
],
"ASSOCIATED":
[
"I_ADDRCURDEFAULTEMAILADDRESS",
"I_ADDRCURDEFAULTFAXNUMBER",
"I_ADDRCURDFLTLANDLINEPHONENMBR",
"I_ADDRCURDFLTMOBILEPHONENUMBER",
"I_ADDRESSCOMMUNICATIONMETHOD",
"I_ADDRESSDELIVERYSERVICETYPE",
"I_ADDRESSEMAILADDRESS_2",
"I_ADDRESSFAXNUMBER_2",
"I_ADDRESSGROUP",
"I_ADDRESSMAINWEBSITEURL",
"I_ADDRESSNONDELIVERABLEREASON",
"I_ADDRESSOBJECTTYPE",
"I_ADDRESSPERSONNAME",
"I_ADDRESSPHONENUMBER_2",
"I_ADDRESSREPRESENTATION",
"I_ADDRESSURI",
"I_COUNTRY",
"I_FORMOFADDRESS",
"I_LANGUAGE",
"I_POSTALCITY",
"I_REGION",
"I_REGIONALSTRUCTURECHECKSTATUS",
"I_SECONDARYREGION",
"I_STREET",
"I_TERTIARYREGION",
"I_TIMEZONE",
"I_TRANSPORTATIONZONE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/