I_MAKEBKTRANSFWITHFILTER
Items of Track Bank Transfer
I_MAKEBKTRANSFWITHFILTER is a CDS View in S/4HANA. Items of Track Bank Transfer. It contains 73 fields. 1 CDS views read from this table.
CDS Views using this table (1)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| I_MakeBankTransferTP | view | from | TRANSACTIONAL | Make Bank Transfers |
Fields (73)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | PaymentRequest | PaymentRequest | 1 |
| AccountingDocument | AccountingDocument | 1 | |
| AccountingDocumentCreationDate | AccountingDocumentCreationDate | 1 | |
| AccountingDocumentItem | AccountingDocumentItem | 1 | |
| BankAccountHolderName | BankAccountHolderName | 1 | |
| BankCountry | BankCountry | 1 | |
| BankDetailReference | BankDetailReference | 1 | |
| BankInternalID | BankInternalID | 1 | |
| BPBankAccountInternalID | BPBankAccountInternalID | 1 | |
| BusinessArea | BusinessArea | 1 | |
| ClearingAccountingDocument | ClearingAccountingDocument | 1 | |
| ClearingDate | ClearingDate | 1 | |
| CompanyCode | CompanyCode | 1 | |
| CompanyCodeCurrency | CompanyCodeCurrency | 1 | |
| CreatedByUser | CreatedByUser | 1 | |
| CreationTime | CreationTime | 1 | |
| DataExchangeInstruction1 | DataExchangeInstruction1 | 1 | |
| DataExchangeInstruction2 | DataExchangeInstruction2 | 1 | |
| DataExchangeInstruction3 | DataExchangeInstruction3 | 1 | |
| DataExchangeInstruction4 | DataExchangeInstruction4 | 1 | |
| DataExchangeInstructionKey | DataExchangeInstructionKey | 1 | |
| FinancialAccountType | FinancialAccountType | 1 | |
| FiscalYear | FiscalYear | 1 | |
| GLAccount | GLAccount | 1 | |
| HouseBank | HouseBank,PayingHouseBank | 1 | |
| HouseBankAccount | HouseBankAccount,PayingHouseBankAccount | 1 | |
| IsReversed | IsReversed | 1 | |
| IsSinglePayment | IsSinglePayment | 1 | |
| LogHandle | LogHandle | 1 | |
| PayeeAdditionalName2 | PayeeAdditionalName2 | 1 | |
| PayeeAdditionalName3 | PayeeAdditionalName3 | 1 | |
| PayeeAdditionalName4 | PayeeAdditionalName4 | 1 | |
| PayeeBank | PayeeBank | 1 | |
| PayeeBankAccount | PayeeBankAccount | 1 | |
| PayeeBankControlKey | PayeeBankControlKey | 1 | |
| PayeeBankCountry | PayeeBankCountry | 1 | |
| PayeeBankInternalID | PayeeBankInternalID | 1 | |
| PayeeBankValueDate | PayeeBankValueDate | 1 | |
| PayeeCityName | PayeeCityName | 1 | |
| PayeeCompanyCode | PayeeCompanyCode | 1 | |
| PayeeCountry | PayeeCountry | 1 | |
| PayeeFaxNumber | PayeeFaxNumber | 1 | |
| PayeeHouseBank | PayeeHouseBank | 1 | |
| PayeeHouseBankAccount | PayeeHouseBankAccount | 1 | |
| PayeeLanguage | PayeeLanguage | 1 | |
| PayeeName | PayeeName | 1 | |
| PayeePOBox | PayeePOBox | 1 | |
| PayeePostalCode | PayeePostalCode | 1 | |
| PayeeRegion | PayeeRegion | 1 | |
| PayeeStreet | PayeeStreet | 1 | |
| PayeeTelephoneNumber | PayeeTelephoneNumber | 1 | |
| PayeeTitle | PayeeTitle | 1 | |
| PayingCompanyCode | PayingCompanyCode | 1 | |
| PaymentMethod | PaymentMethod | 1 | |
| PaymentMethodSupplement | PaymentMethodSupplement | 1 | |
| PaymentReference | PaymentReference | 1 | |
| PaymentRequestAmountInCCCrcy | PaymentRequestAmountInCCCrcy | 1 | |
| PaymentRequestAmountInPaytCrcy | PaymentRequestAmountInPaytCrcy | 1 | |
| PaymentRequestCurrency | PaymentRequestCurrency | 1 | |
| PaymentRequestOrigin | PaymentRequestOrigin | 1 | |
| PaymentRequestPostingDate | PaymentRequestPostingDate | 1 | |
| PaytReqIsCompleted | PaytReqIsCompleted | 1 | |
| PaytReqIsReleasedForPayment | PaytReqIsReleasedForPayment | 1 | |
| PaytReqIsReleasedForPosting | PaytReqIsReleasedForPosting | 1 | |
| POBoxPostalCode | POBoxPostalCode | 1 | |
| ReferenceTypeText | Note,ReferenceTypeText | 1 | |
| ReversalReason | ReversalReason | 1 | |
| StateCentralBankPaymentReason | StateCentralBankPaymentReason | 1 | |
| StatusCode | StatusCode | 1 | |
| SupplierCountry | SupplierCountry | 1 | |
| SupplyingCountry | SupplyingCountry | 1 | |
| TaxID1 | TaxID1 | 1 | |
| ValueDate | ValueDate | 1 |
@AbapCatalog.sqlViewName: 'IMBKTWITHFILTER'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Items of Track Bank Transfer'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'PaymentRequest'
@Search.searchable: true
define view I_MakeBkTransfWithFilter
as select from payrq as payrq
left outer join payrqp on payrq.keyno = payrqp.keyno
association [0..1] to I_RepetitiveCode as _RepetitiveCode on $projection.RepetitiveCode = _RepetitiveCode.RepetitiveCode
and $projection.PayingCompanyCode = _RepetitiveCode.PayingCompanyCode
and $projection.HouseBank = _RepetitiveCode.HouseBank
association [0..1] to I_CompanyCode as _PayingCompanyCode on $projection.PayingCompanyCode = _PayingCompanyCode.CompanyCode
association [0..1] to I_PaymentMethod as _PaymentMethod on $projection.BankCountry = _PaymentMethod.Country
and $projection.PaymentMethod = _PaymentMethod.PaymentMethod
association [1..1] to I_AccountingDocument as _PaymentDocument on $projection.AccountingDocument = _PaymentDocument.AccountingDocument
and $projection.CompanyCode = _PaymentDocument.CompanyCode
and $projection.FiscalYear = _PaymentDocument.FiscalYear
association [1..1] to I_BusinessAreaText as _BusinessAreaText on $projection.BusinessArea = _BusinessAreaText.BusinessArea
and _BusinessAreaText.Language = $session.system_language
association [1..1] to I_Currency as _PaymentRequestCurrency on $projection.PaymentRequestCurrency = _PaymentRequestCurrency.Currency
association [1..1] to I_Currency as _CompanyCodeCurrency on $projection.CompanyCodeCurrency = _CompanyCodeCurrency.Currency
association [1..1] to I_GLAccount as _GLAccount on $projection.GLAccount = _GLAccount.GLAccount
and $projection.CompanyCode = _GLAccount.CompanyCode
association [1..1] to I_Housebank as _HouseBank on $projection.HouseBank = _HouseBank.HouseBank
and $projection.CompanyCode = _HouseBank.CompanyCode
association [1..1] to I_PaytReqChgAndPostingData as _PaytReqChangeAndPost on $projection.PaymentRequest = _PaytReqChangeAndPost.PaymentRequest
association [1..1] to I_ReversalReason as _ReversalReason on $projection.ReversalReason = _ReversalReason.ReversalReason
association [1..*] to I_SystemStatusText as _SystemStatusText on $projection.StatusCode = _SystemStatusText.SystemStatus
association [1..*] to I_OperationalAcctgDocItem as _AccountingDocItem on $projection.CompanyCode = _AccountingDocItem.CompanyCode
and $projection.AccountingDocument = _AccountingDocItem.AccountingDocument
and $projection.FiscalYear = _AccountingDocItem.FiscalYear
association [0..1] to I_UserContactCard as _UserContactCard on $projection.CreatedByUser = _UserContactCard.ContactCardID
{
key cast(payrq.keyno as farp_prq_keyno) as PaymentRequest,
// cast(payrq.zbukr as farp_bnk_com_dzbukr) as PayingCompanyCode,
payrq.zbukr as PayingCompanyCode,
cast(payrq.bukrs as fis_bukrs) as CompanyCode,
cast(payrq.belnr as farp_belnr_d) as AccountingDocument,
cast(payrq.gjahr as fis_gjahr) as FiscalYear,
cast(payrq.buzei as fis_buzei) as AccountingDocumentItem,
cast(payrq.znme1 as farp_dznme1) as PayeeName,
cast(payrq.zbnks as farp_dzbnks) as PayeeBankCountry,
cast(payrq.zbkon as farp_bnk_com_dzbkon) as PayeeBankControlKey,
cast(payrq.zbnkl as farp_bnk_com_dzbnkl) as PayeeBank,
cast(payrq.zbnky as farp_bnk_com_dzbnky) as PayeeBankInternalID,
cast(payrq.zbnkn as fclm_bam_acc_num) as PayeeBankAccount,
cast( coalesce(_RepetitiveCode.PayeeHouseBank,substring( rfttrn, 11, 5 )) as fclm_bam_aclink_hktid ) as PayeeHouseBank,
cast( coalesce(_RepetitiveCode.PayeeHouseBankAccount,substring( rfttrn, 16, 5 )) as farp_hktid ) as PayeeHouseBankAccount,
coalesce(_RepetitiveCode.PayeeCompanyCode,coalesce(payrqp.bukrs,payrq.bukrs)) as PayeeCompanyCode,
cast(payrq.bkref as farp_prq_bkref) as BankDetailReference,
cast(payrq.crval as farp_prq_crval) as PayeeBankValueDate,
cast(payrq.valut as farp_prq_valdt) as ValueDate,
cast(payrq.koinh as bu_koinh) as BankAccountHolderName,
payrq.gsber as BusinessArea,
cast(payrq.sgtxt as farp_reftxt) as ReferenceTypeText, //Reference Text
// cast(payrq.hbkid as farp_hbkid) as HouseBank,
payrq.hbkid as HouseBank,
payrq.hktid as HouseBankAccount,
@Search: {
defaultSearchElement: true,
fuzzinessThreshold : 0.5,
ranking : #HIGH
}
@Semantics.currencyCode: true
@Consumption.valueHelpDefinition: [{association: '_PaymentRequestCurrency'}]
cast(payrq.pacur as fqm_currency) as PaymentRequestCurrency,
@Semantics.amount.currencyCode: 'PaymentRequestCurrency'
@DefaultAggregation: #NONE
cast(payrq.pamtf as farp_prq_amtfc) as PaymentRequestAmountInPaytCrcy,
@Semantics.amount.currencyCode: 'CompanyCodeCurrency'
@DefaultAggregation: #NONE
payrq.pamtl as PaymentRequestAmountInCCCrcy,
@Semantics.currencyCode: true
@ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
payrq.hwaer as CompanyCodeCurrency,
payrq.uzawe as PaymentMethodSupplement,
payrq.zwels as PaymentMethod,
cast(payrq.xpore as farp_prq_xpore) as IsSinglePayment,
payrq.kidno as PaymentReference,
cast(payrq.koart as farp_koart) as FinancialAccountType,
payrq.hkont as GLAccount,
@ObjectModel.foreignKey.association: '_UserContactCard'
cast(payrq.usnam as vdm_createdbyuserid) as CreatedByUser, //fclm_bam_created_by
cast(payrq.xreld as farp_prq_xreld) as PaytReqIsReleasedForPosting,
cast(payrq.xreli as farp_prq_xreli) as PaytReqIsCompleted,
cast(payrq.xrelp as farp_prq_xrelp) as PaytReqIsReleasedForPayment,
cast(payrq.xreve as farp_prq_xreve) as IsReversed,
payrq.stgrd as ReversalReason,
cast(payrq.dtaws as farp_bnk_com_dtaws) as DataExchangeInstructionKey,
cast(payrq.dtws1 as num2) as DataExchangeInstruction1,
cast(payrq.dtws2 as num2) as DataExchangeInstruction2,
cast(payrq.dtws3 as num2) as DataExchangeInstruction3,
cast(payrq.dtws4 as num2) as DataExchangeInstruction4,
cast(payrq.post_date as farp_prq_postdate) as PaymentRequestPostingDate,
payrq.ubnks as BankCountry,
payrq.ubnky as BankInternalID,
payrq.land1 as SupplierCountry, //??
payrq.landl as SupplyingCountry,
cast(payrq.origin as farp_fibl_origin) as PaymentRequestOrigin,
cast(payrq.lzbkz as farp_prq_lzbkz) as StateCentralBankPaymentReason,
cast(payrq.cpudt as farp_cpudt) as AccountingDocumentCreationDate,
cast('000000' as ttet_dt_cr_time) as CreationTime,
stcd1 as TaxID1,
cast( case
when payrq.augbl = payrq.keyno then ''
else payrq.augbl end as fis_augbl
) as ClearingAccountingDocument,
cast(payrq.bvtyp as farp_bnk_com_bvtyp) as BPBankAccountInternalID,
cast(
case
when payrq.xreve = 'X' then 'I0559' //Reversed
when payrq.augbl != '' and payrq.xreve = '' then 'IBC26' //Cleared
when payrq.xrelp = 'X' then 'I0002' //Released
when payrq.belnr = '' then 'I0001' //Created
else ''
end as farp_payrq_status) as StatusCode,
payrq.zanre as PayeeTitle,
payrq.zpstl as PayeePostalCode,
payrq.zpfac as PayeePOBox,
payrq.pstl2 as POBoxPostalCode,
cast(payrq.znme2 as farp_dznme2) as PayeeAdditionalName2,
cast(payrq.znme3 as farp_dznme3) as PayeeAdditionalName3,
cast(payrq.znme4 as farp_dznme4) as PayeeAdditionalName4,
cast(payrq.zort1 as farp_dzort1) as PayeeCityName,
cast(payrq.zstra as farp_dzstra) as PayeeStreet,
cast(payrq.zland as farp_dzland) as PayeeCountry,
cast(payrq.zregi as farp_prq_dzregi) as PayeeRegion,
cast(payrq.zspra as farp_prq_dzspra) as PayeeLanguage,
cast(payrq.ztlfx as farp_telfx) as PayeeFaxNumber,
cast(payrq.ztelf as farp_telf1) as PayeeTelephoneNumber,
payrq.ziban as PayeeIBAN,
payrq.augdt as ClearingDate,
payrq.rfttrn as RepetitiveCode,
cast( payrq.sname4 as apl_log_handle ) as LogHandle,
_PaymentMethod.PaymentMethodName as PaymentMethodName,
_AccountingDocItem,
_PaymentDocument,
_BusinessAreaText,
// _PayeeCompanyCode,
_PaymentRequestCurrency,
_CompanyCodeCurrency,
_GLAccount,
_HouseBank,
_PaymentMethod,
_PaytReqChangeAndPost,
_SystemStatusText,
_ReversalReason,
_UserContactCard,
_PayingCompanyCode,
_RepetitiveCode
}
where
payrq.origin = 'TR-CM-BT'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PAYMENTMETHOD",
"I_REPETITIVECODE",
"PAYRQ",
"PAYRQP"
],
"ASSOCIATED":
[
"I_ACCOUNTINGDOCUMENT",
"I_BUSINESSAREATEXT",
"I_COMPANYCODE",
"I_CURRENCY",
"I_GLACCOUNT",
"I_HOUSEBANK",
"I_OPERATIONALACCTGDOCITEM",
"I_PAYMENTMETHOD",
"I_PAYTREQCHGANDPOSTINGDATA",
"I_REPETITIVECODE",
"I_REVERSALREASON",
"I_SYSTEMSTATUSTEXT",
"I_USERCONTACTCARD"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/