I_MAINTENANCEITEMOBJECT

CDS View

Maintenance Item Object List

I_MAINTENANCEITEMOBJECT is a CDS View in S/4HANA. Maintenance Item Object List. It contains 9 fields. 23 CDS views read from this table.

Used by 23 CDS view(s) 9 fields

CDS Views using this table (23)

ViewTypeJoinVDMDescription
A_MaintenanceItemObj view from BASIC CDS view for API exposure
A_MaintenanceItemObj_1 view from BASIC CDS view for API exposure
A_MaintenanceItemObjList view from BASIC CDS View for Maintenance Item Object List
A_MaintenanceItemObjList_1 view from BASIC CDS View for Maintenance Item Object List
A_ReturnsDeliveryMaintObj view from BASIC Returns Delivery Maintenance Object
A_ReturnsDeliveryMaintObj_1 view from BASIC Returns Delivery Maintenance Object
C_CustRetRefDocSrlNmbr view_entity inner CONSUMPTION Returns Order Reference Document Serial Number
C_MaintItemObjPgObjectList view from CONSUMPTION Object List for the Maintenance Item Object Page
C_MaterialDocumentSerialNoFDP view inner CONSUMPTION Material Document Serial Numbers Output Forms
C_PT_SAFTBillingItemSerialNmbr view inner CONSUMPTION SAF-T PT Item Serial Numbers
C_SAFTDeliverySerialNumber view inner CONSUMPTION PT SAFT MOG Serial Number
C_SerialNmbrEquipNmbrDelivery view left_outer CONSUMPTION Serial and Equipment Numbers
I_CustomerReturnSerialNumber view inner COMPOSITE Returns Order Serial Number
I_FldLogsMaintObjListDelivPO view_entity from COMPOSITE Serial Number
I_FldLogsSrlNmbrItems view inner COMPOSITE Field Logistics Serial Numbers
I_InspLotSerialNumber view_entity inner COMPOSITE Serial Numbers of Inspection Lot
I_MaintItemObjListTechObj view from COMPOSITE Maintenance Item Object List with Technical Object
I_MaintItemObjListTechObj view union_all COMPOSITE Maintenance Item Object List with Technical Object
I_MfgOrderItemSerialNumber view inner COMPOSITE Manufacturing Order Item Serial Number
I_OpenMaintOrderForTechObject view union COMPOSITE Open Maintainance Orders for Technical Object
I_PlantMaintObjectListData view from COMPOSITE Object List Data (Extractor)
I_SerialNumberMaterialDocument view inner COMPOSITE Serial Number Material Documents
P_PhysInvtryDocSrlNmbr view inner COMPOSITE

Fields (9)

KeyField CDS FieldsUsed in Views
KEY Equipment Equipment 8
KEY MaintenanceItemObject MaintenanceItemObject 7
KEY MaintenanceItemObjectList MaintenanceItemObjectList 5
KEY SerialNumber SerialNumber 13
Assembly Assembly 6
FunctionalLocation FunctionalLocation 6
MaintenanceNotification MaintenanceNotification 6
MaintObjectLocAcctAssgmtNmbr MaintObjectLocAcctAssgmtNmbr 6
Material Material 7 
@AbapCatalog.sqlViewName: 'IMTITMOBJ'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: ['_LocationAccountAssignment']
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Maintenance Item Object List'
@ObjectModel: {
    representativeKey: [ 'MaintenanceItemObject' ],
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #B,
        sizeCategory: #XL
    }
}
@VDM.viewType: #BASIC


define view I_MaintenanceItemObject
  as select from objk
  association [0..1] to I_MaintenanceItem           as _MaintenanceItem           on _MaintenanceItem.MaintenanceItemObjectList = $projection.MaintenanceItemObjectList
  association [0..1] to I_LocationAccountAssignment as _LocationAccountAssignment on _LocationAccountAssignment.MaintObjectLocAcctAssgmtNmbr = $projection.MaintObjectLocAcctAssgmtNmbr
  association [0..1] to I_PMNotifMaintenanceData    as _PMNotifMaintenanceData    on _PMNotifMaintenanceData.MaintenanceNotification = $projection.MaintenanceNotification
  association [0..1] to I_MaintenanceNotification   as _MaintenanceNotification   on _MaintenanceNotification.MaintenanceNotification = $projection.MaintenanceNotification
  association [0..1] to I_Equipment                 as _Equipment                 on _Equipment.Equipment = $projection.Equipment
  association [0..1] to I_FunctionalLocation        as _FunctionalLocation        on _FunctionalLocation.FunctionalLocation = $projection.FunctionalLocation
  association [0..1] to I_Material                  as _Assembly                  on _Assembly.Material = $projection.Assembly
  association [0..1] to I_Material                  as _Material                  on _Material.Material = $projection.Material
  association [0..1] to I_Product                   as _Product                   on $projection.Product = _Product.Product
{
  key objk.obknr                                                                                                                       as MaintenanceItemObjectList,

  key objk.obzae                                                                                                                       as MaintenanceItemObject,

      @ObjectModel.foreignKey.association: '_Equipment'
      coalesce( _PMNotifMaintenanceData.Equipment, objk.equnr  )                                                                        as Equipment,

      @ObjectModel.foreignKey.association: '_FunctionalLocation'
      coalesce( _LocationAccountAssignment.FunctionalLocation, _PMNotifMaintenanceData._LocationAccountAssignment.FunctionalLocation ) as FunctionalLocation,

      @Consumption.valueHelpDefinition: [{
        entity: {
            name: 'I_MaterialStdVH',
            element: 'Material'
        }
      }]
      @ObjectModel.foreignKey.association: '_Assembly'
      coalesce( _PMNotifMaintenanceData.Assembly, objk.bautl )                                                                         as Assembly,

      objk.sernr                                                                                                                       as SerialNumber,

      @Consumption.valueHelpDefinition: [{
        entity: {
            name: 'I_MaterialStdVH',
            element: 'Material'
        }
      }]
      @ObjectModel.foreignKey.association: '_Material'
      objk.matnr                                                                                                                       as Material,

      @ObjectModel.foreignKey.association: '_MaintenanceNotification'
      objk.ihnum                                                                                                                       as MaintenanceNotification,

      @ObjectModel.foreignKey.association: '_LocationAccountAssignment'
      objk.iloan                                                                                                                       as MaintObjectLocAcctAssgmtNmbr,

      objk.sortf                                                                                                                       as SortField,

      //needed for BW Extractor

      @UI.hidden: true
      objk.datum                                                                                                                       as CreationDate,

      objk.bearb                                                                                                                       as MaintObjListEntryIsProcessed,
      @ObjectModel.foreignKey.association: '_Product'
      objk.product                                                                                                                     as Product,

      // Associations

      _MaintenanceItem,
      _Assembly,
      _Equipment,
      _FunctionalLocation,
      _LocationAccountAssignment,
      _MaintenanceNotification,
      _Material,
      _Product
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LOCATIONACCOUNTASSIGNMENT",
"I_PMNOTIFMAINTENANCEDATA",
"OBJK"
],
"ASSOCIATED":
[
"I_EQUIPMENT",
"I_FUNCTIONALLOCATION",
"I_LOCATIONACCOUNTASSIGNMENT",
"I_MAINTENANCEITEM",
"I_MAINTENANCENOTIFICATION",
"I_MATERIAL",
"I_PMNOTIFMAINTENANCEDATA",
"I_PRODUCT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More