I_MATERIALPRTBYINTERNALKEY

@AbapCatalog.sqlViewName: 'IPPMATERIALPRTIK'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'ProductionResourceInternalID'
@ObjectModel.semanticKey: 'Material'
@Analytics.dataCategory: #DIMENSION
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Material PRT by internal key'
@Search.searchable: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER }
@Metadata.allowExtensions:true

define view I_MaterialPRTByInternalKey
  as select from I_ProdnRsceToolMasterData as PRT
    inner join   crvm_a on  crvm_a.objty = PRT.ProductionResourceType
                        and crvm_a.objid = PRT.ProductionResourceInternalID

  association [1..1] to I_Material              as _Material              on  $projection.Material = _Material.Material

  association [1..1] to I_Product               as _Product               on  $projection.Product = _Product.Product

  association [1..1] to I_Plant                 as _Plant                 on  $projection.Plant = _Plant.Plant

  association [1..1] to I_ProductPlant          as _ProductPlant          on  $projection.Product = _ProductPlant.Product
                                                                          and $projection.Plant   = _ProductPlant.Plant

  association [1..1] to I_ProductPlantBasic     as _ProductPlant2         on  $projection.Product = _ProductPlant2.Product
                                                                          and $projection.Plant   = _ProductPlant2.Plant

  association [1..1] to I_MaterialProdnRsceTool as _MaterialProdnRsceTool on  $projection.Plant    = _MaterialProdnRsceTool.Plant
                                                                          and $projection.Material = _MaterialProdnRsceTool.Material

{
      @ObjectModel.foreignKey.association: '_ProductionResourceType'
  key PRT.ProductionResourceType,
  key PRT.ProductionResourceInternalID,
      @ObjectModel.foreignKey.association: '_Plant'
      @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}
      crvm_a.werks as Plant,
      @ObjectModel.foreignKey.association: '_MaterialProdnRsceTool'
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
      crvm_a.matnr as Material,
      @ObjectModel.foreignKey.association: '_Product'
      crvm_a.matnr as Product,
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
      PRT.ProductionResourceToolGroup1,
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
      PRT.ProductionResourceToolGroup2,
      PRT.ProductionResourceUsage,
      ProdnRsceToolControlProfile,
      PRT.ChangeNumber,
      ProdnRsceToolStandardTextCode,
      ProdnRsceToolTotQtyCalcFormula,
      ProdnRsceToolUsageQtyCalcFmla,
      StartDateOffsetReferenceCode,
      EndDateOffsetReferenceCode,
      // Reference Indicators

      EndDateOffsetDurnIsReferenced,
      StartDateOffstDurnIsReferenced,
      EndDteOffstRefCodeIsReferenced,
      StartDateOffsetRefCodeIsRefcd,
      PRTTotQtyCalcFmlaIsReferenced,
      PRTUsgeQtyCalcFmlaIsReferenced,
      PRTControlProfileIsReferenced,
      PRTStdTextCodeIsReferenced,

      @Semantics.quantity.unitOfMeasure: 'StartDateOffsetDurationUnit'
      @DefaultAggregation: #SUM
      StartDateOffsetDuration,
      @Semantics.unitOfMeasure: true
      StartDateOffsetDurationUnit,
      @Semantics.quantity.unitOfMeasure: 'EndDateOffsetDurationUnit'
      @DefaultAggregation: #SUM
      EndDateOffsetDuration,
      @Semantics.unitOfMeasure: true
      EndDateOffsetDurationUnit,

      // Admin

      @Semantics.systemDate.createdAt: true
      CreationDate,
      @Semantics.user.createdBy: true
      CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      LastChangeDate,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser,

      //PRT can be Registered at Production Execution

      ShopFloorRtgPRTIsRegistrable,
      
      _ProductionResourceType,
      _Material,
      _Plant,
      _Product,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_ProductPlant2'
      _ProductPlant,
      _ProductPlant2,
      _ProdnRsceToolGroup1,
      _ProdnRsceToolGroup2,
      _ProductionResourceUsage,
      _ProdnRsceToolControlProfile,
      _ProdnRsceToolStandardText,
      _ProdnRsceToolTotQtyCalcFmla,
      _ProdnRsceToolUsageQtyCalcFmla,
      _StartDateOffsetReferenceCode,
      _EndDateOffsetReferenceCode,
      _StartDateOffsetDurationUnit,
      _EndDateOffsetDurationUnit,

      _MaterialProdnRsceTool,

      _CreatedByUser,
      _LastChangedByUser,
      _ChangeMaster
}
where
  PRT.ProdnRsceToolCategory = 'M' // Material

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PRODNRSCETOOLMASTERDATA",
"CRVM_A"
],
"ASSOCIATED":
[
"I_CHANGEMASTER",
"I_MATERIAL",
"I_MATERIALPRODNRSCETOOL",
"I_OPERATIONDATEOFFSETREFCODE",
"I_PLANT",
"I_PRODNRSCETOOLCONTROLPROFILE",
"I_PRODNRSCETOOLGROUP",
"I_PRODNRSCETOOLQTYCALCFORMULA",
"I_PRODNRSCETOOLSTANDARDTEXT",
"I_PRODUCT",
"I_PRODUCTIONRESOURCETYPE",
"I_PRODUCTIONRESOURCEUSAGE",
"I_PRODUCTPLANT",
"I_PRODUCTPLANTBASIC",
"I_UNITOFMEASURE",
"I_USER"
],
"BASE":
[
"I_PRODNRSCETOOLMASTERDATA"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/