I_OPERATIONCONTROLPROFILE

CDS View

Operation Control Profile

I_OPERATIONCONTROLPROFILE is a CDS View in S/4HANA. Operation Control Profile. 23 CDS views read from this table.

Used by 23 CDS view(s)

CDS Views using this table (23)

ViewTypeJoinVDMDescription
A_ProductionRoutingOpCtrlPrfl view_entity from BASIC Operation Control Profile
C_InspPlanOpCtrlProfileVH view from CONSUMPTION Insp Plan Op Control Key ValueHelp
C_MaintOrderOpCtrlKeyVH view from CONSUMPTION VH for Maint Order Operation Control Key
C_MfgOrdOpForReworkInsertion view inner CONSUMPTION Order operation for rework insertion
I_CapEvalByAreaOfRespy view inner COMPOSITE Work Center By Area Of Responsibility
I_EvaltCapWrkCtrGrpAreaOfRespy view_entity inner COMPOSITE Work Center Group Area of Responsibility
I_OperationControlProfileVH view from COMPOSITE Operation Control Profile
I_ProdnModBOOOpCtrlProfileVH view_entity from BASIC Operation Control Profile
I_RSHMaintOperationAssgmtTP view inner TRANSACTIONAL Maintenance Operation Assignment TP
I_RSHMaintSchedExistingOp view inner COMPOSITE Existing Operations not part of Schedule
I_RSHMaintSchedSmltdOp view inner COMPOSITE Maint Scheduling Simulation Operations
I_RSHOperationAndSubOperation view inner COMPOSITE Maintenance Order Operation and Suboperation
I_SchedProdnWrkCtrAreaOfRespy view inner COMPOSITE Work Centers By Area of Responsibilty
I_WrkCtrCapByAreaOfRespy view inner COMPOSITE Work Center By Area Of Responsibility
P_MaintPlngBcktResource view inner CONSUMPTION
P_RSHDueOperForKPIDetails view inner CONSUMPTION Past Order Operation KPI Details
P_RSHExOpsForScheduling view inner CONSUMPTION
P_RSHOperationsForKPI view inner CONSUMPTION Operations and Sub Operations for overview page
P_RSHOperationsForKPIDetails view inner CONSUMPTION Order KPI Details
P_RSHOperationsForUtilization view inner CONSUMPTION Operations and Sub Operations for utilization
P_RSHPastOperForKPIDetails view inner CONSUMPTION Past Order Operation KPI Details
P_RSHTaskListOperations view inner CONSUMPTION Task List Operations
P_WrkCtrMntrAlternateWrkCtr view inner CONSUMPTION 
@AbapCatalog.sqlViewName: 'IPPOPCONTPROF'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.buffering: {status: #ACTIVE, type: #GENERIC, numberOfKeyFields: 001}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@Consumption.ranked: true
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.compositionRoot: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #SEARCHABLE_ENTITY]
@ObjectModel.representativeKey: 'OperationControlProfile'
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #S, dataClass: #CUSTOMIZING}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Operation Control Profile'

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view I_OperationControlProfile
  as select from t430 as prof 
  
  association [0..*] to I_OperationControlProfileText as _Text                        on  $projection.OperationControlProfile     = _Text.OperationControlProfile
  association [0..1] to I_OperationExternalProcessing as _OperationExternalProcessing on  $projection.OperationExternalProcessing = _OperationExternalProcessing.OperationExternalProcessing
{
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
      @ObjectModel.text.association: '_Text'
  key cast(prof.steus as pph_steus preserving type) as OperationControlProfile,

      @ObjectModel.foreignKey.association: '_OperationExternalProcessing'
      cast(prof.lief as pph_lief preserving type)   as OperationExternalProcessing,
      cast( case prof.lief
        when '+' then 'X'
        when 'X' then 'X'
        else ''
      end as flg_frd preserving type)               as OperationIsProcessedExternally,
      cast( case prof.lief
        when ' ' then 'X'
        when 'X' then 'X'
        else ''
      end as ps_workact preserving type)            as OperationIsProcessedInternally,
      cast( case prof.ruek
        when '1' then 'X'
        else ''
      end as flg_mst preserving type)               as OperationIsMilestone,
      cast( case prof.ruek
        when '2' then 'X'
        else ''
      end as pph_confisrequired preserving type)    as ConfirmationIsRequired,
      cast( case prof.ruek
        when '3' then 'X'
        else ''
      end as pph_confisnotpossible preserving type) as ConfirmationIsNotPossible,
      cast( case prof.ruek
        when '' then 'X'
        else ''
      end as pph_confisoptional preserving type)    as ConfirmationIsOptional,
      prof.term                                     as OperationIsScheduled,
      prof.vrgd                                     as OperationIsPrinted,
      prof.kalkz                                    as OperationIsIncludedInCosting,
      prof.rework                                   as OperationIsReworkOperation,
      prof.autwe                                    as GRIsPostedAutomatically,
      prof.kapa                                     as CapacityRequirementsAreDtmnd,
      prof.mrkkz                                    as InspCharacteristicIsRequired,
      prof.not_mes_rel                              as OperationIsNotMESRelevant,

      // Associations

      _OperationExternalProcessing,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _Text
}
where
  prof.plnaw = '*';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"T430"
],
"ASSOCIATED":
[
"I_OPERATIONCONTROLPROFILETEXT",
"I_OPERATIONEXTERNALPROCESSING"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More