I_MASSMAINTCAPAREAOFRESPY

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Work Center Capacity AOR'
@VDM.viewType: #COMPOSITE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
define view entity I_MassMaintCapAreaOfRespy
  as select from I_WorkCenterCapacity          as _crca

    inner join   I_WorkCenterGroupTreeAggrgn   as _wkcgrp    on  _crca.WorkCenterInternalID = _wkcgrp.WorkCenterGroupHierarchyNode
                                                             and _wkcgrp.WrkCtrGroupHierarchyNodeType  = 'A'

    inner join   I_WorkCtrGrpCapByAreaOfRespy  as _wkcgrpAOR on  _wkcgrpAOR.UserID                    = $session.user
                                                             and _wkcgrpAOR.Plant                     = _crca.Plant
                                                             and _wkcgrpAOR.WorkCenterGroupInternalID = _wkcgrp.WrkCtrGroupHierarchyRootNode //HierarchyParentNode

                                                             and _wkcgrpAOR.WorkCenterGroupTypeCode   = 'G'
    inner join   I_MassMaintCapAreaOfRespyPref as _AORPref   on  _AORPref.AreaOfResponsibility           = 'WKCGRP'
                                                             and _AORPref.AreaOfRespyIsMaintained        = 'X'
                                                             and _AORPref.AreaOfRespyPreferencePatternID = 'MMWKC'
{
  key _crca.CapacityInternalID   as CapacityInternalID,
  key _crca.WorkCenterInternalID as WorkCenterInternalID
}


union select from I_WorkCenterCapacity          as _crca
  inner join      I_MassMaintCapAreaOfRespyPref as _AORPref                 on  _AORPref.AreaOfResponsibility           = 'PMRP'
                                                                            and _AORPref.AreaOfRespyIsMaintained        = 'X'
                                                                            and _AORPref.AreaOfRespyPreferencePatternID = 'MMWKC'

  inner join      I_SDMAreaOfResponsibility     as _SDMAreaOfResponsibility on  _SDMAreaOfResponsibility.UserID = $session.user
                                                                            and _SDMAreaOfResponsibility.Plant  = _crca.Plant

//  inner join      P_AreaOfRespyBOOOperation     as _OperationActTasks       on  _OperationActTasks.WorkCenterInternalID = _crca.WorkCenterInternalID

//                                                                            and _OperationActTasks.Plant                = _SDMAreaOfResponsibility.Plant

//

//

//  inner join      I_BOOSqncOperationAssgmtChgSt as _OperationActivities     on  _OperationActivities.IsDeleted              = ''

//                                                                            and _OperationActivities.BillOfOperationsType   = _OperationActTasks.BillOfOperationsType

//                                                                            and _OperationActivities.BillOfOperationsGroup  = _OperationActTasks.BillOfOperationsGroup

//                                                                            and _OperationActivities.BOOOperationInternalID = _OperationActTasks.BOOOperationInternalID


  inner join      P_AreaOfRespyBOOSqncOpAssgmt     as _OperationActTasks       on  _OperationActTasks.WorkCenterInternalID = _crca.WorkCenterInternalID
                                                                            and _OperationActTasks.Plant                = _SDMAreaOfResponsibility.Plant

  inner join      P_WrkCtrCapAreaOfRespyHrzn    as _Horizon                 on  _Horizon.HorizonStartDate <= $session.system_date
                                                                            and _Horizon.HorizonEndDate   >= $session.system_date


  inner join      I_ProductionVersion           as _ProductionVersions      on  _ProductionVersions.BillOfOperationsType      = _OperationActTasks.BillOfOperationsType
                                                                            and _ProductionVersions.BillOfOperationsGroup     = _OperationActTasks.BillOfOperationsGroup
//                                                                            and _ProductionVersions.BillOfOperationsVariant   = _OperationActivities.BillOfOperationsVariant

                                                                            and _ProductionVersions.BillOfOperationsVariant   = _OperationActTasks.BillOfOperationsVariant
                                                                            and _ProductionVersions.Plant                     = _SDMAreaOfResponsibility.Plant
                                                                            and (
                                                                               _ProductionVersions.ValidityStartDate          <= $session.system_date
                                                                               or _ProductionVersions.ValidityStartDate       between $session.system_date and _Horizon.HorizonEndDate
                                                                             )
                                                                            and (
                                                                               _ProductionVersions.ValidityEndDate            >= $session.system_date
                                                                             )
                                                                            and _ProductionVersions.ProductionVersionIsLocked = ''
                                                                            and (
                                                                               _ProductionVersions.BillOfOperationsType       = 'N'
                                                                               or _ProductionVersions.BillOfOperationsType    = '2'
                                                                             )

  inner join      P_MaterialPlantAreaOfRespy    as _Material                on  _Material.Material = _ProductionVersions.Material
                                                                            and _Material.Plant    = _ProductionVersions.Plant


{
  key _crca.CapacityInternalID   as CapacityInternalID,
  key _crca.WorkCenterInternalID as WorkCenterInternalID
}
union select from I_WorkCenterCapacity          as _crca

    inner join   P_WrkCtrPersnRespAORList  as _wkcrespAOR on  _wkcrespAOR.Plant = _crca.Plant
                                                          and  _wkcrespAOR.WorkCenterResponsible = _crca.WorkCenterResponsible
                                                          and _wkcrespAOR.PersnRespAORIsAssigned = 1
    inner join   I_MassMaintCapAreaOfRespyPref as _AORPref   on  _AORPref.AreaOfResponsibility           = 'WKCRESP'
                                                             and _AORPref.AreaOfRespyIsMaintained        = 'X'
                                                             and _AORPref.AreaOfRespyPreferencePatternID = 'MMWKC'
{
  key _crca.CapacityInternalID   as CapacityInternalID,
  key _crca.WorkCenterInternalID as WorkCenterInternalID
 }
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MASSMAINTCAPAREAOFRESPYPREF",
"I_PRODUCTIONVERSION",
"I_SDMAREAOFRESPONSIBILITY",
"I_WORKCENTERCAPACITY",
"I_WORKCENTERGROUPTREEAGGRGN",
"I_WORKCTRGRPCAPBYAREAOFRESPY",
"P_AREAOFRESPYBOOSQNCOPASSGMT",
"P_MATERIALPLANTAREAOFRESPY",
"P_WRKCTRCAPAREAOFRESPYHRZN",
"P_WRKCTRPERSNRESPAORLIST"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/