I_MAINTENANCEITEMTEXT

CDS View

Maintenance Item Long Text

I_MAINTENANCEITEMTEXT is a CDS View in S/4HANA. Maintenance Item Long Text. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
R_MaintenanceItemTextTP view_entity from TRANSACTIONAL Maintenace Item Long Text 
@AbapCatalog.sqlViewName: 'IMAINTITEMTEXT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@EndUserText.label: 'Maintenance Item Long Text'
@VDM.viewType: #COMPOSITE
@ObjectModel.representativeKey: 'MaintenanceItem'

@ObjectModel.dataCategory: #TEXT

@ObjectModel: {
   usageType.serviceQuality: #C,
   usageType.sizeCategory: #XL,
   usageType.dataClass: #MIXED
}

define view I_MaintenanceItemText
  as select from I_MaintenanceItem as _MaintenanceItem
    inner join   I_TextObject      as _TextObject on  _TextObject.TextObjectType     = 'LTXT'
                                                  and _TextObject.TextObjectCategory = 'MPOS'
                                                  and _TextObject.TextObjectKey      = _MaintenanceItem.MaintenanceItem

  association [0..1] to I_Language                as _Language           on  _Language.Language = $projection.Language


  association [0..1] to I_TextObjectType          as _TextObjectType     on  _TextObjectType.TextObjectType     = $projection.TextObjectType
                                                                         and _TextObjectType.TextObjectCategory = $projection.TextObjectCategory

  association [0..1] to I_TextObjectCategory      as _TextObjectCategory on  _TextObjectCategory.TextObjectCategory = $projection.TextObjectCategory

  association [0..1] to I_TextObjectPlainLongText as _LongText           on  _LongText.TextObjectCategory = 'MPOS'
                                                                         and _LongText.TextObjectType     = 'LTXT'
                                                                         and _LongText.TextObjectKey      = $projection.MaintenanceItem
                                                                         and _LongText.Language           = $projection.Language
{

  key     _MaintenanceItem.MaintenanceItem,

          @Semantics.language:true
          @ObjectModel.foreignKey.association: '_Language'
  key     cast( _TextObject.Language as spras preserving type ) as Language,

          cast( _MaintenanceItem.MaintenanceItem as tdobname )  as TextObjectKey,

          @ObjectModel.foreignKey.association: '_TextObjectCategory'
          cast( 'MPOS      ' as tdobject preserving type )      as TextObjectCategory,

          @ObjectModel.foreignKey.association: '_TextObjectType'
          cast( 'LTXT' as tdid preserving type )                as TextObjectType,

          @Semantics.text:true
          _LongText.PlainLongText                               as MaintenanceItemLongText,

          /* Local Association */
          _LongText,
          _Language,
          _TextObjectType,
          _TextObjectCategory

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MAINTENANCEITEM",
"I_TEXTOBJECT",
"I_TEXTOBJECTPLAINLONGTEXT"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_TEXTOBJECTCATEGORY",
"I_TEXTOBJECTPLAINLONGTEXT",
"I_TEXTOBJECTTYPE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More