I_MAINTPLANCALLHISTORY

CDS View

Maintenance Plan Call History

I_MAINTPLANCALLHISTORY is a CDS View in S/4HANA. Maintenance Plan Call History. 7 CDS views read from this table.

Used by 7 CDS view(s)

CDS Views using this table (7)

ViewTypeJoinVDMDescription
I_MaintenancePlanSchedule view from COMPOSITE Scheduled calls for Maintenance Plan
I_MaintPlanMaintCall view from COMPOSITE Maintenance calls for Maintenance Plan
P_MaintenancePlanCallDateBasic view from COMPOSITE Maintenance Plan Call Date
P_MaintenancePlanCallDateBasic view union COMPOSITE Maintenance Plan Call Date
P_RSHMaintAssetBoard view inner CONSUMPTION Maintenance Asset Board
P_RSHMaintAssetBoardShapes view inner CONSUMPTION Maintenance asset board shapes
P_RSHMaintPlanConsumption view inner CONSUMPTION Maintenance Plan Consumption 
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.sqlViewName: 'IMPLANCALLHIST'
@AbapCatalog.preserveKey: true
@AccessControl: {
    authorizationCheck:#CHECK,
    personalData.blocking: #NOT_REQUIRED,
    privilegedAssociations: [ '_ReleasedByUserName' ]
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Maintenance Plan Call History'
@ObjectModel: {
    representativeKey: 'MaintenancePlanCallNumber',
    semanticKey: ['MaintenancePlanCallNumber'],
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #A,
        sizeCategory: #M
    }
}
@VDM.viewType: #BASIC


define view I_MaintPlanCallHistory
  as select from mhis
    inner join   mpla on mpla.warpl = mhis.warpl

  association [0..1] to I_MaintenancePlan         as _MaintenancePlan             on  _MaintenancePlan.MaintenancePlan = $projection.MaintenancePlan
  association [0..1] to I_MaintenancePackage      as _MaintenancePackage          on  _MaintenancePackage.MaintenanceStrategy = $projection.MaintenanceStrategy
                                                                                  and _MaintenancePackage.MaintenancePackage  = $projection.MaintenancePackage
  association [0..1] to I_MaintenanceStrategy     as _MaintenanceStrategy         on  _MaintenanceStrategy.MaintenanceStrategy = $projection.MaintenanceStrategy
  association [0..1] to I_Indicator               as _MaintenancePlanCallIsLocked on  _MaintenancePlanCallIsLocked.IndicatorValue = $projection.MaintenancePlanCallIsLocked
  association [0..1] to I_MaintCallSchedulingType as _SchedulingType              on  _SchedulingType.SchedulingType = $projection.SchedulingType
  association [0..1] to I_User                    as _ReleasedByUserName          on  _ReleasedByUserName.UserID = $projection.ReleasedByUserName

{
      @ObjectModel.foreignKey.association: '_MaintenancePlan'
  key mhis.warpl                   as MaintenancePlan,

  key mhis.abnum                   as MaintenancePlanCallNumber,

      @ObjectModel.foreignKey.association: '_MaintenancePackage'
  key mhis.zaehl                   as MaintenancePackage,

      @ObjectModel.foreignKey.association: '_MaintenanceStrategy'
      mpla.strat                   as MaintenanceStrategy,

      mhis.nplda                   as MaintenanceCallNextPlannedDate,

      @ObjectModel.foreignKey.association: '_SchedulingType'
      mhis.terma                   as SchedulingType,

      @ObjectModel.foreignKey.association: '_MaintenancePlanCallIsLocked'
      mhis.tsenm                   as MaintenancePlanCallIsLocked,

      mhis.tstat                   as SchedulingStatus,

      @Semantics.businessDate.at: true
      case mhis.horda
          when '' then '00000000'
          else mhis.horda
      end                          as MaintenanceCallDate,

      @Semantics.businessDate.to: true
      mhis.lrmdt                   as CompletionDate,

      mhis.cycleseqind             as CycleSetSequence,

      mhis.rzaeh                   as MaintCallCompltnCntrRdng,

      mhis.nzaeh                   as MaintCallNextPlndCntrRdng,

      mhis.abrna                   as ReleasedByUserName,

      mhis.tsabr                   as MaintCallIsInvokedOnPlndDate,

      mhis.tsvbt                   as MaintenanceCallIsOutstanding,

      mhis.tsenq                   as MaintCallHorizonIsNotReached,

      mhis.abrud                   as MaintPlanLastScheduledDate,
      
      mhis.npldz                   as MaintPlanPrdcssrCallCompltnDte,
      
      mhis.manda                   as MaintenancePlanManualCallDate,
      
      mhis.adcycle                 as MaintPlanCycRcrrcIntervalQty,
      
      mhis.adunit                  as MaintPlanCycRcrrcIntervalUnit,
      
      mhis.npldo                   as MaintenanceCallLastPlannedDate,

      /* Associations */
      _MaintenancePlan,
      _MaintenancePlanCallIsLocked,
      _SchedulingType,
      _MaintenancePackage,
      _MaintenanceStrategy,
      _ReleasedByUserName

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"MHIS",
"MPLA"
],
"ASSOCIATED":
[
"I_INDICATOR",
"I_MAINTCALLSCHEDULINGTYPE",
"I_MAINTENANCEPACKAGE",
"I_MAINTENANCEPLAN",
"I_MAINTENANCESTRATEGY",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More