I_MASTERRECIPEHEADER

CDS View

Master Recipe Header Details

I_MASTERRECIPEHEADER is a CDS View in S/4HANA. Master Recipe Header Details. It contains 25 fields. 3 CDS views read from this table.

Used by 3 CDS view(s) 25 fields

CDS Views using this table (3)

ViewTypeJoinVDMDescription
C_LinkedProdnVersBOO view_entity from CONSUMPTION BOO to Material Assignment for ProdnVers
C_LinkedProdnVersBOO view_entity union CONSUMPTION BOO to Material Assignment for ProdnVers
I_MasterRecipeHeaderTP view_entity from TRANSACTIONAL Master Recipe - Header

Fields (25)

KeyField CDS FieldsUsed in Views
KEY BillOfOperationsGroup MasterRecipeGroup 1
KEY BillOfOperationsVariant MasterRecipe 1
KEY BOOInternalVersionCounter MasterRecipeInternalVersion,ProductionRoutingInternalVers 2
BillOfOperationsDesc BillOfOperationsDesc 2
BillOfOperationsProfile BillOfOperationsProfile 1
BillOfOperationsStatus BillOfOperationsStatus 2
BillOfOperationsUnit BillOfOperationsUnit 2
BillOfOperationsUsage BillOfOperationsUsage 2
ChangeNumber ChangeNumber 1
CreatedByUser CreatedByUser 1
CreationDate CreationDate 1
LastChangeDate LastChangeDate 1
LastChangedByUser LastChangedByUser 1
LongTextLanguageCode LongTextLanguageCode 1
MaximumLotSizeQuantity MaximumLotSizeQuantity 2
MinimumLotSizeQuantity MinimumLotSizeQuantity 2
OperationReferenceQuantity OperationReferenceQuantity 1
OperationUnit OperationUnit 1
OpQtyToBaseQtyDnmntr OpQtyToBaseQtyDnmntr 1
OpQtyToBaseQtyNmrtr OpQtyToBaseQtyNmrtr 1
PlainLongText PlainLongText 1
Plant Plant 1
ResponsiblePlannerGroup ResponsiblePlannerGroup 1
ValidityEndDate ValidityEndDate 2
ValidityStartDate ValidityStartDate 2 
@AbapCatalog.sqlViewName: 'IMSTRRECPHDR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #BASIC
@Analytics: {dataCategory: #DIMENSION}
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'BOOInternalVersionCounter'
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Master Recipe Header Details'
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER }
@Metadata.allowExtensions: true
define view I_MasterRecipeHeader
  as select from I_MfgBillOfOperationsChgSt
  association [0..1] to I_TaskListLongText as _LongText on  $projection.BillOfOperationsType      = _LongText.TaskListType
                                                        and $projection.BillOfOperationsGroup     = _LongText.TaskListGroup
                                                        and $projection.BillOfOperationsVariant   = _LongText.TaskListGroupCounter
                                                        and $projection.BOOInternalVersionCounter = _LongText.TaskListVersionCounter
                                                        and $projection.LongTextLanguageCode      is not null
{
  key BillOfOperationsType,
  key BillOfOperationsGroup,
  key BillOfOperationsVariant,
  key BOOInternalVersionCounter,
      @Semantics.businessDate.from: true
      cast( ValidityStartDate as vdm_datuv ) as ValidityStartDate,
      @Semantics.businessDate.to: true
      cast( ValidityEndDate as vdm_datub )   as ValidityEndDate,
      ChangeNumber,
      IsMarkedForDeletion, //DELKZ

      IsDeleted,           //LOEKZ

      IsImplicitlyDeleted, //LOEKZ_INHERITED

      @Semantics.text: true
      BillOfOperationsDesc,
      LongTextLanguageCode,
      @ObjectModel.foreignKey.association: '_Plant'
      Plant,
      @ObjectModel.foreignKey.association: '_BillOfOperationsUsage'
      BillOfOperationsUsage,
      @ObjectModel.foreignKey.association: '_BillOfOperationsStatus'
      BillOfOperationsStatus,
      @ObjectModel.foreignKey.association: '_ResponsiblePlannerGroup'
      ResponsiblePlannerGroup,
      BillOfOperationsProfile,
      @Semantics.quantity.unitOfMeasure: 'BillOfOperationsUnit'
      @DefaultAggregation: #MIN
      MinimumLotSizeQuantity,
      @Semantics.quantity.unitOfMeasure: 'BillOfOperationsUnit'
      @DefaultAggregation: #MAX
      MaximumLotSizeQuantity,
      @Semantics.unitOfMeasure: true
      BillOfOperationsUnit,
      @Semantics.systemDate.createdAt: true
      cast( CreationDate as vdm_andat )      as CreationDate,
      @Semantics.user.createdBy: true
      cast( CreatedByUser as vdm_annam )     as CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      cast( LastChangeDate as vdm_aedat )    as LastChangeDate,
      @Semantics.user.lastChangedBy: true
      cast( LastChangedByUser as vdm_aenam ) as LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      ChangedDateTime,
      @Consumption.hidden: true
      _LongText.PlainLongText,

      // Default values of Activity

      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      OperationReferenceQuantity,
      @Semantics.unitOfMeasure: true
      OperationUnit,
      OpQtyToBaseQtyNmrtr,
      OpQtyToBaseQtyDnmntr,      
      
      /*    Associations    */
      _BillOfOperations,
      _BillOfOperationsType,
      _BillOfOperationsGroup,
      _BillOfOperationsUsage,
      _BillOfOperationsStatus,
      _ResponsiblePlannerGroup,
      _BillOfOperationsUnit,
      _Plant,
      _ChangeMaster
}
where
      BillOfOperationsType =  '2'
  and ValidityEndDate      >= ValidityStartDate
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MFGBILLOFOPERATIONSCHGST",
"I_TASKLISTLONGTEXT"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSSTATUS",
"I_BILLOFOPERATIONSTYPE",
"I_BILLOFOPERATIONSUSAGE",
"I_CHANGEMASTER",
"I_MFGBILLOFOPERATIONS",
"I_PLANT",
"I_RESPONSIBLEPLANNERGROUP",
"I_TASKLISTLONGTEXT",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_MFGBILLOFOPERATIONSCHGST"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More