I_MFGORDEROPERATIONPRT

@AbapCatalog.sqlViewName: 'IPPMFGORDOPPRT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.privilegedAssociations: ['_CreatedByUser', '_LastChangedByUser']
@Analytics.dataCategory: #DIMENSION
@Analytics.dataExtraction.enabled: true
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #EXTRACTION_DATA_SOURCE]
@ObjectModel.representativeKey: 'MfgOrderOpProdnRsceToolIntID'
@ObjectModel.semanticKey: ['ManufacturingOrder', 'ManufacturingOrderSequence', 'ManufacturingOrderOperation', 'ProdnRsceToolItemNumber']
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #L, dataClass: #MIXED}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Mfg Order Operation Production Resource Tool'

define view I_MfgOrderOperationPRT
  as select from I_OrderProdnResourceTool as prt
    inner join   I_OrderOperationBasic    as opr on  opr.OrderInternalID          = prt.OrderInternalBillOfOperations
                                                 and opr.OrderOperationInternalID = prt.OrderIntBillOfOperationsItem

  association [1..1] to I_OrderInternalID             as _MfgOrderInternalID          on  $projection.MfgOrderInternalID = _MfgOrderInternalID.OrderInternalID
  association [1..1] to I_ManufacturingOrder          as _MfgOrder                    on  $projection.ManufacturingOrder = _MfgOrder.ManufacturingOrder
  association [1..1] to I_MfgOrder                    as _MfgOrder2                   on  $projection.ManufacturingOrder = _MfgOrder2.ManufacturingOrder
  association [1..1] to I_MfgOrderSequence            as _MfgOrderSequence            on  $projection.ManufacturingOrder         = _MfgOrderSequence.ManufacturingOrder
                                                                                      and $projection.ManufacturingOrderSequence = _MfgOrderSequence.ManufacturingOrderSequence
  association [1..1] to I_ManufacturingOrderSequence  as _MfgOrderSequence2           on  $projection.ManufacturingOrder         = _MfgOrderSequence2.ManufacturingOrder
                                                                                      and $projection.ManufacturingOrderSequence = _MfgOrderSequence2.ManufacturingOrderSequence
  association [1..1] to I_ManufacturingOrderOperation as _MfgOrderOperation           on  $projection.MfgOrderInternalID       = _MfgOrderOperation.MfgOrderInternalID
                                                                                      and $projection.OrderOperationInternalID = _MfgOrderOperation.OrderOperationInternalID
  association [1..1] to I_MfgOrderOperationBySemanKey as _MfgOrderOperationBySemanKey on  $projection.ManufacturingOrder          = _MfgOrderOperationBySemanKey.ManufacturingOrder
                                                                                      and $projection.ManufacturingOrderSequence  = _MfgOrderOperationBySemanKey.ManufacturingOrderSequence
                                                                                      and $projection.ManufacturingOrderOperation = _MfgOrderOperationBySemanKey.ManufacturingOrderOperation
  association [1..1] to I_MfgOrderOperationBySemKey   as _MfgOrderOperationBySemKey   on  $projection.ManufacturingOrder            = _MfgOrderOperationBySemKey.ManufacturingOrder
                                                                                      and $projection.ManufacturingOrderSequence    = _MfgOrderOperationBySemKey.ManufacturingOrderSequence
                                                                                      and $projection.ManufacturingOrderOperation_2 = _MfgOrderOperationBySemKey.ManufacturingOrderOperation
  association [1..1] to I_MfgOrderCategory            as _MfgOrderCategory            on  $projection.ManufacturingOrderCategory = _MfgOrderCategory.ManufacturingOrderCategory
  association [1..1] to I_MfgOrderType                as _MfgOrderType                on  $projection.ManufacturingOrderType = _MfgOrderType.ManufacturingOrderType
  association [1..1] to I_ProdnRsceToolCategory       as _ProdnRsceToolCategory       on  $projection.ProdnRsceToolCategory   = _ProdnRsceToolCategory.ProdnRsceToolCategory // deprecated

  association [1..1] to I_ProdnRsceToolCategory_2     as _ProdnRsceToolCategory_2     on  $projection.ProdnRsceToolCategory_2 = _ProdnRsceToolCategory_2.ProdnRsceToolCategory
  association [1..1] to I_Plant                       as _ProductionPlant             on  $projection.ProductionPlant = _ProductionPlant.Plant
  association [1..1] to I_OperationControlProfile     as _OperationControlProfile     on  $projection.OperationControlProfile = _OperationControlProfile.OperationControlProfile
{
      // Key

      @ObjectModel.foreignKey.association: '_MfgOrderInternalID'
  key prt.OrderInternalBillOfOperations as MfgOrderInternalID,
      @ObjectModel.text.element: ['MfgOrderOpProdnRsceToolText']
  key prt.OrderProdnRsceToolInternalID  as MfgOrderOpProdnRsceToolIntID,

      // Admin data

      prt.IsDeleted,
      @Semantics.systemDate.createdAt: true
      prt.CreationDate,
      @Semantics.user.createdBy: true
      prt.CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      prt.LastChangeDate,
      @Semantics.user.lastChangedBy: true
      prt.LastChangedByUser,

      // Text

      @Semantics.text: true
      prt.OrderProdnRsceToolText        as MfgOrderOpProdnRsceToolText,
      @ObjectModel.foreignKey.association: '_Language'
      prt.Language,

      // PRT data

      @ObjectModel.foreignKey.association: '_ProductionResourceType'
      prt.ProductionResourceType,
      @ObjectModel.foreignKey.association: '_ProdnRsceToolByInternalKey'
      prt.ProductionResourceInternalID,
      cast(prt._ProdnRsceToolByInternalKey.ProductionResourceTool as pph_fhmnr preserving type) as ProductionResourceTool,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'ProdnRsceToolCategory_2'
      @ObjectModel.foreignKey.association: '_ProdnRsceToolCategory'
      prt._ProdnRsceToolByInternalKey.ProdnRsceToolCategory                 as ProdnRsceToolCategory,   // with conv. exit

      @ObjectModel.foreignKey.association: '_ProdnRsceToolCategory_2'      
      prt._ProdnRsceToolByInternalKey.ProdnRsceToolCategory_2               as ProdnRsceToolCategory_2, // w/o conv. exit

      @ObjectModel.foreignKey.association: '_ProdnRsceToolControlProfile'
      prt.ProdnRsceToolControlProfile,
      @ObjectModel.text.element: ['MfgOrderOpProdnRsceToolText']
      prt.ProdnRsceToolItemNumber,
--    @ObjectModel.foreignKey.association:    
      prt.ObjectInternalID,

      // Order and Operation data

      @ObjectModel.foreignKey.association: '_MfgOrderOperation'
      prt.OrderIntBillOfOperationsItem                                      as OrderOperationInternalID,
      @ObjectModel.foreignKey.association: '_MfgOrder'
      cast(prt.OrderID as manufacturingorder preserving type)               as ManufacturingOrder,
      @ObjectModel.foreignKey.association: '_MfgOrderSequence2'
      cast(opr.Sequence as manufacturingordersequence preserving type)      as ManufacturingOrderSequence,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'ManufacturingOrderOperation_2'
      @ObjectModel.foreignKey.association: '_MfgOrderOperationBySemanKey'
      cast(opr.Operation as manufacturingorderoperation preserving type)    as ManufacturingOrderOperation,  // with conv. exit

      @ObjectModel.foreignKey.association: '_MfgOrderOperationBySemKey' 
      opr.Operation_2                                                       as ManufacturingOrderOperation_2, // w/o conv. exit

      opr.MfgOrderOperationIsPhase                                          as MfgOrderOperationIsPhase,
      @ObjectModel.foreignKey.association: '_MfgOrderCategory'
      cast(prt.OrderCategory as manufacturingordercategory preserving type) as ManufacturingOrderCategory,
      @ObjectModel.foreignKey.association: '_MfgOrderType'
      cast(prt.OrderType as manufacturingordertype preserving type)         as ManufacturingOrderType,
      @ObjectModel.foreignKey.association: '_ProductionPlant'
      cast(prt.Plant as pwwrk preserving type)                              as ProductionPlant,
      @ObjectModel.foreignKey.association: '_OperationControlProfile'
      cast(opr.OperationControlProfile as pph_steus preserving type)        as OperationControlProfile,

      // BOO Data

      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
      prt.BillOfOperationsType,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
      prt.BillOfOperationsGroup,

      // Dates and Times

      prt.EarliestSchedldUsageStartDate,
      prt.EarliestSchedldUsageStartTime,
      prt.EarliestSchedldUsageEndDate,
      prt.EarliestSchedldUsageEndTime,
      prt.LatestSchedldUsageStartDate,
      prt.LatestSchedldUsageStartTime,
      prt.LatestSchedldUsageEndDate,
      prt.LatestSchedldUsageEndTime,
      prt.ActualUsageStartDate,
      prt.ActualUsageStartTime,
      prt.ActualUsageEndDate,
      prt.ActualUsageEndTime,

      // Duration

      @Semantics.unitOfMeasure: true
      prt.ProdnRsceToolUsageDurnUnit,
      prt.ProdnRsceToolUsageDuration,

      // Quantities and UoM

      @Semantics.unitOfMeasure: true
      prt.ProdnRsceToolStdWorkQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'ProdnRsceToolStdWorkQtyUnit'
      @Aggregation.default: #SUM
      prt.ProdnRsceToolStandardWorkQty,

      @Semantics.unitOfMeasure: true
      prt.PlannedProdnRsceToolQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'PlannedProdnRsceToolQtyUnit'
      @Aggregation.default: #SUM
      prt.PlannedTotalProdnRsceToolQty,

      @Semantics.unitOfMeasure: true
      prt.ConfirmedProdnRsceToolQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'ConfirmedProdnRsceToolQtyUnit'
      @Aggregation.default: #SUM
      prt.ConfirmedProdnRsceToolQty,

      @Semantics.unitOfMeasure: true
      prt.RemainingProdnRsceToolQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'RemainingProdnRsceToolQtyUnit'
      @Aggregation.default: #SUM
      prt.RemainingProdnRsceToolQty,

      // Usage Quantities and UoMs

      @Semantics.unitOfMeasure: true
      prt.ProdnRsceToolUsageQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'ProdnRsceToolUsageQuantityUnit'
      @Aggregation.default: #SUM
      prt.ProdnRsceToolUsageQuantity,

      @Semantics.unitOfMeasure: true
      prt.PlndProdnRsceToolUsageQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'PlndProdnRsceToolUsageQtyUnit'
      @Aggregation.default: #SUM
      prt.PlannedProdnRsceToolUsageQty,

      @Semantics.unitOfMeasure: true
      prt.ConfdProdnRsceToolUsageQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'ConfdProdnRsceToolUsageQtyUnit'
      @Aggregation.default: #SUM
      prt.ConfirmedProdnRsceToolUsageQty,

      @Semantics.unitOfMeasure: true
      prt.RmngProdnRsceToolUsageQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'RmngProdnRsceToolUsageQtyUnit'
      @Aggregation.default: #SUM
      prt.RemainingProdnRsceToolUsageQty,

      // Formulas

      prt.ProdnRsceToolTotQtyCalcFormula,
      prt.ProdnRsceToolUsageQtyCalcFmla,

      // Associations

      _MfgOrderInternalID,
      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT]
      _MfgOrder,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_MfgOrder'
      _MfgOrder2,
      _MfgOrderSequence,
