I_MAINTENANCEPLANNERGROUP

CDS View

Maintenance Planner Group

I_MAINTENANCEPLANNERGROUP is a CDS View in S/4HANA. Maintenance Planner Group. It contains 5 fields. 2 CDS views read from this table.

Used by 2 CDS view(s) 5 fields

CDS Views using this table (2)

ViewTypeJoinVDMDescription
C_MaintenancePlannerGroupVH view from CONSUMPTION Maintenance Planner Group
I_MaintPlnrGrpStdVH view from COMPOSITE Maintenance Planner Group

Fields (5)

KeyField CDS FieldsUsed in Views
KEY MaintenancePlannerGroup MaintenancePlannerGroup 1
KEY MaintenancePlanningPlant MaintenancePlanningPlant 1
EmailAddress EmailAddress 1
MaintenancePlannerGroupName MaintenancePlannerGroupName 1
MaintPlannerGroupPhoneNumber MaintPlannerGroupPhoneNumber 1 
@EndUserText.label: 'Maintenance Planner Group'
@Analytics: { dataCategory: #DIMENSION, 
  dataExtraction : { enabled: true , 
  delta.changeDataCapture.automatic: true } 
}
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IMAINTPLGRP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK

@ObjectModel.representativeKey:  'MaintenancePlannerGroup'

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions: true
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #EXTRACTION_DATA_SOURCE]
@ObjectModel.alternativeKey:[{id:'OID',element:['MaintenancePlannerGroupOID']}] 
@ObjectModel.objectIdentifier.oidElement:'MaintenancePlannerGroupOID' 

define view I_MaintenancePlannerGroup as select from t024i
 left outer to one join I_MdiOidConfiguration on I_MdiOidConfiguration.ObjectTypeCode = '5680'
//Obsolete-C1 released association not intended to used and replaced with I_MaintenancePlanPlant

association[0..1] to I_Plant as _MaintenancePlanningPlant on $projection.MaintenancePlanningPlant = _MaintenancePlanningPlant.Plant
//////////////////////////////////////////////////////////////////////////////

association[0..1] to I_MaintenancePlanPlant  as _MaintenancePlanPlant on $projection.MaintenancePlanningPlant = _MaintenancePlanPlant.MaintenancePlanningPlant
{

    @ObjectModel.text.element:  [ 'MaintenancePlannerGroupName' ]
    key cast( t024i.ingrp as eam_planner_group preserving type ) as MaintenancePlannerGroup, 
    
    @ObjectModel.foreignKey.association: '_MaintenancePlanPlant'     
    key t024i.iwerk as MaintenancePlanningPlant, 
    
    @Semantics.text: true
    cast( t024i.innam as eam_planner_group_name preserving type ) as MaintenancePlannerGroupName, 
    @Semantics.telephone.type:#PREF
    t024i.intel as MaintPlannerGroupPhoneNumber, 
    t024i.auart_wp as MaintenanceOrderType, 
    @Semantics.eMail.address : true
    t024i.smtp_addr as EmailAddress,
    
    //MDI/ODM

      @ObjectModel.filter.enabled:false
      @ObjectModel.sort.enabled:false

      //Context ID is not specified

      case when I_MdiOidConfiguration.Context is initial

      //Composition is disabled

             or I_MdiOidConfiguration.ComposeOid is initial then

           cast( t024i.ingrp as maintenanceplannergroup_oid ) //use your own data element


      //Context ID is specified

           when I_MdiOidConfiguration.Context    is not initial
      //           and dd07l.domvalue_l                 is not initial

            and I_MdiOidConfiguration.ComposeOid is not initial then

           cast( concat( concat( I_MdiOidConfiguration.Context, ':' ), t024i.ingrp ) as maintenanceplannergroup_oid ) //use your own data element

           end        as MaintenancePlannerGroupOID, //use your own OID field name

    
    _MaintenancePlanningPlant,  //Obsolete association

    _MaintenancePlanPlant
}               
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MDIOIDCONFIGURATION",
"T024I"
],
"ASSOCIATED":
[
"I_MAINTENANCEPLANPLANT",
"I_PLANT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More