I_NOTIFICATIONCAUSE

CDS View

Notification Cause

I_NOTIFICATIONCAUSE is a CDS View in S/4HANA. Notification Cause. It contains 22 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 22 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_QltyNotificationCause view from COMPOSITE Quality Notification Item Cause

Fields (22)

KeyField CDS FieldsUsed in Views
KEY Notification QualityNotification 1
KEY NotificationCauseID NotificationCauseID 1
KEY NotificationItem NotificationItem 1
_CreatedByUserContactCard _CreatedByUserContactCard 1
_LastChangedByUserContactCard _LastChangedByUserContactCard 1
_NotifCauseCode _NotifCauseCode 1
_NotifCauseCodeCatalog _NotifCauseCodeCatalog 1
_NotifCauseCodeGroup _NotifCauseCodeGroup 1
_NotificationRootCause _NotificationRootCause 1
ChangedDateTime ChangedDateTime 1
CreatedByUser CreatedByUser 1
CreationDate CreationDate 1
CreationTime CreationTime 1
IsBusinessPurposeCompleted IsBusinessPurposeCompleted 1
LastChangeDate LastChangeDate 1
LastChangedByUser LastChangedByUser 1
LastChangeTime LastChangeTime 1
MasterLanguage MasterLanguage 1
NotificationCauseCode NotificationCauseCode 1
NotificationCauseSortNumber NotificationCauseSortNumber 1
NotificationCauseText NotificationCauseText 1
NotificationRootCause NotificationRootCause 1 
@AbapCatalog.sqlViewName: 'INOTIFCAUSE'
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Notification Cause'
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl.authorizationCheck: #CHECK
@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #L,
        serviceQuality: #A },
    representativeKey: 'NotificationCauseID'
}

define view I_NotificationCause as select from qmur 
  association [1..1] to I_Notification as _Notification on $projection.Notification = _Notification.Notification
  association [1..1] to I_NotificationItem as _NotificationItem on  $projection.Notification = _NotificationItem.Notification and
                                                                    $projection.NotificationItem = _NotificationItem.NotificationItem
  
  association [0..1] to I_UserContactCard as _CreatedByUserContactCard on $projection.CreatedByUser = _CreatedByUserContactCard.ContactCardID
  association [0..1] to I_UserContactCard as _LastChangedByUserContactCard on $projection.LastChangedByUser = _LastChangedByUserContactCard.ContactCardID
  
  association [0..1] to I_NotifCauseCodeCatalog as _NotifCauseCodeCatalog on $projection.NotificationCauseCodeCatalog = _NotifCauseCodeCatalog.NotificationCauseCodeCatalog
  association [0..1] to I_NotifCauseCodeGroup as _NotifCauseCodeGroup on  $projection.NotificationCauseCodeCatalog = _NotifCauseCodeGroup.NotificationCauseCodeCatalog and
                                                                          $projection.NotificationCauseCodeGroup = _NotifCauseCodeGroup.NotificationCauseCodeGroup
  association [0..1] to I_NotifCauseCode as _NotifCauseCode on  $projection.NotificationCauseCodeCatalog = _NotifCauseCode.NotificationCauseCodeCatalog and
                                                                $projection.NotificationCauseCodeGroup = _NotifCauseCode.NotificationCauseCodeGroup and
                                                                $projection.NotificationCauseCode = _NotifCauseCode.NotificationCauseCode
  association [0..1] to I_NotificationRootCause as _NotificationRootCause on $projection.NotificationRootCause = _NotificationRootCause.NotificationRootCause
  
  //Extension

  association [1..1] to E_NotificationCause as _Extension on  $projection.Notification        = _Extension.Notification
                                                          and $projection.NotificationItem    = _Extension.NotificationItem
                                                          and $projection.NotificationCauseID = _Extension.NotificationCauseID 
  
{
  @ObjectModel.foreignKey.association: '_Notification'
  key qmur.qmnum as Notification,
  @ObjectModel.foreignKey.association: '_NotificationItem'
  key qmur.fenum as NotificationItem,  
  @ObjectModel.text.element: ['NotificationCauseText']
  key qmur.urnum as NotificationCauseID,
  qmur.qurnum as NotificationCauseSortNumber,
  @ObjectModel.foreignKey.association: '_CreatedByUserContactCard'
  qmur.ernam as CreatedByUser,
  qmur.erdat as CreationDate,
  qmur.erzeit as CreationTime,
  
  @ObjectModel.foreignKey.association: '_LastChangedByUserContactCard'
  qmur.aenam as LastChangedByUser,
  qmur.aedat as LastChangeDate,
  qmur.aezeit as LastChangeTime,
  
  @Semantics.text: true
  qmur.urtxt as NotificationCauseText,
  
  @ObjectModel.foreignKey.association: '_NotifCauseCodeCatalog'
  qmur.urkat as NotificationCauseCodeCatalog,
  @ObjectModel.foreignKey.association: '_NotifCauseCodeGroup'
  qmur.urgrp as NotificationCauseCodeGroup,
  @ObjectModel.foreignKey.association: '_NotifCauseCode'
  qmur.urcod as NotificationCauseCode,
  
  case changeddatetime
        when 0 then cast( '19000101010101' as tzntstmps )
        else changeddatetime                            
    end         as ChangedDateTime,
  cast(qmur.kzmla as vdm_j_masterlanguage )  as MasterLanguage,
  qmur.kzloesch as IsDeleted,
  @ObjectModel.foreignKey.association: '_NotificationRootCause'
  cast( qmur.rootcause as vdm_notificationrootcause preserving type ) as NotificationRootCause,
  
  _Notification.IsBusinessPurposeCompleted,  
  
  
  _Notification,
  _NotificationItem,
  _CreatedByUserContactCard,
  _LastChangedByUserContactCard,
  _NotifCauseCodeCatalog,
  _NotifCauseCodeGroup,
  _NotifCauseCode,
  _NotificationRootCause
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_NOTIFICATION",
"QMUR"
],
"ASSOCIATED":
[
"E_NOTIFICATIONCAUSE",
"I_NOTIFCAUSECODE",
"I_NOTIFCAUSECODECATALOG",
"I_NOTIFCAUSECODEGROUP",
"I_NOTIFICATION",
"I_NOTIFICATIONITEM",
"I_NOTIFICATIONROOTCAUSE",
"I_USERCONTACTCARD"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More