--    @API.element.releaseState: #DEPRECATED
--    @API.element.successor: '_MfgOrderSequence2'
      _MfgOrderSequence2,
      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT]
      _MfgOrderOperation,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_MfgOrderOperationBySemKey'
      _MfgOrderOperationBySemanKey,
      _MfgOrderOperationBySemKey,   
      _MfgOrderCategory,
      _MfgOrderType,
      _ProductionPlant,
      _OperationControlProfile,
      prt._ProdnRsceToolControlProfile,
      prt._ProductionResourceType,
      prt._ProdnRsceToolByInternalKey,
      prt._ProdnRsceToolMasterData,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_ProdnRsceToolCategory_2'
      _ProdnRsceToolCategory,
      _ProdnRsceToolCategory_2,
      prt._CreatedByUser,
      prt._LastChangedByUser,
      prt._Language,
      prt._BillOfOperationsType,
      prt._BillOfOperationsGroup,
      prt._ProdnRsceToolUsageDurnUnit,
      prt._ProdnRsceToolStdWorkQtyUnit,
      prt._PlannedProdnRsceToolQtyUnit,
      prt._ConfirmedProdnRsceToolQtyUnit,
      prt._RemainingProdnRsceToolQtyUnit,
      prt._ProdnRsceToolUsageQtyUnit,
      prt._PlndProdnRsceToolUsageQtyUnit,
      prt._ConfdProdnRsceToolUsgeQtyUnit,
      prt._RmngProdnRsceToolUsageQtyUnit
}
where
  (    prt.OrderCategory = '10'
    or prt.OrderCategory = '40' //Manufacturing orders only

  );
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ORDEROPERATIONBASIC",
"I_ORDERPRODNRESOURCETOOL",
"I_PRODNRSCETOOLBYINTERNALKEY"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSTYPE",
"I_LANGUAGE",
"I_MANUFACTURINGORDER",
"I_MANUFACTURINGORDEROPERATION",
"I_MANUFACTURINGORDERSEQUENCE",
"I_MFGORDER",
"I_MFGORDERCATEGORY",
"I_MFGORDEROPERATIONBYSEMANKEY",
"I_MFGORDEROPERATIONBYSEMKEY",
"I_MFGORDERSEQUENCE",
"I_MFGORDERTYPE",
"I_OPERATIONCONTROLPROFILE",
"I_ORDERINTERNALID",
"I_PLANT",
"I_PRODNRSCETOOLBYINTERNALKEY",
"I_PRODNRSCETOOLCATEGORY",
"I_PRODNRSCETOOLCATEGORY_2",
"I_PRODNRSCETOOLCONTROLPROFILE",
"I_PRODNRSCETOOLMASTERDATA",
"I_PRODUCTIONRESOURCETYPE",
"I_UNITOFMEASURE",
"I_USER"
],
"BASE":
[
"I_ORDERPRODNRESOURCETOOL"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/